setting a graphics window as the active window

[rwg]

hi - i'm having trouble making a graphics window the active window without having to click on it.

i want clicking on the graphics window (left click, right click etc) to send the program to different branches,

  instead of using them to activate the graphics screen. ok - i could click twice, but this is messy.

the following code shows the problem.

it's quite possible i'm doing something wrong.

i've tried "setfocus" with no success

regards rwg

     'get mainwindow number
     calldll #user32,"GetActiveWindow",_
     mainwinhandle as short

    'place mainwindow to left top, 400x400 pixels
     calldll #user32,"MoveWindow", _
     mainwinhandle as word, _
     0 as short, _
     0 as short, _
     400 as short, _
     400 as short, _
     1 as word, _
     result as void

    'create a graphics window
    WindowWidth=300
    WindowHeight=300
    UpperLeftX=600
    UpperLeftY=1
    open "Test Window" for graphics as #test

[repeat]
    cls
    #test "cls"
    'print hello on graphic window at 50,50
    #test "place 50 50"
    #test "\ hello"

    'set the mainwindow as the active window
    gosub [main]

    input "junk = ";a$

    'set the graphics window as the active window
    gosub [graph]

    'print hello2 on graphic window at 50,80
    #test "place 50 80"
    #test "\ hello2"

    'i have to click on the graphics window to make it active
    'even though i made it active via subroutine [graph]
    #test "when characterInput [gotit]"
    wait

    [gotit]
    gosub [main]
goto [repeat]

[main]
  calldll #user32, "SetActiveWindow",_
  mainwinhandle as ulong,_
  ret as ulong
  return

[graph]
  'get the graphics window number
  h1=hwnd(#test)
  calldll #user32, "SetActiveWindow",_
  h1 as ulong,_
  ret as ulong
  '#test "setfocus"
  return

[Chris Iverson]

(Moving this to the LB code subforum)

You need to get the parent of the graphics window to get the main application window that you need to send in to a call to SetActiveWindow().

[graph]
'get the graphics window number
h1=hwnd(#test)

'get graphics window parent
calldll #user32, "GetParent",_
h1 as ulong,_
hparent as ulong

print hparent

calldll #user32, "SetActiveWindow",_
hparent as ulong,_
ret as ulong
'#test "setfocus"
return

This is because of what a graphics window is: it's a regular window, with a full-size graphic box automatically sized to it. As shorthand, the handle you use to create the "graphic" window doesn't refer to the regular window; it refers to the graphicbox inside of it.

This works as a drop-in replacement for LB commands, because LB is able to know which commands you send it are meant for the graphicbox(and just get sent directly) or which are meant for the actual window(and get silently transferred to the actual window).


However, if you're doing API stuff, you don't get LB handling that for you, so you need to do it yourself. Grab the graphicbox's handle with hwnd(), and send it in to GetParent() to get the main window.

[rwg]

thanks Chris - i'd never had worked that out.

i used your solution and it works fine for "when leftButtonDown", and for "when rightButtonDown".

however it is not working for "when characterInput"

is there any reason for this ?

regards rwg

[rwg]

ok - worked out the "when characterInput" problem.
have to use the "setfocus" command
regards
rwg

[Chris Iverson]

Yeah, it's things like this that hint at how much LB does for you behind the scenes when it comes to window management.

Directly interacting with the win32 API means not having that crutch anymore when it comes to some things, and you just have to know how to handle it.