Infinite loop

[angelo2449]

Hi Guys,
in this program, which appears correct, LB makes a error, at least it seems.

Resetting a radio button causes an infinite loop!



   nomainwin



   if FileExists("C:\AutocadSupporto\Config\Unita.dat") then

       open "C:\AutocadSupporto\Config\Unita.dat" for input as #14

           input #14, Disco$

       close #14

   end if



   WindowWidth  = 750

   WindowHeight = 430



   UpperLeftX=int((DisplayWidth-WindowWidth)/2)

   UpperLeftY=int((DisplayHeight-WindowHeight)/2)



   BackgroundColor$ = "yellow"

   ForegroundColor$ = "black"



   xa = 30 : ya = 40



   texteditor #main.edit, -400, -400, 200, 100

   textbox #main.fin, xa + 15, 20, 640, 25



   groupbox #main.colore, "Colore", xa + 20, ya + 15, 300, 115

   radiobutton #main.nero, "Linea colore Nero", [NeroSet], [NeroReset], xa + 25, ya + 40, 200, 25

   radiobutton #main.rosso, "Linea colore Rosso", [RossoSet], [RossoReset], xa + 25, ya + 70, 200, 25



   groupbox #main.linea, "Linea", xa + 335, ya + 15, 317, 115

   radiobutton #main.continua, "Linea Continua", [ContinuaSet], [ContinuaReset], xa + 345, ya + 40, 200, 25

   radiobutton #main.tratt, "Linea Tratteggiata", [TrattSet], [TrattReset], xa + 345, ya + 70, 200, 25

   radiobutton #main.punt, "Linea Puntinata", [PuntSet], [PuntReset], xa + 345, ya + 100, 200, 25



   button #main.si, "Salva i 10 Punti", [Salva10Punti], UL, xa + 225, ya + 150, 210, 45

   button #main.info, "Info", [Info], UL, 45, ya + 210, 120, 40

   button #main.libr, "Libretto", [Libretto], UL, 255, ya + 210, 210, 40

   button #main.esci, "Esci", [quit.main], UL, 565, ya + 210, 120, 40

   TextboxColor$ = "cyan"

   textbox #main.notifica, 42, ya + 275, 643, 25



   open "Gestione della Linea di Tipo > 7 < - Contorni 10 Punti - Ver. 30/09/2020" for window as #main

   #main, "font courier_new 10 17 bold"

   #main, "trapclose [quit.main]"



   CodColor$ = "nil"

   CodLinea$ = "nil"



   #main.edit, "!cls";

   #main.edit, "!paste";

   #main.edit, "!contents? StringaIn$";

   StringaIn$ = "7|0|1430|1430|1430|1430|1430|1430|1430|1430|1430|1430|NC|"  ''7|0|1310|1290|1280|1100|1400|1420|1430|1390|1310|1290|N|T|

   #main.fin, trim$(StringaIn$)



   if left$(StringaIn$, 4) = "7|0|" then

       Pos1 = len(StringaIn$) - 4  ' |RC|

       CodColor$ = mid$(StringaIn$, Pos1 + 2, 1)

       CodLinea$ = mid$(StringaIn$, Pos1 + 3, 1)

   end if



   print "left$(StringaIn$, 4) xxxx "; left$(StringaIn$, 4)

   print "Pos1 xxxx "; Pos1

   print "StringaIn$ xxxx "; StringaIn$

   print "CodColor$ xxxx "; CodColor$

   print "CodLinea$ xxxx "; CodLinea$



   if CodColor$ <> "nil" then

       select case CodColor$



           case "N"

           #main.nero, "set"



           case "R"

           #main.rosso, "set"



       end select

   end if



   if CodLinea$ <> "nil" then

       select case CodLinea$



           case "C"

           #main.continua, "set"



           case "T"

           #main.tratt, "set"



           case "P"

           #main.punt, "set"



       end select

   end if



   CodColor$ = ""

   FlagColor = 0

   #main.nero, "reset"

   #main.rosso, "reset"

   #main.continua, "reset"

   #main.tratt, "reset"

   #main.punt, "reset"



   wait



   ' -----------------------------------------------



   [Libretto]



   run "Notepad " + Disco$ + "\AutocadSupporto\Libretto\LibrettoPregeo.dat"



   wait



   ' -----------------------------------------------



   [Salva10Punti]



   if CodColor$ = "nil" then

       Notice "Attenzione" + chr$(13) + "Devi impostare il Colore della linea"

       wait

   end if



   if CodLinea$ = "nil" then

       Notice "Attenzione" + chr$(13) + "Devi impostare il Tipo della linea"

       wait

   end if



   #main.fin, "!contents? Contenuto$"

   Contenuto$ = trim$(Contenuto$) + CodColor$ + CodLinea$ + "|"



   open Disco$ + "\AutocadSupporto\Libretto\LibrettoPregeo.dat" for append as #15

       print #15, Contenuto$

   close #15



   #main.edit, "!cls";

   #main.edit, CodColor$ + "#" + CodLinea$;

   #main.edit, "!selectall";

   #main.edit, "!copy";



   #main.notifica, "Riga salvata in > LibrettoPregeo <"

   Timer 1000, [Salta]

   wait



   [Salta]

   #main.notifica, ""

   #main.libr, "!setfocus"



   close #main

   end



   ' ----------------------------



   [NeroSet]



   CodColor$ = "N"

   FlagColor = 1



   wait



   ' ----------------------------



   [NeroReset]

   [RossoReset]

   [ContinuaReset]

   [TrattReset]

   [PuntReset]



   wait



   ' ----------------------------



   [RossoSet]



   CodColor$ = "R"

   FlagColor = 1



   wait



   ' ----------------------------



   [Controlla]



   if FlagColor = 0 then

       Notice "Attenzione" + chr$(13) + "Devi prima scegliere il Colore!"

       #Caso$, "reset"

       wait

   else

       return

   end if







   ' ----------------------------



   [ContinuaSet]



   Caso$ = "#main.continua"

   gosub [Controlla]

   CodLinea$ = "C"



   wait



   ' ----------------------------



   [TrattSet]



   Caso$ = "#main.tratt"

   gosub [Controlla]

   CodLinea$ = "T"



   wait



   ' ----------------------------



   [PuntSet]



   Caso$ = "#main.punt"

   gosub [Controlla]

   CodLinea$ = "P"



   wait



   ' ----------------------------



   [Info]



   if FileExists("C:\AutocadSupporto\Info\SiNo7.txt") then

      run "Notepad " + "C:\AutocadSupporto\Info\SiNo7.txt"

   end if



   wait



   ' ----------------------------



   function FileExists(FilePath$)

       dim FileExistsInfo$(1,1)    ' ritorna 0 (zero) se il file non esiste, 1 (uno) se esiste

       files "", FilePath$, FileExistsInfo$(

       FileExists = val(FileExistsInfo$(0,0))

   end function



' -------------------------------



   [quit.main]



   #main.edit, "!cls";

   #main.edit, "Fine";

   #main.edit, "!selectall";

   #main.edit, "!copy";



   close #main

   end



   ' -----------------------------------------------



The error occurs in :
[ContinuaSet]

[TrattSet]

[PuntSet]


What do you think? Can it be avoided?

Thank you.



[Brandon Parker]

When I run it through the Debugger, the code above does not appear to be running into a loop when I change RadioButton selections. It seems more likely that your code has a "logical" error in what you are trying to do.


{:0)

Brandon Parker

[Chris Iverson]

No, that fact makes me even more certain it's a bug in LB. It was brought up in another topic, too.

Here's a trimmed down example that demonstrates it.

'Form created with the help of Freeform 3 v07-15-08
'Generated on Oct 02, 2020 at 13:12:11


[setup.main.Window]

   '-----Begin code for #main

   'nomainwin
   WindowWidth = 550
   WindowHeight = 410
   UpperLeftX=int((DisplayWidth-WindowWidth)/2)
   UpperLeftY=int((DisplayHeight-WindowHeight)/2)


   '-----Begin GUI objects code

   radiobutton #main.radiobutton1, "RadioButton Caption", [radiobutton1Set], [radiobutton1Reset],   5,   5, 144,  25
   button #main.button2,"Reset",[button2Click], UL,  60, 152,  44,  25

   '-----End GUI objects code

   open "untitled" for window as #main
   print #main, "font ms_sans_serif 10"
   print #main, "trapclose [quit.main]"


[main.inputLoop]   'wait here for input event
   wait


[radiobutton1Set]   'Perform action for the radiobutton named 'radiobutton1'


   'Insert your own code here
   notice "Set"
   print "set"
   #main.radiobutton1, "reset"
   wait



[radiobutton1Reset]   'Perform action for the radiobutton named 'radiobutton1'

   'Insert your own code here
   notice "reset"
   wait


[button2Click]   'Perform action for the button named 'button2'

   'Insert your own code here
   #main.radiobutton1, "reset"
   wait

[quit.main] 'End the program
   close #main
   end


Your observation of the behavior in the debugger holds true here, too: it doesn't loop in the debugger.

Based on what's been said here, as well as in the other topic, I've gathered these strange behaviors:

1. If there is a NOTICE in the direct event handler for the SET event of a radio button, and that event handler also resets the button, then it will go into an infinite loop.
2. If the NOTICE is removed/commented out, the loop will not happen.
3. If the reset is not performed in the direct SET event handler(i.e. a WAIT is executed first), the loop will not happen. (Demonstrated this by setting a timer in the SET event handler, and then resetting the radiobutton in the timer event handler)
4. If the program is run in the LB debugger, the loop will not happen.
5. Opening other windows instead of a NOTICE will cause the loop to happen. See below:

'Form created with the help of Freeform 3 v07-15-08
'Generated on Oct 02, 2020 at 13:12:11


[setup.main.Window]

   '-----Begin code for #main

   'nomainwin
   WindowWidth = 550
   WindowHeight = 410
   UpperLeftX=int((DisplayWidth-WindowWidth)/2)
   UpperLeftY=int((DisplayHeight-WindowHeight)/2)


   '-----Begin GUI objects code

   radiobutton #main.radiobutton1, "RadioButton Caption", [radiobutton1Set], [radiobutton1Reset],   5,   5, 144,  25
   button #main.button2,"Reset",[button2Click], UL,  60, 152,  44,  25

   '-----End GUI objects code

   open "untitled" for window as #main
   print #main, "font ms_sans_serif 10"
   print #main, "trapclose [quit.main]"


[main.inputLoop]   'wait here for input event
   wait


[radiobutton1Set]   'Perform action for the radiobutton named 'radiobutton1'


   'Insert your own code here
   print "set"
   'notice "Set"
   open "test" for window as #win2
   for x = 1 to 1000000
   next x
   close #win2
   #main.radiobutton1, "reset"
   wait



[radiobutton1Reset]   'Perform action for the radiobutton named 'radiobutton1'

   'Insert your own code here
   notice "reset"
   wait


[button2Click]   'Perform action for the button named 'button2'

   'Insert your own code here
   #main.radiobutton1, "reset"
   wait

[quit.main] 'End the program
   close #main
   end


All-in-all, I think something weird is going on with LB's internal event-handling logic.

[Brandon Parker]

Yeah, that concise example is easier to follow. I would suspect that it is something internal as well. Obviously, Carl would have to chime in on this one.

Maybe the better question would be why one would want to reset a RadioButton in the handler code where it is being set. That just screams to use a different control...

{:0)

Brandon Parker

[Carl Gundel]

Oct 13, 2020 19:31:47 GMT -5 Brandon Parker said:

Yeah, that concise example is easier to follow. I would suspect that it is something internal as well. Obviously, Carl would have to chime in on this one.

Maybe the better question would be why one would want to reset a RadioButton in the handler code where it is being set. That just screams to use a different control...

{:0)

Brandon Parker

Perhaps the reset command doesn't need to signal an event that would cause a loop?

[tsh73]

Perhaps the reset command doesn't need to signal an event that would cause a loop?

I'm sorry I can't quite understand this sentense.
So is it confirmed bug now?

[Carl Gundel]

Oct 14, 2020 7:16:15 GMT -5 tsh73 said:

Perhaps the reset command doesn't need to signal an event that would cause a loop?

I'm sorry I can't quite understand this sentense.
So is it confirmed bug now?

Just asking the question.  Not saying it's a bug, but that doesn't mean I can't change it if it makes sense to do so.

[Rod]

If we accept that only one radio button can be set and that only the set command has any effect then the reset command should not exist or should simply be ignored.

[Chris Iverson]

I do think that an explicit "reset" command should exist, so that it's possible to return the UI to it's default state without needing to close and reopen the window, but I agree that maybe there doesn't need to be an explicit reset event and event handler, if that's what's causing the problem. I can't think of much, if anything, you would do in a "reset" handler for a radiobutton that you couldn't do in a "set" handler for one of the other options that gets pressed.


I also agree with Brandon's idea that the logic of the code causing this in the first place might need a second look. In particular, if a user isn't supposed to be able to interact with an option at that time, perhaps disabling the control until it's viable is a better option?

[Rod]

Thinking about it I more I would say again reset should not exist and the default should be option one, or the first radio button established in the group set. The only option to the programmer is to set an alternative or read the user choice.

So user change results in an event taking us to the set handler. Clicking on a set button does nothing.

Programmatic change visually sets the desired button.

Nothing else is needed.

[Brandon Parker]

Yeah, the logic of "Resetting" a RadioButton in its own "Set" handler is ... err ... NOT LOGICAL at all.

That being said, the problem is only that of the "Set" handler when the circumstances listed above by Chris are in place. When the specific circumstances are met, the "Set" handler appears to be called repeatedly until a forced "Reset" is activated from a click of the button.

Maybe the "Reset" should be triggered when a RadioButton is deselected in any manner. This would allow the programmer to easily determine which RadioButton was selected when the change occurred without keeping track of the currently selected one. I am just thinking of situations where the code would do one thing when going from A to B, but a completely different thing when going from A to C (that type of thing)...

{:0)

Brandon Parker

[Rod]

Continuing this "bug" hunt. I was trying to recreate the infinite loop but could not make it happen. I have never used reset, I dont suppose many folks have. However in this code it all works perfectly until I try and address #main.rb2 Only the first radiobutton seems to accept "reset". You can click everything on this form and it works correctly until you click on [reset radiobutton 2]. I can reset radiobutton 1 but 2 gives a handle not found error.

I realise that resetting radiobuttons is logically wrong, but the command exists, having none set might be a valid position to set up.

EDIT: coding error in creation of control, I used . instead of , in the continuation of the radiobutton creation line for #main.rb2

'nomainwin
   WindowWidth = 550
   WindowHeight = 410
   UpperLeftX=int((DisplayWidth-WindowWidth)/2)
   UpperLeftY=int((DisplayHeight-WindowHeight)/2)
   groupbox #main.gb "Test",5,5,75,80
   radiobutton #main.rb1, "Button 1", [rb1set], [nil],   10,   20, 150,  25
   radiobutton #main.rb2. "Button 2", [rb2set], [nil],   10,   45, 150,  25
   button #main.button,"set to default",[defaultClick], UL,  5, 125, 150,  25
   button #main.button2,"reset radiobutton1",[reset1Click], UL, 5,150,150,25
   button #main.button3,"reset radiobutton2",[reset2Click], UL, 5,175,150,25
   open "untitled" for window as #main
   #main "trapclose [quit.main]"

   'set the default radiobutton
   #main.rb1 "set"
   b=1
   wait

   'if the user clicks the button set default radiobutton
   'ie programatically set a radiobutton
   [defaultClick]
   #main.rb1 "set"
   notice "1 set programatically"
   print "Button 1 set"
   b=1
   wait

   [reset1Click]
   #main.rb1 "reset"
   notice "1 reset programmatically"
   print "1 reset"
   b=0
   wait

   [reset2Click]
   #main.rb2 "reset"
   notice "2 reset programmatically"
   print "2 reset"
   b=0
   wait

   'if the user clicks a radiobutton record it
   [rb1set]
   notice "1 Set by user"
   print "Button 1 set"
   b=1
   wait


   'if the user clicks a radiobutton record it
   [rb2set]
   print "Button 2 set"
   notice "2 set by user"
   b=2
   wait

   'do nothing
   [nil]
   wait


   [quit.main]
   print "Closing with button ";b;" set."
   close #main
   end



[BeeTrap]

Check the "period" in this line, change to comma and seems to work better.

radiobutton #main.rb2.

[Rod]

Ahhh, well spotted BeeTrap. It now works just as I expected. So just my silly coding. But I still get no infinite loop, so more study required of the original code.