make a graphicbox with video

[atomose]

hi !

i would like to know how can i play a video file on a graphicbox or graphicwindow. I know its possible because i found some .bas code with this but i dont understand it .... can someone explain to me how is it possible ? and maybe be show me some synthax code ^^. thx !

[Rod]

Are we talking about animation, where we have background and moving images overlaid? These can be cartoon sprite or photorealistic sprite based. Or are we talking about streaming video files. Showing the code you found will get the best help.

[atomose]

i speak about real streaming video file. Play .avi movi on graphicboxe with button "play" and "stop". Like VLC software

[Rod]

The answer to this is to use the MultiMediaInterface (MMI) We usually access this using API code and sending "messages" or "commands" to the MMI. This code should work but my PC seems not to like .avi

Perhaps someone else will have more success. It would still be good to see the code you found.


'nomainwin

WindowWidth=500
WindowHeight=500


graphicbox #main.gb, 0, 0, 480, 480

Open "MMI Demo" For Window_nf As #main
#main "TrapClose [quit]"

m$="test.avi"

h=hwnd(#main.gb)
r$=mciSendString$("open "+m$+" type avivideo alias movie")
r$=mciSendString$("window movie handle "+str$(h))
r$=mciSendString$("put movie destination at 0 0 0 0")
r$=mciSendString$("play movie wait")
r$=mciSendString$("close movie")
wait

[quit]
close #main
end

Function mciSendString$(s$)
buffer$=space$(1024)+chr$(0)
calldll #winmm,"mciSendStringA",s$ as ptr,buffer$ as ptr,_
1028 as ulong, 0 as ulong, r as long
'truncate returned string at null character
buffer$=left$(buffer$, instr(buffer$, chr$(0)) - 1)
if r>0 then
buffer2$=space$(129)
calldll #winmm,"mciGetErrorStringA", r as long, buffer2$ as ptr,_
128 as ulong, r as boolean
mciSendString$=buffer2$
else
mciSendString$=buffer$
end if
print mciSendString$
End Function



[atomose]

thx !!

after somes hours it work !


   nomainwin
   WindowWidth=80 : WindowHeight=26 : UpperLeftX=100 : UpperLeftY=120
   open "winmm.dll" for dll as #mm
   button #1, "CLOSE /STOP",[quit],UL,0,0,80,26
   graphicbox #1.map, 0, 0, WindowWidth, WindowHeight
   open "test" for window_popup as #1
   print #1, "trapclose [quit]"

   DefaultDir$ = path$
   m$="test.avi"
   sFile$ = noPath$(m$)
   plen = len(m$)-len(sFile$)
   path$ = left$(m$,plen)
   scrw = 1310 : scrh = 833
   xpos = int((DisplayWidth-scrw)/2) : ypos = int((DisplayHeight-scrh)/2)
   m$=GetShortPathName$(m$)
   r$=mciSendString$("open "+m$+" type MpegVideo alias movie")
   r$=mciSendString$("window movie text " + chr$(34) + "video player" + chr$(34))
   r$=mciSendString$("put movie window at ";xpos;" ";ypos;" ";scrw;" ";scrh)
   r$=mciSendString$("status movie length")
   mlength=val(r$)
   movieOpen=1
   r$=mciSendString$("play movie")
   wait

   [quit]
   if movieOpen then r$=mciSendString$("close movie")
   close #1 : close #mm : end

Function noPath$(t$)
   while instr(t$, "\")
   t$ = mid$(t$, 2)
   wend
   noPath$ = t$
end function

Function GetShortPathName$(lPath$)
   lPath$=lPath$+chr$(0)
   sPath$=space$(256)
   lenPath=len(sPath$)
   open "kernel32" for dll as #k
   calldll #k, "GetShortPathNameA",lPath$ as ptr,_
   sPath$ as ptr,lenPath as long,r as long
   close #k
   GetShortPathName$=left$(sPath$,r)
end function

Function mciSendString$(s$)
   buffer$=space$(1024)+chr$(0)
   calldll #mm,"mciSendStringA",s$ as ptr,buffer$ as ptr,_
   1028 as long, 0 as long, r as long
   buffer$=left$(buffer$, instr(buffer$, chr$(0)) - 1)
   if r>0 then mciSendString$="error"
   if r<=0 then mciSendString$=buffer$
end Function