Spreadsheet in LB

[johnnyd]

Hi,

Many moons ago, someone had written (or maybe produced a DLL) to create a spreadsheet in LB.

I remember the cells laid out in a demo program but can't seem to locate it.

Anyone remember?

Cheers,

John.

[Carl Gundel]

Aug 14, 2020 6:48:58 GMT -5 johnnyd said:

Hi,

Many moons ago, someone had written (or maybe produced a DLL) to create a spreadsheet in LB.

I remember the cells laid out in a demo program but can't seem to locate it.

Anyone remember?

Cheers,

John.

You might have a peek at the LB5 builds, which include a grid control.

[johnnyd]

Hi Carl,

OK, I'll look into it.

Thanks!

John.

[meerkat]

Is it possible to enter data into a grid cell?

Thanks for the help..

Dan

[Rod]

You may have seen this before.

   nomainwin

   'set up a 12x25 cell sheet
   numCols=12   'x
   numRows=25  'y
   cellW=50   'cell width in pixels
   cellH=20   'cell height in pixels
   gridW=numCols*cellW 'total pixel width needed
   gridH=numRows*cellH 'total pixel height needed
   gridX=50    'location of data grid on window
   gridY=50
   cellColor$="black"
   cellBackcolor$="white"

   'fill the sheet's array with dummy data
   dim cell$(numCols,numRows)
   for C=1 to numCols
       for R=1 to numRows
           cell$(C,R)=str$(C)+":"+str$(R)
       next R
   next C

   'open a standard 800x600 window
   WindowWidth=800
   WindowHeight=600
   UpperLeftX=(DisplayWidth-WindowWidth)/2
   UpperLeftY=(DisplayHeight-WindowHeight)/2
   Margin=3
   'place a graphicbox at gridX,gridY,gridW and gridH
   graphicbox #main.g,gridX,gridY,gridW+Margin,gridH+Margin

   'set up a hidden default button
   'now if enter is pressed [okclicked] will be called
   button #main.ok,"",[okclicked],UL,-25,-25,20,20
   stylebits #main.ok, _BS_DEFPUSHBUTTON, 0, 0, 0

   'set up a hidden textbox
   'this will be relocated to intercept data input
   'when a cell is clicked
   textbox #main.txt, -100, -100, cellW, cellH


   button #main.print, "Print", [printit], LR, 105, 50
   button #main.submit, "Submit", [okclicked],LR, 50,50

   open "Data Grid" for window_nf as #main
   #main "trapclose [quit]"
   #main "font arial 8"
   #main.g "font arial 8"
   #main.g "down;fill buttonface;flush"

   #main.g "when leftButtonUp [cellclicked]"
   'find the handle of the moveable textbox and the ok button
   'so we can check which has focus
   htxt = hWnd(#main.txt)
   hok = hWnd(#main.submit)

   goto [redraw]




   [cellclicked]
   'set an editing flag and capture cell coordinates
   editing=1
   curx=int(MouseX/cellW)+1
   cury=int(MouseY/cellH)+1

   [editit]
   'set x and y to locate the textbox at the cell location
   txtX=(curx-1)*cellW+1+gridX
   txtY=(cury-1)*cellH+1+gridY
   #main.txt "!locate ";txtX;" ";txtY;" ";cellW;" ";cellH
   #main "refresh"
   #main.txt cell$(curx,cury)
   #main.txt "!setfocus"
   goto [redraw]

   [okclicked]
   'the user either pressed enter or clicked the ok button
   'set the editing flag, move the textbox off screen and save the changes
   timer 0
   editing=0
   txtX=-100
   txtY=-100
   #main.txt "!locate ";txtX;" ";txtY;" ";cellW;" ";cellH
   #main "refresh"
   #main.txt "!contents? t$"
   cell$(curx,cury)=t$


   [redraw]
   'delete the last segment, redraw all cells and flush
   #main.g "delsegment t"
   #main.g "color ";cellColor$;";backcolor ";cellBackcolor$
   for C=1 to numCols
       for R=1 to numRows
           #main.g "place ";(C-1)*cellW;" ";(R-1)*cellH
           #main.g "boxfilled ";C*cellW+1;" ";R*cellH+1
           #main.g "place ";(C-1)*cellW+8;" ";((R-1)*cellH)+17;";|";cell$(C,R)
       next R
   next C
   #main.g "flush t"

   'now if we are editing start to repeatedly check if the user
   'has moved focus by tabbing, pressing enter or
   'clicking the ok button.

   if editing then
       timer 100, [check]
       wait

       [check]
       'check if we have lost focus
       CallDLL #user32, "GetFocus", h As ulong
       'if focus is not on the textbox check if it
       'is on the ok button and branch accordingly
       if htxt<>h then
           if h=hok then goto [okclicked]
           timer 0
           'save the changes
           #main.txt "!contents? t$"
           cell$(curx,cury)=t$
           'tab to next cell
           curx=curx+1
           if curx>numCols then curx=1 : cury=cury+1
           if cury>numRows then cury=1 : curx=1
           goto [editit]
       end if
   end if
   wait



   [printit]
   timer 0
   #main.g "cls"
   'redraw all cells and flush
   #main.g "delsegment t"
   #main.g "color ";cellColor$;";backcolor ";cellBackcolor$
   for C=1 to numCols
       for R=1 to numRows
           #main.g "place ";(C-1)*cellW;" ";(R-1)*cellH
           #main.g "boxfilled ";C*cellW+1;" ";R*cellH+1
           #main.g "place ";(C-1)*cellW+8;" ";((R-1)*cellH)+17;";|";cell$(C,R)
       next R
   next C
   #main.g "flush t"
   #main.g "print ";gridW+Margin
   wait


   [quit]
   close #main
   end





[johnnyd]

Hi Rod,

That's the very beastie.

With the email autorespoder program, I create a database of entries and encode them, so this, combined with decoding the entries will be perfect.

Cheers Rod!

John.

[meerkat]

Thanks Rod!

Looks Great, and exactly what I need.
My project is too far along and it's suing GRID. So I'm thinking of opening a window or something to enter data on top of each grid x,y location as they enter a cell. I also need a popup for date, time, and color. And I'll need to check each entered key for numeric for number fields.

Thanks for the help..
Dan

[Marco Kurvers]

Rod,

I saw your grid listing. Very good. A nice idea to place one textbox per cell.
I try now to make a module with widgets via graphics commands. Very difficult and maybe it's better to use API. But I am interesting to build self these things. For example your grid.
Is it possible to make in the grid that you can move a line for a sizeable cell? It's a tough challenge to do that.
I made an own spinedit widget with a textbox and two bmpbuttons with the arrows on the buttons. It works fine.

Marco Kurvers

[Rod]

It was Dan Teal that introduced us to the floating textbox. It has been used a lot in various demos. However using a textbox does tie you down to textbox limitations. I sometimes wish I had just mimicked a textbox by drawing it. The downside is that you won’t have copy past, highlight, insert in other than rudimentary form. Text handling is not easy.

[stig]

Rod, thanks! but the code is like a car without an engine. I asked ChatGPT for a skeleton spreadsheet, and it was pretty good. But, I also sit on the source of a fully functional spreadsheet written in MS Basic 1.0 in the early eighties, worked very well. a few hudred lines, and a simplified math parser (relied on parantheses to figure out opererator precedence) Used it to map our ecnomic state of affairs before appliing for an appartment loan. But I liked it, worked

[metro]

In 2006 Janet Terra gave us this, not sure if it helps...

you can load a couple of demo's from the zip attached

there are limitations as outlined in About


' Liberty BASIC Spreadsheet Contest
' Janet Terra  10/29/06
' A very simple offering

   Dim CellInfo$(9, 25)
   CellInfo$(0, 0) = "SUM"
'    CellInfo$(0, 1) = Selected Cell
   Dim CellValue(9, 25)
   Dim CellType(9, 25)
'    CellType = 1 (Number)
'    CellType = 2 (Formula)
'    CellType = 3 (Text Label)
   Dim CellEval$(9, 25)
   Dim SyntaxError$(10)
   SyntaxError$(0) = "0"
   SyntaxError$(1) = "Improper Nesting of Parentheses"
   SyntaxError$(2) = "Invalid Formula"
   SyntaxError$(3) = "Invalid Formula Syntax"
   SyntaxError$(4) = "Invalid Formula Range"
   SyntaxError$(5) = "Invalid Formula Data"
   SyntaxError$(10) = "Unknown Etiology"
   Call MainGUI
   Timer 150, CellDisplay
   Wait

Sub QuitByTrap handle$
   Timer 0
   Close #main
   End
End Sub

Sub QuitByMenu
   Call QuitByTrap "#main"
End Sub

Sub CellDisplay
   Timer 0
   #main.entry, "!Contents? display$"
   CallDLL #user32, "GetFocus", _
       handle As Long
   FindTextbox$ = FindTextbox$(handle)
   col = Asc(Mid$(FindTextbox$, 8, 1)) - 64
   row = Val(Right$(FindTextbox$, 2))
   If FindTextbox$ <> "" Then
       #FindTextbox$, "!Contents? Info$"
       If display$ <> Info$ Then
           If CellType(col, row) = 2 Then
               #main.entry, CellInfo$(col, row)
           Else
               #main.entry, Info$
           End If
       End If
   End If
   Timer 250, CellDisplay
   Wait
End Sub

Sub FileOptions handle$
   Select Right$(handle$, 1)
       Case "1"
           Call SSNew
       Case "2"
           Call SSLoad
       Case "3"
           Call SSSave
       Case "4"
           Call QuitByTrap "#main"
   End Select
End Sub

Sub NewByMenu
   Call SSNew
End Sub

Sub LoadByMenu
   Call SSLoad
End Sub

Sub SaveByMenu
   Call SSSave
End Sub

Sub SSNew
   Redim CellInfo$(9, 25)
   CellInfo$(0, 0) = "SUM"
   Redim CellValue(9, 25)
   For r = 1 to 25
       For c = 1 to 9
           h$ = "#main.0";Chr$(c + 64);Right$("0";r, 2)
           #h$, ""
       Next c
   Next r
   Call ShowTextboxes
   #main.0A01, "!Setfocus"
   CellInfo$(0, 1) = "0A01"
End Sub

Sub SSLoad
   FileDialog "Load LB SpreadSheet", "*.lbss", fileName$
   If fileName$ = "" Then
       Exit Sub
   End If
   Open fileName$ for Input as #1
       For col = 1 to 9
           For row = 1 to 25
               Line Input #1, CellInfo$(col, row)
               Line Input #1, CellValue(col, row)
               Line Input #1, CellType(col, row)
               Line Input #1, CellEval$(col, row)
           Next row
       Next col
   Close #1
   Call ShowTextboxes
   Call RecalculateSpreadSheet
   #main.0A01, "!Setfocus"
   CellInfo$(0, 1) = "0A01"
End Sub

Sub SSSave
   FileDialog "Save LB SpreadSheet as", "*.lbss", fileName$
   If fileName$ = "" Then
       Exit Sub
   End If
   If Instr(fileName$, ".") = 0 Then
       fileName$ = fileName$;".lbss"
   End If
   Open fileName$ for Output as #1
       For col = 1 to 9
           For row = 1 to 25
               #1, CellInfo$(col, row)
               #1, CellValue(col, row)
               #1, CellType(col, row)
               #1, CellEval$(col, row)
           Next row
       Next col
   Close #1
End Sub

Sub AboutNotes
   Run "notepad.exe LBSSJLTNotes.txt"
End Sub

Sub NumberRow row, clr
   h$ = "#main.gb";Right$("0";row, 2)
   #h$, "Down; Cls; Color Black"
   If clr = 1 Then
       #h$, "Fill Buttonface; Backcolor Buttonface"
   Else
       #h$, "Fill 128 192 192; Backcolor 128 192 192"
   End If
   #h$, "Font Times_New_Roman 12"
   n$ = Str$(row)
   #h$, "Stringwidth? n$ wdth"
   #h$, "Place ";14 - wdth/2;" 14"
   #h$, "\";row
   #h$, "Flush"
End Sub

Sub LetterCol col, clr
   h$ = "#main.gb0";Chr$(col + 64)
   #h$, "Down; Cls; Color Black"
   If clr = 1 Then
       #h$, "Fill Buttonface; Backcolor Buttonface"
   Else
       #h$, "Fill 128 192 192; Backcolor 128 192 192"
   End If
   #h$, "Font Times_New_Roman 12"
   n$ = Chr$(col + 64)
   #h$, "Stringwidth? n$ wdth"
   #h$, "Place ";38 - wdth/2;" 14"
   #h$, "\";n$
   #h$, "Flush"
End Sub

Sub HideTextboxes
   For r = 1 to 25
       For c = 1 to 9
           h$ = "#main.0";Chr$(c + 64);Right$("0";r, 2)
           #h$, "!Hide"
       Next c
   Next r
End Sub

Sub ShowTextboxes
   For r = 1 to 25
       For c = 1 to 9
           h$ = "#main.0";Chr$(c + 64);Right$("0";r, 2)
           #h$, "!Show"
       Next c
   Next r
End Sub

Sub EnterKey handle$
   SyntaxError$(0) = "0"
   CallDLL #user32, "GetFocus", _
       handle As Long
   FindTextbox$ = FindTextbox$(handle)
   CellInfo$(0, 2) = FindTextbox$
   col = Asc(Mid$(FindTextbox$, 8, 1)) - 64
   row = Val(Right$(FindTextbox$, 2))
   #main.entry, CellInfo$(col, row)
   #FindTextbox$, "!Contents? txt$"
   CellInfo$(0, 9) = txt$
   CellInfo$(0, 10) = Upper$(RemoveSpaces$(txt$))
   IsNumber$ = IsNumber$(txt$)
   If IsNumber$ <> "" Then
       #FindTextbox$, IsNumber$
       CellInfo$(col, row) = IsNumber$
       CellValue(col, row) = Val(IsNumber$)
       CellType(col, row) = 1
       CellEval$(col, row) = IsNumber$
   End If
   IsFormula$ = IsFormula$(txt$)
   If IsFormula$ <> "" Then
       CellInfo$(col, row) = IsFormula$
       CellValue(col, row) = Eval(CellEval$(col, row))
       #main.entry, IsFormula$
       #FindTextbox$, CellValue(col, row)
       CellType(col, row) = 2
   End If
   IsTextLabel$ = IsNumber$;IsFormula$;txt$
   If IsTextLabel$ = txt$ Then
       CellInfo$(col, row) = txt$
       CellValue(col, row) = 0
       CellType(col, row) = 3
       #main.entry, txt$
       #FindTextbox$, txt$
   End If
   NextTextbox$ = NextTextbox$(FindTextbox$)
   CellInfo$(0, 1) = Word$(NextTextbox$, 2, ".")
   col = Asc(Mid$(CellInfo$(0, 1), 2, 1)) - 64
   row = Val(Right$(CellInfo$(0, 1), 2))
   Select Case CellType(col, row)
       Case 1 ' Number
           #main.entry, CellInfo$(col, row)
           #NextTextbox$, CellValue(col, row)
       Case 2 ' Formula
           #main.entry, CellInfo$(col, row)
           #NextTextbox$, CellInfo$(col, row)
       Case 0, 3 ' Text Label
           #main.entry, CellInfo$(col, row)
           #NextTextbox$, CellValue(col, row)
   End Select
   Call RecalculateSpreadSheet
   #NextTextbox$, CellInfo$(col, row)
   #NextTextbox$, "!Contents? txt$"
   #main.entry, txt$
   #NextTextbox$, "!Setfocus"
   Call CaretAtEnd NextTextbox$
   #NextTextbox$, "!Setfocus"
End Sub

Sub RecalculateSpreadSheet
   For col = 1 to 9
       For row = 1 to 25
           col$ = "0";Chr$(col + 64)
           row$ = Right$("0";row, 2)
           txtbx$ = "#main.";col$;row$
           Select Case CellType(col, row)
               Case 1, 2
                   CellValue(col, row) = Eval(CellEval$(col, row))
                   #txtbx$, CellValue(col, row)
               Case 0, 3
                   #txtbx$, CellInfo$(col, row)
           End Select
       Next row
   Next col
End Sub

Function IsNumber$(txt$)
   IsNumber$ = txt$
   num$ = " 0123456789,.-"
   For i = 1 to Len(txt$)
       If Instr(num$, Mid$(txt$, i, 1)) = 0 Then
           IsNumber$ = ""
       End If
       If Mid$(txt$, i, 1) <> Chr$(32) Then
           If Mid$(txt$, i, 1) <> "," Then
               n$ = n$;Mid$(txt$, i, 1)
           End If
       End If
   Next i
   If Instr(n$, "-") > 1 Then
       IsNumber$ = ""
   End If
   If Instr(Mid$(n$, 2), "-") > 0 Then
       IsNumber$ = ""
   End If
   If IsNumber$ <> "" Then
       IsNumber$ = n$
   End If
End Function

Function IsFormula$(txt$)
   If Trim$(txt$) = "=" Then
       IsFormula$ = ""
       Exit Function
   End If
   txt$ = Upper$(txt$)
   col = Asc(Mid$(CellInfo$(0, 2), 8, 1)) - 64
   row = Val(Right$(CellInfo$(0, 2), 2))
   txt$ = RemoveSpaces$(txt$)
   IsFormula$ = txt$
   If Left$(Trim$(txt$), 1) <> "=" Then
       IsFormula$ = ""
       SyntaxError$(0) = "0"
       Exit Function
   End If
   txt$ = Mid$(txt$, 2)
   If nParentheses(txt$) = -1 Then
       IsFormula$ = ""
       SyntaxError$(0) = "1"
       Exit Function
   End If
   While Instr(txt$, ":") > 0
       ExtractRange$ = ExtractRange$(txt$)
       If ExtractRange$ = "Error" Then
           Exit While
       Else
           If Left$(ExtractRange$, 1) <> "=" Then
               txt$ = "=";ExtractRange$
           Else
               txt$ = ExtractRange$
           End If
       End If
   Wend
   If Left$(txt$, 1) <> "=" Then
       txt$ = "=";txt$
   End If
   For i = 1 to Len(txt$)
       t$ = Upper$(Mid$(txt$, i, 1))
       Select Case t$
           Case "A", "B", "C", "D", "E", "F", "G", "H", "I"
               nxt$ = Mid$(txt$, i + 1, 1)
               If Val(nxt$) > 0 Then
                   txt$ = Left$(txt$, i - 1);Lower$(t$);Mid$(txt$, i + 1)
               End If
       End Select
   Next i
   TranscribeCell$ = TranscribeCell$(txt$)
   CellSel$ = "CellValue(";col;",";row;")"
   If Instr(TranscribeCell$, CellSel$) Then
       SyntaxError$(0) = "4"
       IsFormula$ = ""
       Exit Function
   End If
   #main.entry, CellInfo$(0, 10)
   cell$ = "#main.0";Chr$(col + 64);Right$("0";row, 2)
   CellEval$(col, row) = Mid$(TranscribeCell$, 2)
   #cell$, Eval(CellEval$(col, row))
' Parse for Valid Operands
   Operand$ = "ABS SIN COS TAN ASN ACS ATN EXP " + _
       "LOG HEXDEC DECHEX$ INT MAX MIN MOD RND SQR"
End Function

Function TranscribeCell$(txt$)
   TranscribeCell$ = ""
   For i = 1 to Len(txt$)
       t$ = Mid$(txt$, i, 1)
       If t$ = Upper$(t$) Then
           TranscribeCell$ = TranscribeCell$;t$
       Else
           c = Asc(Upper$(t$)) - 64
           r = Val(Mid$(txt$, i + 1))
           TranscribeCell$ = TranscribeCell$;"CellValue(";c;",";r;")"
           i = i + 1 + (r > 9)
       End If
   Next i
End Function

Function ExtractRange$(txt$)
   col = Asc(Mid$(CellInfo$(0, 2), 8, 1)) - 64
   row = Val(Right$(CellInfo$(0, 2), 2))
   t1$ = Word$(txt$, 1, ":")
   t2$ = Word$(Mid$(txt$, Len(t1$) + 2), 1, ")");")"
   t3$ = Mid$(txt$, Len(t1$) + Len(t2$) + 2)
   rP = Len(t1$)
   While Val(Mid$(t1$, rP)) > 0
       rP = rP - 1
   Wend
   col1 = Asc(Mid$(t1$, rP, 1)) - 64
   row1 = Val(Mid$(t1$, rP + 1))
   par1 = rP - 1
   If Mid$(t1$, par1, 1) <> "(" Then
       SyntaxError$(0) = "3"
       ExtractRange$ = ""
       Exit Function
   End If
   If par1 < 4 Then
       SyntaxError$(0) = "3"
       ExtractRange$ = ""
       Exit Function
   End If
   Formula$ = Mid$(t1$, par1 - 3, 3)
   If Instr(CellInfo$(0, 0), Formula$) = 0 Then
       SyntaxError$(0) = "2"
       ExtractRange$ = ""
       Exit Function
   End If
   t0$ = Left$(t1$, par1 - 4)
   t1$ = Mid$(t1$, Len(t0$) + 1)
   col2 = Asc(Left$(t2$, 1)) - 64
   row2 = Val(Mid$(t2$, 2))
   par2 = 3 + Int(row2 / 10)
   par2$ = Mid$(t2$, par2, 1)
   If par2$ <> ")" Then
       SyntaxError$(0) = "3"
       ExtractRange$ = ""
       Exit Function
   End If
   If col1 > col2 Then
       temp = col1
       col1 = col2
       col2 = temp
   End If
   If row1 > row2 Then
       temp = row1
       row1 = row2
       row2 = temp
   End If
   Select Case
       Case (col = col1) and (col = col2)
           If row >= row1 Then
               If row <= row2 Then
                   SyntaxError$(0) = "4"
                   ExtractRange$ = ""
                   Exit Function
               End If
           End If
       Case (col = col1) or (col = col2)
           If (row = row1) or (row = row2) Then
               SyntaxError$(0) = "4"
               ExtractRange$ = ""
               Exit Function
           End If
       Case (row = row1) and (row = row2)
           If col >= col1 Then
               If col <= col2 Then
                   SyntaxError$(0) = "4"
                   ExtractRange$ = ""
                   Exit Function
               End If
           End If
       Case (row = row1) or (row = row2)
           If (col = col1) or (col = col2) Then
               SyntaxError$(0) = "4"
               ExtractRange$ = ""
               Exit Function
           End If
   End Select
   Select Case
       Case col1 = col2
           range = 1
       Case row1 = row2
           range = 2
       Case Else
           SyntaxError$(0) = "4"
           ExtractRange$ = ""
           Exit Function
   End Select
   range$ = ""
   Select Case range
       Case 1
           c$ = Lower$(Chr$(col1 + 64))
           For i = row1 to row2
               range$ = range$;"+";c$;Str$(i)
           Next i
           nRows = row2 - row1 + 1
       Case 2
           r$ = Str$(row1)
           For i = col1 to col2
               range$ = range$;"+";Lower$(Chr$(i + 64));r$
           Next i
   End Select
   ExtractRange$ = t0$;"(";Mid$(range$, 2);")";t3$
End Function

Function RemoveSpaces$(txt$)
   RemoveSpaces$ = ""
   For i = 1 to Len(txt$)
       If Mid$(txt$, i, 1) <> Chr$(32) Then
           RemoveSpaces$ = RemoveSpaces$;Mid$(txt$, i, 1)
       End If
   Next i
End Function

Function nParentheses(txt$)
   p1 = 0 : p2 = 0
   For i = 1 to Len(txt$)
       If Mid$(txt$, i, 1) = "(" Then
           p1 = p1 + 1
       End If
       If Mid$(txt$, i, 1) = ")" Then
           p2 = p2 + 1
       End If
   Next i
   If p1 <> p2 Then
       nParentheses = -1
   Else
       nParentheses = p1
   End If
End Function

Function FindTextbox$(handle)
   FindTextbox$ = ""
   For r = 1 to 25
       For c = 1 to 9
           h$ = "#main.0";Chr$(c + 64);Right$("0";r, 2)
           If hWnd(#h$) = handle Then
               FindTextbox$ = h$
               col = c
               row = r
           End If
       Next c
   Next r
   #h$, "!Contents? txt$"
   CellInfo$(0, 1) = txt$
   ' If CellInfo$(col, row) <> txt$ Then update cell contents
End Function

Function NextTextbox$(FindTextbox$)
   c = Asc(Mid$(FindTextbox$, 8)) - 64
   r = Val(Right$(FindTextbox$, 2))
   Select Case r
       Case 25
       r = 1
       Case Else
       r = r + 1
   End Select
   NextTextbox$ = "#main.0";Chr$(c + 64);Right$("0";r, 2)
End Function

Sub UpdateSpreadSheet
   For row = 1 to 25
       For col = 1 to 9
           h$ = "#main.0";Chr$(64 + col);Right$("0";row, 2)
           Select Case CellType(col, row)
               Case 1
                   #h$, CellValue(col, row)
               Case 2
                   #h$, Eval(CellEval$(col, row))
               Case 3
                   #h$, CellInfo$(col, row)
           End Select
       Next col
   Next row
End Sub

Sub CaretAtEnd hTBox$
   hTBox = hWnd(#hTBox$)
   #hTBox$, "!Contents? txt$"
   pos = Len(txt$)
   CallDLL #user32, "SendMessageA", _
       hTBox as Ulong, _
       _EM_SETSEL as Long, _
       pos as Long, _
       pos as Long, _
       result as Long
End Sub

Sub MainGUI
   WindowWidth = 800
   WindowHeight = 600

   UpperLeftX = Int((DisplayWidth - WindowWidth) /2)
   UpperLeftY = Int((DisplayHeight - WindowHeight) /2)

   Menu #main, "&Options", "&New", NewByMenu, "&Load", LoadByMenu, "&Save", _
       SaveByMenu,|, "E&xit", QuitByMenu
   Menu #main, "&About", "&Program Notes", AboutNotes
   Bmpbutton #main.opt1, "sym01.bmp", FileOptions, UL, 0, 1
   Bmpbutton #main.opt2, "sym02.bmp", FileOptions, UL, 30, 1
   Bmpbutton #main.opt3, "sym03.bmp", FileOptions, UL, 60, 1
   Bmpbutton #main.opt4, "sym04.bmp", FileOptions, UL, 90, 1

   Graphicbox #main.gb00, 0, 24, 30, 20
   Graphicbox #main.gb01, 0, 44, 30, 20
   Graphicbox #main.gb02, 0, 64, 30, 20
   Graphicbox #main.gb03, 0, 84, 30, 20
   Graphicbox #main.gb04, 0, 104, 30, 20
   Graphicbox #main.gb05, 0, 124, 30, 20
   Graphicbox #main.gb06, 0, 144, 30, 20
   Graphicbox #main.gb07, 0, 164, 30, 20
   Graphicbox #main.gb08, 0, 184, 30, 20
   Graphicbox #main.gb09, 0, 204, 30, 20
   Graphicbox #main.gb10, 0, 224, 30, 20
   Graphicbox #main.gb11, 0, 244, 30, 20
   Graphicbox #main.gb12, 0, 264, 30, 20
   Graphicbox #main.gb13, 0, 284, 30, 20
   Graphicbox #main.gb14, 0, 304, 30, 20
   Graphicbox #main.gb15, 0, 324, 30, 20
   Graphicbox #main.gb16, 0, 344, 30, 20
   Graphicbox #main.gb17, 0, 364, 30, 20
   Graphicbox #main.gb18, 0, 384, 30, 20
   Graphicbox #main.gb19, 0, 404, 30, 20
   Graphicbox #main.gb20, 0, 424, 30, 20
   Graphicbox #main.gb21, 0, 444, 30, 20
   Graphicbox #main.gb22, 0, 464, 30, 20
   Graphicbox #main.gb23, 0, 484, 30, 20
   Graphicbox #main.gb24, 0, 504, 30, 20
   Graphicbox #main.gb25, 0, 524, 30, 20
   Graphicbox #main.gb0A, 30, 24, 80, 20
   Graphicbox #main.gb0B, 110, 24, 80, 20
   Graphicbox #main.gb0C, 190, 24, 80, 20
   Graphicbox #main.gb0D, 270, 24, 80, 20
   Graphicbox #main.gb0E, 350, 24, 80, 20
   Graphicbox #main.gb0F, 430, 24, 80, 20
   Graphicbox #main.gb0G, 510, 24, 80, 20
   Graphicbox #main.gb0H, 590, 24, 80, 20
   Graphicbox #main.gb0I, 670, 24, 80, 20
   Graphicbox #main.fb01, 750, 0, 42, 545
   Stylebits #main.0A01, _ES_RIGHT, _WS_BORDER or _WS_VISIBLE, 0, 0
   Textbox #main.0A01, 30, 44, 80, 20
   Stylebits #main.0B01, _ES_RIGHT, _WS_BORDER or _WS_VISIBLE, 0, 0
   Textbox #main.0B01, 110, 44, 80, 20
   Stylebits #main.0C01, _ES_RIGHT, _WS_BORDER or _WS_VISIBLE, 0, 0
   Textbox #main.0C01, 190, 44, 80, 20
   Stylebits #main.0D01, _ES_RIGHT, _WS_BORDER or _WS_VISIBLE, 0, 0
   Textbox #main.0D01, 270, 44, 80, 20
   Stylebits #main.0E01, _ES_RIGHT, _WS_BORDER or _WS_VISIBLE, 0, 0
   Textbox #main.0E01, 350, 44, 80, 20
   Stylebits #main.0F01, _ES_RIGHT, _WS_BORDER or _WS_VISIBLE, 0, 0
   Textbox #main.0F01, 430, 44, 80, 20
   Stylebits #main.0G01, _ES_RIGHT, _WS_BORDER or _WS_VISIBLE, 0, 0
   Textbox #main.0G01, 510, 44, 80, 20
   Stylebits #main.0H01, _ES_RIGHT, _WS_BORDER or _WS_VISIBLE, 0, 0
   Textbox #main.0H01, 590, 44, 80, 20
   Stylebits #main.0I01, _ES_RIGHT, _WS_BORDER or _WS_VISIBLE, 0, 0
   Textbox #main.0I01, 670, 44, 80, 20
   Stylebits #main.0A02, _ES_RIGHT, _WS_BORDER or _WS_VISIBLE, 0, 0
   Textbox #main.0A02, 30, 64, 80, 20
   Stylebits #main.0B02, _ES_RIGHT, _WS_BORDER or _WS_VISIBLE, 0, 0
   Textbox #main.0B02, 110, 64, 80, 20
   Stylebits #main.0C02, _ES_RIGHT, _WS_BORDER or _WS_VISIBLE, 0, 0
   Textbox #main.0C02, 190, 64, 80, 20
   Stylebits #main.0D02, _ES_RIGHT, _WS_BORDER or _WS_VISIBLE, 0, 0
   Textbox #main.0D02, 270, 64, 80, 20
   Stylebits #main.0E02, _ES_RIGHT, _WS_BORDER or _WS_VISIBLE, 0, 0
   Textbox #main.0E02, 350, 64, 80, 20
   Stylebits #main.0F02, _ES_RIGHT, _WS_BORDER or _WS_VISIBLE, 0, 0
   Textbox #main.0F02, 430, 64, 80, 20
   Stylebits #main.0G02, _ES_RIGHT, _WS_BORDER or _WS_VISIBLE, 0, 0
   Textbox #main.0G02, 510, 64, 80, 20
   Stylebits #main.0H02, _ES_RIGHT, _WS_BORDER or _WS_VISIBLE, 0, 0
   Textbox #main.0H02, 590, 64, 80, 20
   Stylebits #main.0I02, _ES_RIGHT, _WS_BORDER or _WS_VISIBLE, 0, 0
   Textbox #main.0I02, 670, 64, 80, 20
   Stylebits #main.0A03, _ES_RIGHT, _WS_BORDER or _WS_VISIBLE, 0, 0
   Textbox #main.0A03, 30, 84, 80, 20
   Stylebits #main.0B03, _ES_RIGHT, _WS_BORDER or _WS_VISIBLE, 0, 0
   Textbox #main.0B03, 110, 84, 80, 20
   Stylebits #main.0C03, _ES_RIGHT, _WS_BORDER or _WS_VISIBLE, 0, 0
   Textbox #main.0C03, 190, 84, 80, 20
   Stylebits #main.0D03, _ES_RIGHT, _WS_BORDER or _WS_VISIBLE, 0, 0
   Textbox #main.0D03, 270, 84, 80, 20
   Stylebits #main.0E03, _ES_RIGHT, _WS_BORDER or _WS_VISIBLE, 0, 0
   Textbox #main.0E03, 350, 84, 80, 20
   Stylebits #main.0F03, _ES_RIGHT, _WS_BORDER or _WS_VISIBLE, 0, 0
   Textbox #main.0F03, 430, 84, 80, 20
   Stylebits #main.0G03, _ES_RIGHT, _WS_BORDER or _WS_VISIBLE, 0, 0
   Textbox #main.0G03, 510, 84, 80, 20
   Stylebits #main.0H03, _ES_RIGHT, _WS_BORDER or _WS_VISIBLE, 0, 0
   Textbox #main.0H03, 590, 84, 80, 20
   Stylebits #main.0I03, _ES_RIGHT, _WS_BORDER or _WS_VISIBLE, 0, 0
   Textbox #main.0I03, 670, 84, 80, 20
   Stylebits #main.0A04, _ES_RIGHT, _WS_BORDER or _WS_VISIBLE, 0, 0
   Textbox #main.0A04, 30, 104, 80, 20
   Stylebits #main.0B04, _ES_RIGHT, _WS_BORDER or _WS_VISIBLE, 0, 0
   Textbox #main.0B04, 110, 104, 80, 20
   Stylebits #main.0C04, _ES_RIGHT, _WS_BORDER or _WS_VISIBLE, 0, 0
   Textbox #main.0C04, 190, 104, 80, 20
   Stylebits #main.0D04, _ES_RIGHT, _WS_BORDER or _WS_VISIBLE, 0, 0
   Textbox #main.0D04, 270, 104, 80, 20
   Stylebits #main.0E04, _ES_RIGHT, _WS_BORDER or _WS_VISIBLE, 0, 0
   Textbox #main.0E04, 350, 104, 80, 20
   Stylebits #main.0F04, _ES_RIGHT, _WS_BORDER or _WS_VISIBLE, 0, 0
   Textbox #main.0F04, 430, 104, 80, 20
   Stylebits #main.0G04, _ES_RIGHT, _WS_BORDER or _WS_VISIBLE, 0, 0
   Textbox #main.0G04, 510, 104, 80, 20
   Stylebits #main.0H04, _ES_RIGHT, _WS_BORDER or _WS_VISIBLE, 0, 0
   Textbox #main.0H04, 590, 104, 80, 20
   Stylebits #main.0I04, _ES_RIGHT, _WS_BORDER or _WS_VISIBLE, 0, 0
   Textbox #main.0I04, 670, 104, 80, 20
   Stylebits #main.0A05, _ES_RIGHT, _WS_BORDER or _WS_VISIBLE, 0, 0
   Textbox #main.0A05, 30, 124, 80, 20
   Stylebits #main.0B05, _ES_RIGHT, _WS_BORDER or _WS_VISIBLE, 0, 0
   Textbox #main.0B05, 110, 124, 80, 20
   Stylebits #main.0C05, _ES_RIGHT, _WS_BORDER or _WS_VISIBLE, 0, 0
   Textbox #main.0C05, 190, 124, 80, 20
   Stylebits #main.0D05, _ES_RIGHT, _WS_BORDER or _WS_VISIBLE, 0, 0
   Textbox #main.0D05, 270, 124, 80, 20
   Stylebits #main.0E05, _ES_RIGHT, _WS_BORDER or _WS_VISIBLE, 0, 0
   Textbox #main.0E05, 350, 124, 80, 20
   Stylebits #main.0F05, _ES_RIGHT, _WS_BORDER or _WS_VISIBLE, 0, 0
   Textbox #main.0F05, 430, 124, 80, 20
   Stylebits #main.0G05, _ES_RIGHT, _WS_BORDER or _WS_VISIBLE, 0, 0
   Textbox #main.0G05, 510, 124, 80, 20
   Stylebits #main.0H05, _ES_RIGHT, _WS_BORDER or _WS_VISIBLE, 0, 0
   Textbox #main.0H05, 590, 124, 80, 20
   Stylebits #main.0I05, _ES_RIGHT, _WS_BORDER or _WS_VISIBLE, 0, 0
   Textbox #main.0I05, 670, 124, 80, 20
   Stylebits #main.0A06, _ES_RIGHT, _WS_BORDER or _WS_VISIBLE, 0, 0
   Textbox #main.0A06, 30, 144, 80, 20
   Stylebits #main.0B06, _ES_RIGHT, _WS_BORDER or _WS_VISIBLE, 0, 0
   Textbox #main.0B06, 110, 144, 80, 20
   Stylebits #main.0C06, _ES_RIGHT, _WS_BORDER or _WS_VISIBLE, 0, 0
   Textbox #main.0C06, 190, 144, 80, 20
   Stylebits #main.0D06, _ES_RIGHT, _WS_BORDER or _WS_VISIBLE, 0, 0
   Textbox #main.0D06, 270, 144, 80, 20
   Stylebits #main.0E06, _ES_RIGHT, _WS_BORDER or _WS_VISIBLE, 0, 0
   Textbox #main.0E06, 350, 144, 80, 20
   Stylebits #main.0F06, _ES_RIGHT, _WS_BORDER or _WS_VISIBLE, 0, 0
   Textbox #main.0F06, 430, 144, 80, 20
   Stylebits #main.0G06, _ES_RIGHT, _WS_BORDER or _WS_VISIBLE, 0, 0
   Textbox #main.0G06, 510, 144, 80, 20
   Stylebits #main.0H06, _ES_RIGHT, _WS_BORDER or _WS_VISIBLE, 0, 0
   Textbox #main.0H06, 590, 144, 80, 20
   Stylebits #main.0I06, _ES_RIGHT, _WS_BORDER or _WS_VISIBLE, 0, 0
   Textbox #main.0I06, 670, 144, 80, 20
   Stylebits #main.0A07, _ES_RIGHT, _WS_BORDER or _WS_VISIBLE, 0, 0
   Textbox #main.0A07, 30, 164, 80, 20
   Stylebits #main.0B07, _ES_RIGHT, _WS_BORDER or _WS_VISIBLE, 0, 0
   Textbox #main.0B07, 110, 164, 80, 20
   Stylebits #main.0C07, _ES_RIGHT, _WS_BORDER or _WS_VISIBLE, 0, 0
   Textbox #main.0C07, 190, 164, 80, 20
   Stylebits #main.0D07, _ES_RIGHT, _WS_BORDER or _WS_VISIBLE, 0, 0
   Textbox #main.0D07, 270, 164, 80, 20
   Stylebits #main.0E07, _ES_RIGHT, _WS_BORDER or _WS_VISIBLE, 0, 0
   Textbox #main.0E07, 350, 164, 80, 20
   Stylebits #main.0F07, _ES_RIGHT, _WS_BORDER or _WS_VISIBLE, 0, 0
   Textbox #main.0F07, 430, 164, 80, 20
   Stylebits #main.0G07, _ES_RIGHT, _WS_BORDER or _WS_VISIBLE, 0, 0
   Textbox #main.0G07, 510, 164, 80, 20
   Stylebits #main.0H07, _ES_RIGHT, _WS_BORDER or _WS_VISIBLE, 0, 0
   Textbox #main.0H07, 590, 164, 80, 20
   Stylebits #main.0I07, _ES_RIGHT, _WS_BORDER or _WS_VISIBLE, 0, 0
   Textbox #main.0I07, 670, 164, 80, 20
   Stylebits #main.0A08, _ES_RIGHT, _WS_BORDER or _WS_VISIBLE, 0, 0
   Textbox #main.0A08, 30, 184, 80, 20
   Stylebits #main.0B08, _ES_RIGHT, _WS_BORDER or _WS_VISIBLE, 0, 0
   Textbox #main.0B08, 110, 184, 80, 20
   Stylebits #main.0C08, _ES_RIGHT, _WS_BORDER or _WS_VISIBLE, 0, 0
   Textbox #main.0C08, 190, 184, 80, 20
   Stylebits #main.0D08, _ES_RIGHT, _WS_BORDER or _WS_VISIBLE, 0, 0
   Textbox #main.0D08, 270, 184, 80, 20
   Stylebits #main.0E08, _ES_RIGHT, _WS_BORDER or _WS_VISIBLE, 0, 0
   Textbox #main.0E08, 350, 184, 80, 20
   Stylebits #main.0F08, _ES_RIGHT, _WS_BORDER or _WS_VISIBLE, 0, 0
   Textbox #main.0F08, 430, 184, 80, 20
   Stylebits #main.0G08, _ES_RIGHT, _WS_BORDER or _WS_VISIBLE, 0, 0
   Textbox #main.0G08, 510, 184, 80, 20
   Stylebits #main.0H08, _ES_RIGHT, _WS_BORDER or _WS_VISIBLE, 0, 0
   Textbox #main.0H08, 590, 184, 80, 20
   Stylebits #main.0I08, _ES_RIGHT, _WS_BORDER or _WS_VISIBLE, 0, 0
   Textbox #main.0I08, 670, 184, 80, 20
   Stylebits #main.0A09, _ES_RIGHT, _WS_BORDER or _WS_VISIBLE, 0, 0
   Textbox #main.0A09, 30, 204, 80, 20
   Stylebits #main.0B09, _ES_RIGHT, _WS_BORDER or _WS_VISIBLE, 0, 0
   Textbox #main.0B09, 110, 204, 80, 20
   Stylebits #main.0C09, _ES_RIGHT, _WS_BORDER or _WS_VISIBLE, 0, 0
   Textbox #main.0C09, 190, 204, 80, 20
   Stylebits #main.0D09, _ES_RIGHT, _WS_BORDER or _WS_VISIBLE, 0, 0
   Textbox #main.0D09, 270, 204, 80, 20
   Stylebits #main.0E09, _ES_RIGHT, _WS_BORDER or _WS_VISIBLE, 0, 0
   Textbox #main.0E09, 350, 204, 80, 20
   Stylebits #main.0F09, _ES_RIGHT, _WS_BORDER or _WS_VISIBLE, 0, 0
   Textbox #main.0F09, 430, 204, 80, 20
   Stylebits #main.0G09, _ES_RIGHT, _WS_BORDER or _WS_VISIBLE, 0, 0
   Textbox #main.0G09, 510, 204, 80, 20
   Stylebits #main.0H09, _ES_RIGHT, _WS_BORDER or _WS_VISIBLE, 0, 0
   Textbox #main.0H09, 590, 204, 80, 20
   Stylebits #main.0I09, _ES_RIGHT, _WS_BORDER or _WS_VISIBLE, 0, 0
   Textbox #main.0I09, 670, 204, 80, 20
   Stylebits #main.0A10, _ES_RIGHT, _WS_BORDER or _WS_VISIBLE, 0, 0
   Textbox #main.0A10, 30, 224, 80, 20
   Stylebits #main.0B10, _ES_RIGHT, _WS_BORDER or _WS_VISIBLE, 0, 0
   Textbox #main.0B10, 110, 224, 80, 20
   Stylebits #main.0C10, _ES_RIGHT, _WS_BORDER or _WS_VISIBLE, 0, 0
   Textbox #main.0C10, 190, 224, 80, 20
   Stylebits #main.0D10, _ES_RIGHT, _WS_BORDER or _WS_VISIBLE, 0, 0
   Textbox #main.0D10, 270, 224, 80, 20
   Stylebits #main.0E10, _ES_RIGHT, _WS_BORDER or _WS_VISIBLE, 0, 0
   Textbox #main.0E10, 350, 224, 80, 20
   Stylebits #main.0F10, _ES_RIGHT, _WS_BORDER or _WS_VISIBLE, 0, 0
   Textbox #main.0F10, 430, 224, 80, 20
   Stylebits #main.0G10, _ES_RIGHT, _WS_BORDER or _WS_VISIBLE, 0, 0
   Textbox #main.0G10, 510, 224, 80, 20
   Stylebits #main.0H10, _ES_RIGHT, _WS_BORDER or _WS_VISIBLE, 0, 0
   Textbox #main.0H10, 590, 224, 80, 20
   Stylebits #main.0I10, _ES_RIGHT, _WS_BORDER or _WS_VISIBLE, 0, 0
   Textbox #main.0I10, 670, 224, 80, 20
   Stylebits #main.0A11, _ES_RIGHT, _WS_BORDER or _WS_VISIBLE, 0, 0
   Textbox #main.0A11, 30, 244, 80, 20
   Stylebits #main.0B11, _ES_RIGHT, _WS_BORDER or _WS_VISIBLE, 0, 0
   Textbox #main.0B11, 110, 244, 80, 20
   Stylebits #main.0C11, _ES_RIGHT, _WS_BORDER or _WS_VISIBLE, 0, 0
   Textbox #main.0C11, 190, 244, 80, 20
   Stylebits #main.0D11, _ES_RIGHT, _WS_BORDER or _WS_VISIBLE, 0, 0
   Textbox #main.0D11, 270, 244, 80, 20
   Stylebits #main.0E11, _ES_RIGHT, _WS_BORDER or _WS_VISIBLE, 0, 0
   Textbox #main.0E11, 350, 244, 80, 20
   Stylebits #main.0F11, _ES_RIGHT, _WS_BORDER or _WS_VISIBLE, 0, 0
   Textbox #main.0F11, 430, 244, 80, 20
   Stylebits #main.0G11, _ES_RIGHT, _WS_BORDER or _WS_VISIBLE, 0, 0
   Textbox #main.0G11, 510, 244, 80, 20
   Stylebits #main.0H11, _ES_RIGHT, _WS_BORDER or _WS_VISIBLE, 0, 0
   Textbox #main.0H11, 590, 244, 80, 20
   Stylebits #main.0I11, _ES_RIGHT, _WS_BORDER or _WS_VISIBLE, 0, 0
   Textbox #main.0I11, 670, 244, 80, 20
   Stylebits #main.0A12, _ES_RIGHT, _WS_BORDER or _WS_VISIBLE, 0, 0
   Textbox #main.0A12, 30, 264, 80, 20
   Stylebits #main.0B12, _ES_RIGHT, _WS_BORDER or _WS_VISIBLE, 0, 0
   Textbox #main.0B12, 110, 264, 80, 20
   Stylebits #main.0C12, _ES_RIGHT, _WS_BORDER or _WS_VISIBLE, 0, 0
   Textbox #main.0C12, 190, 264, 80, 20
   Stylebits #main.0D12, _ES_RIGHT, _WS_BORDER or _WS_VISIBLE, 0, 0
   Textbox #main.0D12, 270, 264, 80, 20
   Stylebits #main.0E12, _ES_RIGHT, _WS_BORDER or _WS_VISIBLE, 0, 0
   Textbox #main.0E12, 350, 264, 80, 20
   Stylebits #main.0F12, _ES_RIGHT, _WS_BORDER or _WS_VISIBLE, 0, 0
   Textbox #main.0F12, 430, 264, 80, 20
   Stylebits #main.0G12, _ES_RIGHT, _WS_BORDER or _WS_VISIBLE, 0, 0
   Textbox #main.0G12, 510, 264, 80, 20
   Stylebits #main.0H12, _ES_RIGHT, _WS_BORDER or _WS_VISIBLE, 0, 0
   Textbox #main.0H12, 590, 264, 80, 20
   Stylebits #main.0I12, _ES_RIGHT, _WS_BORDER or _WS_VISIBLE, 0, 0
   Textbox #main.0I12, 670, 264, 80, 20
   Stylebits #main.0A13, _ES_RIGHT, _WS_BORDER or _WS_VISIBLE, 0, 0
   Textbox #main.0A13, 30, 284, 80, 20
   Stylebits #main.0B13, _ES_RIGHT, _WS_BORDER or _WS_VISIBLE, 0, 0
   Textbox #main.0B13, 110, 284, 80, 20
   Stylebits #main.0C13, _ES_RIGHT, _WS_BORDER or _WS_VISIBLE, 0, 0
   Textbox #main.0C13, 190, 284, 80, 20
   Stylebits #main.0D13, _ES_RIGHT, _WS_BORDER or _WS_VISIBLE, 0, 0
   Textbox #main.0D13, 270, 284, 80, 20
   Stylebits #main.0E13, _ES_RIGHT, _WS_BORDER or _WS_VISIBLE, 0, 0
   Textbox #main.0E13, 350, 284, 80, 20
   Stylebits #main.0F13, _ES_RIGHT, _WS_BORDER or _WS_VISIBLE, 0, 0
   Textbox #main.0F13, 430, 284, 80, 20
   Stylebits #main.0G13, _ES_RIGHT, _WS_BORDER or _WS_VISIBLE, 0, 0
   Textbox #main.0G13, 510, 284, 80, 20
   Stylebits #main.0H13, _ES_RIGHT, _WS_BORDER or _WS_VISIBLE, 0, 0
   Textbox #main.0H13, 590, 284, 80, 20
   Stylebits #main.0I13, _ES_RIGHT, _WS_BORDER or _WS_VISIBLE, 0, 0
   Textbox #main.0I13, 670, 284, 80, 20
   Stylebits #main.0A14, _ES_RIGHT, _WS_BORDER or _WS_VISIBLE, 0, 0
   Textbox #main.0A14, 30, 304, 80, 20
   Stylebits #main.0B14, _ES_RIGHT, _WS_BORDER or _WS_VISIBLE, 0, 0
   Textbox #main.0B14, 110, 304, 80, 20
   Stylebits #main.0C14, _ES_RIGHT, _WS_BORDER or _WS_VISIBLE, 0, 0
   Textbox #main.0C14, 190, 304, 80, 20
   Stylebits #main.0D14, _ES_RIGHT, _WS_BORDER or _WS_VISIBLE, 0, 0
   Textbox #main.0D14, 270, 304, 80, 20
   Stylebits #main.0E14, _ES_RIGHT, _WS_BORDER or _WS_VISIBLE, 0, 0
   Textbox #main.0E14, 350, 304, 80, 20
   Stylebits #main.0F14, _ES_RIGHT, _WS_BORDER or _WS_VISIBLE, 0, 0
   Textbox #main.0F14, 430, 304, 80, 20
   Stylebits #main.0G14, _ES_RIGHT, _WS_BORDER or _WS_VISIBLE, 0, 0
   Textbox #main.0G14, 510, 304, 80, 20
   Stylebits #main.0H14, _ES_RIGHT, _WS_BORDER or _WS_VISIBLE, 0, 0
   Textbox #main.0H14, 590, 304, 80, 20
   Stylebits #main.0I14, _ES_RIGHT, _WS_BORDER or _WS_VISIBLE, 0, 0
   Textbox #main.0I14, 670, 304, 80, 20
   Stylebits #main.0A15, _ES_RIGHT, _WS_BORDER or _WS_VISIBLE, 0, 0
   Textbox #main.0A15, 30, 324, 80, 20
   Stylebits #main.0B15, _ES_RIGHT, _WS_BORDER or _WS_VISIBLE, 0, 0
   Textbox #main.0B15, 110, 324, 80, 20
   Stylebits #main.0C15, _ES_RIGHT, _WS_BORDER or _WS_VISIBLE, 0, 0
   Textbox #main.0C15, 190, 324, 80, 20
   Stylebits #main.0D15, _ES_RIGHT, _WS_BORDER or _WS_VISIBLE, 0, 0
   Textbox #main.0D15, 270, 324, 80, 20
   Stylebits #main.0E15, _ES_RIGHT, _WS_BORDER or _WS_VISIBLE, 0, 0
   Textbox #main.0E15, 350, 324, 80, 20
   Stylebits #main.0F15, _ES_RIGHT, _WS_BORDER or _WS_VISIBLE, 0, 0
   Textbox #main.0F15, 430, 324, 80, 20
   Stylebits #main.0G15, _ES_RIGHT, _WS_BORDER or _WS_VISIBLE, 0, 0
   Textbox #main.0G15, 510, 324, 80, 20
   Stylebits #main.0H15, _ES_RIGHT, _WS_BORDER or _WS_VISIBLE, 0, 0
   Textbox #main.0H15, 590, 324, 80, 20
   Stylebits #main.0I15, _ES_RIGHT, _WS_BORDER or _WS_VISIBLE, 0, 0
   Textbox #main.0I15, 670, 324, 80, 20
   Stylebits #main.0A16, _ES_RIGHT, _WS_BORDER or _WS_VISIBLE, 0, 0
   Textbox #main.0A16, 30, 344, 80, 20
   Stylebits #main.0B16, _ES_RIGHT, _WS_BORDER or _WS_VISIBLE, 0, 0
   Textbox #main.0B16, 110, 344, 80, 20
   Stylebits #main.0C16, _ES_RIGHT, _WS_BORDER or _WS_VISIBLE, 0, 0
   Textbox #main.0C16, 190, 344, 80, 20
   Stylebits #main.0D16, _ES_RIGHT, _WS_BORDER or _WS_VISIBLE, 0, 0
   Textbox #main.0D16, 270, 344, 80, 20
   Stylebits #main.0E16, _ES_RIGHT, _WS_BORDER or _WS_VISIBLE, 0, 0
   Textbox #main.0E16, 350, 344, 80, 20
   Stylebits #main.0F16, _ES_RIGHT, _WS_BORDER or _WS_VISIBLE, 0, 0
   Textbox #main.0F16, 430, 344, 80, 20
   Stylebits #main.0G16, _ES_RIGHT, _WS_BORDER or _WS_VISIBLE, 0, 0
   Textbox #main.0G16, 510, 344, 80, 20
   Stylebits #main.0H16, _ES_RIGHT, _WS_BORDER or _WS_VISIBLE, 0, 0
   Textbox #main.0H16, 590, 344, 80, 20
   Stylebits #main.0I16, _ES_RIGHT, _WS_BORDER or _WS_VISIBLE, 0, 0
   Textbox #main.0I16, 670, 344, 80, 20
   Stylebits #main.0A17, _ES_RIGHT, _WS_BORDER or _WS_VISIBLE, 0, 0
   Textbox #main.0A17, 30, 364, 80, 20
   Stylebits #main.0B17, _ES_RIGHT, _WS_BORDER or _WS_VISIBLE, 0, 0
   Textbox #main.0B17, 110, 364, 80, 20
   Stylebits #main.0C17, _ES_RIGHT, _WS_BORDER or _WS_VISIBLE, 0, 0
   Textbox #main.0C17, 190, 364, 80, 20
   Stylebits #main.0D17, _ES_RIGHT, _WS_BORDER or _WS_VISIBLE, 0, 0
   Textbox #main.0D17, 270, 364, 80, 20
   Stylebits #main.0E17, _ES_RIGHT, _WS_BORDER or _WS_VISIBLE, 0, 0
   Textbox #main.0E17, 350, 364, 80, 20
   Stylebits #main.0F17, _ES_RIGHT, _WS_BORDER or _WS_VISIBLE, 0, 0
   Textbox #main.0F17, 430, 364, 80, 20
   Stylebits #main.0G17, _ES_RIGHT, _WS_BORDER or _WS_VISIBLE, 0, 0
   Textbox #main.0G17, 510, 364, 80, 20
   Stylebits #main.0H17, _ES_RIGHT, _WS_BORDER or _WS_VISIBLE, 0, 0
   Textbox #main.0H17, 590, 364, 80, 20
   Stylebits #main.0I17, _ES_RIGHT, _WS_BORDER or _WS_VISIBLE, 0, 0
   Textbox #main.0I17, 670, 364, 80, 20
   Stylebits #main.0A18, _ES_RIGHT, _WS_BORDER or _WS_VISIBLE, 0, 0
   Textbox #main.0A18, 30, 384, 80, 20
   Stylebits #main.0B18, _ES_RIGHT, _WS_BORDER or _WS_VISIBLE, 0, 0
   Textbox #main.0B18, 110, 384, 80, 20
   Stylebits #main.0C18, _ES_RIGHT, _WS_BORDER or _WS_VISIBLE, 0, 0
   Textbox #main.0C18, 190, 384, 80, 20
   Stylebits #main.0D18, _ES_RIGHT, _WS_BORDER or _WS_VISIBLE, 0, 0
   Textbox #main.0D18, 270, 384, 80, 20
   Stylebits #main.0E18, _ES_RIGHT, _WS_BORDER or _WS_VISIBLE, 0, 0
   Textbox #main.0E18, 350, 384, 80, 20
   Stylebits #main.0F18, _ES_RIGHT, _WS_BORDER or _WS_VISIBLE, 0, 0
   Textbox #main.0F18, 430, 384, 80, 20
   Stylebits #main.0G18, _ES_RIGHT, _WS_BORDER or _WS_VISIBLE, 0, 0
   Textbox #main.0G18, 510, 384, 80, 20
   Stylebits #main.0H18, _ES_RIGHT, _WS_BORDER or _WS_VISIBLE, 0, 0
   Textbox #main.0H18, 590, 384, 80, 20
   Stylebits #main.0I18, _ES_RIGHT, _WS_BORDER or _WS_VISIBLE, 0, 0
   Textbox #main.0I18, 670, 384, 80, 20
   Stylebits #main.0A19, _ES_RIGHT, _WS_BORDER or _WS_VISIBLE, 0, 0
   Textbox #main.0A19, 30, 404, 80, 20
   Stylebits #main.0B19, _ES_RIGHT, _WS_BORDER or _WS_VISIBLE, 0, 0
   Textbox #main.0B19, 110, 404, 80, 20
   Stylebits #main.0C19, _ES_RIGHT, _WS_BORDER or _WS_VISIBLE, 0, 0
   Textbox #main.0C19, 190, 404, 80, 20
   Stylebits #main.0D19, _ES_RIGHT, _WS_BORDER or _WS_VISIBLE, 0, 0
   Textbox #main.0D19, 270, 404, 80, 20
   Stylebits #main.0E19, _ES_RIGHT, _WS_BORDER or _WS_VISIBLE, 0, 0
   Textbox #main.0E19, 350, 404, 80, 20
   Stylebits #main.0F19, _ES_RIGHT, _WS_BORDER or _WS_VISIBLE, 0, 0
   Textbox #main.0F19, 430, 404, 80, 20
   Stylebits #main.0G19, _ES_RIGHT, _WS_BORDER or _WS_VISIBLE, 0, 0
   Textbox #main.0G19, 510, 404, 80, 20
   Stylebits #main.0H19, _ES_RIGHT, _WS_BORDER or _WS_VISIBLE, 0, 0
   Textbox #main.0H19, 590, 404, 80, 20
   Stylebits #main.0I19, _ES_RIGHT, _WS_BORDER or _WS_VISIBLE, 0, 0
   Textbox #main.0I19, 670, 404, 80, 20
   Stylebits #main.0A20, _ES_RIGHT, _WS_BORDER or _WS_VISIBLE, 0, 0
   Textbox #main.0A20, 30, 424, 80, 20
   Stylebits #main.0B20, _ES_RIGHT, _WS_BORDER or _WS_VISIBLE, 0, 0
   Textbox #main.0B20, 110, 424, 80, 20
   Stylebits #main.0C20, _ES_RIGHT, _WS_BORDER or _WS_VISIBLE, 0, 0
   Textbox #main.0C20, 190, 424, 80, 20
   Stylebits #main.0D20, _ES_RIGHT, _WS_BORDER or _WS_VISIBLE, 0, 0
   Textbox #main.0D20, 270, 424, 80, 20
   Stylebits #main.0E20, _ES_RIGHT, _WS_BORDER or _WS_VISIBLE, 0, 0
   Textbox #main.0E20, 350, 424, 80, 20
   Stylebits #main.0F20, _ES_RIGHT, _WS_BORDER or _WS_VISIBLE, 0, 0
   Textbox #main.0F20, 430, 424, 80, 20
   Stylebits #main.0G20, _ES_RIGHT, _WS_BORDER or _WS_VISIBLE, 0, 0
   Textbox #main.0G20, 510, 424, 80, 20
   Stylebits #main.0H20, _ES_RIGHT, _WS_BORDER or _WS_VISIBLE, 0, 0
   Textbox #main.0H20, 590, 424, 80, 20
   Stylebits #main.0I20, _ES_RIGHT, _WS_BORDER or _WS_VISIBLE, 0, 0
   Textbox #main.0I20, 670, 424, 80, 20
   Stylebits #main.0A21, _ES_RIGHT, _WS_BORDER or _WS_VISIBLE, 0, 0
   Textbox #main.0A21, 30, 444, 80, 20
   Stylebits #main.0B21, _ES_RIGHT, _WS_BORDER or _WS_VISIBLE, 0, 0
   Textbox #main.0B21, 110, 444, 80, 20
   Stylebits #main.0C21, _ES_RIGHT, _WS_BORDER or _WS_VISIBLE, 0, 0
   Textbox #main.0C21, 190, 444, 80, 20
   Stylebits #main.0D21, _ES_RIGHT, _WS_BORDER or _WS_VISIBLE, 0, 0
   Textbox #main.0D21, 270, 444, 80, 20
   Stylebits #main.0E21, _ES_RIGHT, _WS_BORDER or _WS_VISIBLE, 0, 0
   Textbox #main.0E21, 350, 444, 80, 20
   Stylebits #main.0F21, _ES_RIGHT, _WS_BORDER or _WS_VISIBLE, 0, 0
   Textbox #main.0F21, 430, 444, 80, 20
   Stylebits #main.0G21, _ES_RIGHT, _WS_BORDER or _WS_VISIBLE, 0, 0
   Textbox #main.0G21, 510, 444, 80, 20
   Stylebits #main.0H21, _ES_RIGHT, _WS_BORDER or _WS_VISIBLE, 0, 0
   Textbox #main.0H21, 590, 444, 80, 20
   Stylebits #main.0I21, _ES_RIGHT, _WS_BORDER or _WS_VISIBLE, 0, 0
   Textbox #main.0I21, 670, 444, 80, 20
   Stylebits #main.0A22, _ES_RIGHT, _WS_BORDER or _WS_VISIBLE, 0, 0
   Textbox #main.0A22, 30, 464, 80, 20
   Stylebits #main.0B22, _ES_RIGHT, _WS_BORDER or _WS_VISIBLE, 0, 0
   Textbox #main.0B22, 110, 464, 80, 20
   Stylebits #main.0C22, _ES_RIGHT, _WS_BORDER or _WS_VISIBLE, 0, 0
   Textbox #main.0C22, 190, 464, 80, 20
   Stylebits #main.0D22, _ES_RIGHT, _WS_BORDER or _WS_VISIBLE, 0, 0
   Textbox #main.0D22, 270, 464, 80, 20
   Stylebits #main.0E22, _ES_RIGHT, _WS_BORDER or _WS_VISIBLE, 0, 0
   Textbox #main.0E22, 350, 464, 80, 20
   Stylebits #main.0F22, _ES_RIGHT, _WS_BORDER or _WS_VISIBLE, 0, 0
   Textbox #main.0F22, 430, 464, 80, 20
   Stylebits #main.0G22, _ES_RIGHT, _WS_BORDER or _WS_VISIBLE, 0, 0
   Textbox #main.0G22, 510, 464, 80, 20
   Stylebits #main.0H22, _ES_RIGHT, _WS_BORDER or _WS_VISIBLE, 0, 0
   Textbox #main.0H22, 590, 464, 80, 20
   Stylebits #main.0I22, _ES_RIGHT, _WS_BORDER or _WS_VISIBLE, 0, 0
   Textbox #main.0I22, 670, 464, 80, 20
   Stylebits #main.0A23, _ES_RIGHT, _WS_BORDER or _WS_VISIBLE, 0, 0
   Textbox #main.0A23, 30, 484, 80, 20
   Stylebits #main.0B23, _ES_RIGHT, _WS_BORDER or _WS_VISIBLE, 0, 0
   Textbox #main.0B23, 110, 484, 80, 20
   Stylebits #main.0C23, _ES_RIGHT, _WS_BORDER or _WS_VISIBLE, 0, 0
   Textbox #main.0C23, 190, 484, 80, 20
   Stylebits #main.0D23, _ES_RIGHT, _WS_BORDER or _WS_VISIBLE, 0, 0
   Textbox #main.0D23, 270, 484, 80, 20
   Stylebits #main.0E23, _ES_RIGHT, _WS_BORDER or _WS_VISIBLE, 0, 0
   Textbox #main.0E23, 350, 484, 80, 20
   Stylebits #main.0F23, _ES_RIGHT, _WS_BORDER or _WS_VISIBLE, 0, 0
   Textbox #main.0F23, 430, 484, 80, 20
   Stylebits #main.0G23, _ES_RIGHT, _WS_BORDER or _WS_VISIBLE, 0, 0
   Textbox #main.0G23, 510, 484, 80, 20
   Stylebits #main.0H23, _ES_RIGHT, _WS_BORDER or _WS_VISIBLE, 0, 0
   Textbox #main.0H23, 590, 484, 80, 20
   Stylebits #main.0I23, _ES_RIGHT, _WS_BORDER or _WS_VISIBLE, 0, 0
   Textbox #main.0I23, 670, 484, 80, 20
   Stylebits #main.0A24, _ES_RIGHT, _WS_BORDER or _WS_VISIBLE, 0, 0
   Textbox #main.0A24, 30, 504, 80, 20
   Stylebits #main.0B24, _ES_RIGHT, _WS_BORDER or _WS_VISIBLE, 0, 0
   Textbox #main.0B24, 110, 504, 80, 20
   Stylebits #main.0C24, _ES_RIGHT, _WS_BORDER or _WS_VISIBLE, 0, 0
   Textbox #main.0C24, 190, 504, 80, 20
   Stylebits #main.0D24, _ES_RIGHT, _WS_BORDER or _WS_VISIBLE, 0, 0
   Textbox #main.0D24, 270, 504, 80, 20
   Stylebits #main.0E24, _ES_RIGHT, _WS_BORDER or _WS_VISIBLE, 0, 0
   Textbox #main.0E24, 350, 504, 80, 20
   Stylebits #main.0F24, _ES_RIGHT, _WS_BORDER or _WS_VISIBLE, 0, 0
   Textbox #main.0F24, 430, 504, 80, 20
   Stylebits #main.0G24, _ES_RIGHT, _WS_BORDER or _WS_VISIBLE, 0, 0
   Textbox #main.0G24, 510, 504, 80, 20
   Stylebits #main.0H24, _ES_RIGHT, _WS_BORDER or _WS_VISIBLE, 0, 0
   Textbox #main.0H24, 590, 504, 80, 20
   Stylebits #main.0I24, _ES_RIGHT, _WS_BORDER or _WS_VISIBLE, 0, 0
   Textbox #main.0I24, 670, 504, 80, 20
   Stylebits #main.0A25, _ES_RIGHT, _WS_BORDER or _WS_VISIBLE, 0, 0
   Textbox #main.0A25, 30, 524, 80, 20
   Stylebits #main.0B25, _ES_RIGHT, _WS_BORDER or _WS_VISIBLE, 0, 0
   Textbox #main.0B25, 110, 524, 80, 20
   Stylebits #main.0C25, _ES_RIGHT, _WS_BORDER or _WS_VISIBLE, 0, 0
   Textbox #main.0C25, 190, 524, 80, 20
   Stylebits #main.0D25, _ES_RIGHT, _WS_BORDER or _WS_VISIBLE, 0, 0
   Textbox #main.0D25, 270, 524, 80, 20
   Stylebits #main.0E25, _ES_RIGHT, _WS_BORDER or _WS_VISIBLE, 0, 0
   Textbox #main.0E25, 350, 524, 80, 20
   Stylebits #main.0F25, _ES_RIGHT, _WS_BORDER or _WS_VISIBLE, 0, 0
   Textbox #main.0F25, 430, 524, 80, 20
   Stylebits #main.0G25, _ES_RIGHT, _WS_BORDER or _WS_VISIBLE, 0, 0
   Textbox #main.0G25, 510, 524, 80, 20
   Stylebits #main.0H25, _ES_RIGHT, _WS_BORDER or _WS_VISIBLE, 0, 0
   Textbox #main.0H25, 590, 524, 80, 20
   Stylebits #main.0I25, _ES_RIGHT, _WS_BORDER or _WS_VISIBLE, 0, 0
   Textbox #main.0I25, 670, 524, 80, 20
   Stylebits #main.entry, _ES_READONLY, _WS_BORDER, 0, 0
   Textbox #main.entry, 120, 1, 630, 22
   Stylebits #main.def, _BS_DEFPUSHBUTTON, 0, 0, 0
   Button #main.def, "", EnterKey, UL, -100, -100
   BackgroundColor$ = "Darkgray"
   Open "Simple LB Spreadsheet" for Window as #main
   #main, "Trapclose QuitByTrap"
   For i = 1 to 25
       Call NumberRow i, 1
   Next i
   For i = 1 to 9
       Call LetterCol i, 1
   Next i
   #main.fb01, "Down; Fill Buttonface; Flush"
   #main, "Font Times_New_Roman 10"
End Sub



Attachments:

LBSpreadsheetJLT.zip (11.2 KB)

[Rod]

Perhaps the original source can be ported to Liberty? Even when we have a grid tool it will still not provide the engine. But perhaps Janet gives you all you need.