Enhance Your Windows and Controls

[Walt Decker]

CTL_COLOR.DLL will set the color of listboxes, textboxes, and statictext to the text color and background color of your choice.  It will also color your parent window to a color of your choice.

With buttons the border color is set to a color of your choice.  The attached zip contains the below source code and CTL_COLOR.DLL.

!!! EDIT !!!

I have made a significant change in CTL_COLOR.DLL.  It will now accommodate  DIBsection memory bitmaps loaded by either LB's LOADBMP function or gdi32.dll function LoadImage().

Although the code below will still work, results may be unexpected.  Therefore it is advisable  to use the source code in the zip file below.

'
[CONTROL.COLORS]
DARKRED     = HEXDEC("&H00008B")
LIGHTSALMON = HEXDEC("&H7AA0FF")
VIOLETRED   = HEXDEC("&H8515C7")
LIGHTPINK   = HEXDEC("&HC1B6FF")
LIGHTLEMON  = HEXDEC("&HCDFAFF")
ORANGERED   = HEXDEC("&H0045FF")

[STATIC.CONTROL.STYLES]
SS.CENTER      = HEXDEC("&H00000001")
SS.CENTERIMAGE = HEXDEC("&H00000200")

DIM LbxAry$(1) '<--- listbox array
LbxAry$(0) = "[SWAP.COLORS]"

[DEFINE.STATIC.CONTROLS]
STYLEBITS #NEW.LBL1, SS.CENTER OR SS.CENTERIMAGE, 0, 0, 0
STYLEBITS #NEW.LBL2, SS.CENTER OR SS.CENTERIMAGE, 0, 0, 0

STATICTEXT #NEW.LBL1, "LBL 1", 5, 5, 50, 20
STATICTEXT #NEW.LBL2, "LBL 2", 5, 30, 50, 20

STYLEBITS #SHO.LBL1, SS.CENTER OR SS.CENTERIMAGE, 0, 0, 0
STYLEBITS #SHO.LBL2, SS.CENTER OR SS.CENTERIMAGE, 0, 0, 0

STATICTEXT #SHO.LBL1, "LBL 1", 5, 5, 50, 20
STATICTEXT #SHO.LBL2, "LBL 2", 5, 30, 50, 20

[DEFINE.EDIT.AND.LISTBOX]
TEXTBOX #SHO.TXB, 65, 5, 125, 20

LISTBOX #NEW.LBX, LbxAry$(), DMO.END, 60, 5, 125, 125
BUTTON #NEW.BTN, "QUIT", DONE, UL, 110, 135, 50, 25

[DEFINE.PARENT.WINDOWS]
UpperLeftX = 25
UpperLeftY = 100
OPEN "NEW WIN" FOR WINDOW AS #NEW

UpperLeftX = 00
UpperLeftY = 00

OPEN "LABELS" FOR WINDOW AS #SHO

[SET.PROPERTIES]
'####################################################
'
' SET PROPERTIES FOR CONTROLS ON WINDOW "LABELS"
' "TXTCLR": 32-bit Color of text; The string "TXTCLOR" is
'           a property key.  It can be anything you want,
'           e. g. "FORCOLOR", "TXT".
'           It can also be mix-cased and be expressed as a
'           string, e. g. Prop1$ = "ForeColor".
'
' "BKGCLR": See above
'
'####################################################

LblHndl = HWND(#SHO.LBL1) '<--- static control handle
RetVal = FN.SetProp(LblHndl, "TXTCLR", "BKGCLR", DARKRED, LIGHTSALMON)

LblHndl = HWND(#SHO.LBL2) '<--- static control handle
RetVal = FN.SetProp(LblHndl, "TXTCLR", "BKGCLR", VIOLETRED, LIGHTPINK)

LblHndl = HWND(#SHO.TXB) '<--- edit control handle
RetVal = FN.SetProp(LblHndl, "TXTCLR", "BKGCLR", LIGTHSALMON, DARKRED)

'<--------------- SET PROPERTIES FOR WINDOW "NEW WIN" ----------->
LbxHndl = HWND(#NEW.LBX) '<--- listbox handle
RetVal = FN.SetProp(LbxHndl, "TXTCLR", "BKGCLR", ORANGERED, LIGHTLEMON)

LbxHndl = HWND(#NEW.BTN)
RetVal = FN.SetProp(LbxHndl, "TXTCLR", "BKGCLR", LIGTHSALMON, DARKRED)

'##################################################################
'  INITIALIZE THE DLL
'  "TXTCLR":  The property key you defined for the text color of your
'             controls.
'
'  "BKGCLR":  The property key you defined for the background color
'             of your control
'
'  WinColor:  The color of the parent window.  This value must be
'             greater than zero.
'##################################################################

OPEN "CTL_COLOR" FOR DLL AS #CTL

WinHndl = HWND(#SHO)
CALLDLL #CTL, "FN_InitProperties", WinHndl AS ULONG, "TXTCLR" AS PTR, _
             "BKGCLR" AS PTR, LIGHTLEMON AS ULONG, RetVal AS ULONG

NewHndl = HWND(#NEW)
CALLDLL #CTL, "FN_InitProperties", NewHndl AS ULONG, "TXTCLR" AS PTR, _
             "BKGCLR" AS PTR, 0 AS ULONG, RetVal AS ULONG '<--- SUCCESS: Non-zero

PRINT #NEW, "TRAPCLOSE DMO.END"
PRINT #SHO, "TRAPCLOSE DMO.END"

[SET.TIMER]
TIMER 6000, [SWAP.COLORS]

WAIT

'----------------------------------------------------------
'----------------------------------------------------------

[SWAP.COLORS]
TIMER 0

RetVal = 0
'<--- change the colors of controls: see [SET.PROPERTIES] above ----------->
LblHndl = HWND(#SHO.LBL1)
RetVal = FN.SetProp(LblHndl, "TXTCLR", "BKGCLR", VIOLETRED, LIGHTPINK)

LblHndl = HWND(#SHO.LBL2)
RetVal = FN.SetProp(LblHndl, "TXTCLR", "BKGCLR", DARKRED, LIGHTSALMON)

'<----------- change the text ----------------------------->
PRINT #SHO.LBL2, "Ooops"
PRINT #SHO.LBL1, "DUH!"

WAIT
[SWAP.COLORS.END]

'----------------------------------------------------
'----------------------------------------------------

SUB DMO.END WinHndl$

RetVal = 0

WinHndl = HWND(#SHO)
CALLDLL #CTL, "FN_CLOSE", WinHndl AS ULONG, RetVal AS VOID
WinHndl = HWND(#NEW)
CALLDLL #CTL, "FN_CLOSE", WinHndl AS ULONG, RetVal AS VOID

WinHndl = HWND(#SHO.LBL1)
RetVal = FN.RemoveProp(WinHndl, "TXTCLR", "BKGCLR")
WinHndl = HWND(#SHO.LBL2)
RetVal = FN.RemoveProp(WinHndl, "TXTCLR", "BKGCLR")
WinHndl = HWND(#SHO.TXB)
RetVal = FN.RemoveProp(WinHndl, "TXTCLR", "BKGCLR")
WinHndl = HWND(#NEW.LBX)
RetVal = FN.RemoveProp(WinHndl, "TXTCLR", "BKGCLR")

CLOSE #SHO
CLOSE #NEW
CLOSE #CTL

END

END SUB

SUB DONE BtnHndl$
END SUB

'---------------------------------------------------------------
'---------------------------------------------------------------

FUNCTION FN.SetProp(WinHndl, TxtClr$, Bkg$, ForeColor, BackColor)

RetVal = 0
CALLDLL #user32, "SetPropA", WinHndl AS ULONG, TxtClr$ AS PTR, _
                ForeColor AS ULONG, RetVal AS VOID
CALLDLL #user32, "SetPropA", WinHndl AS ULONG, Bkg$ AS PTR, _
                BackColor AS ULONG, RetVal AS VOID

END FUNCTION

'---------------------------------------------------------------
'---------------------------------------------------------------

FUNCTION FN.RemoveProp(WinHndl, Prop1$, Prop2$)

RetVal = 0

CALLDLL #user32, "RemovePropA", WinHndl AS ULONG, Prop1$ AS PTR, _
                RetVal AS VOID
CALLDLL #user32, "RemovePropA", WinHndl AS ULONG, Prop2$ AS PTR, _
                RetVal AS VOID
END FUNCTION
'

CONTROL_COLOR.ZIP (18.27 KB)

EDIT:  Sunday, 14 November 2021

The internal working of CTL_COLOR.DLL has changed.

Tasp:  You can get the color value of buttonface with:

COLOR.BTNFACE = 15
CALLDLL #user32, "GetSysColor", 15 AS LONG, SysColor AS ULONG

[Tasp]

Hi Walt,

Thanks for this DLL, very handy.

I don't seem to be able to be change the foregorund colour separately to the background colour. 

If you remove the 2nd call to not set the background, it simply does not change the foreground colour, as if it needs both calls to action, I assume your DLL is waiting for that 2nd call before it actually instructs windows to make a change?
I've 

The reason behind this is, the background behind the statictext is set to "buttonface" which LB picks up as the windows default colour scheme.
Obviously buttonface doesn't have a value within LB so I cannot make a colour value that is buttonface.

As a side note
 BLACK       = HEXDEC("&H000000")
Doesn't actually produce black, it see zero and does nothing, this actually needs to be 00 00 01, it does clearly state in your docs that it must be greater than 0, but this might catch out new players.

[Walt Decker]

Sure you can.

TxtColor = HEXDEC("&HFAFAFF")  '<--- close to buttonface

CALLDLL #CTL, "SetProperty", YourCtl AS ULONG,  YourTxtKey$ AS PTR, TxtColor AS ULONG, YourBkgClr$ AS PTR, 1 AS ULONG, RetVal AS VOID  '<--- set initial forground and background

TxtColor = HEXDEC("&HCDEBFF")

CALLDLL #CTL, "SetProperty", YourCtl AS ULONG, YourTxtKey$ AS PTR, TxtColor AS ULONG, YourBkgClr$ AS PTR, 1 AS ULONG, RetVal AS VOID  '<--- change foreground

OR

CALLDLL #user32, "SetPropA", YourCtlHndl AS ULONG, YourTxtKey$ AS PTR, TxtColor AS ULONG, RetVal AS VOID

The latter takes 3 calls, 1 to set the foreground color, 1 to set the background color, and one to change the foreground color while leaving the background untouched.

The reason the value has to be greater than zero is GetPropA() returns zero if the property key is not present in the property list for the control or window.  Therefore, the dll needs a value greater than zero to determine if the property key is in the property list.

If you are talking about buttons, the only way I can change the color of a button is if the button is owner drawn.  That puts things at very different level.

[Tasp]

No this is strictly focusing statictext.

The issue with approximating Buttonface is as the image below. This is Win10 using default colour scheme. On a different machine or colour scheme this would produce something as odd looking.
As you can see the background is a slightly different colour to the window shade.



So this is why I was attempting to not change the background colour at all. 

I have tried not calling the set background command, I have also tried not even passing it to the function.
When I do this, nothing gets changed, only the physical word, the colours remain unchanged.
I have stripped away the unnecessary code relating to everything else and just left the statictext code. And commented out the 2nd call to change the background. If you uncomment out the 2nd call and the function calls. it does change both the foreground and background colouring. 


'===========================================================================
'                        STATCLR_TST_001
'===========================================================================


'<------------------------- control colors --------------------->
RED         = HEXDEC("&H0000FF")
BLACK       = HEXDEC("&H000001") 'Doesn't accept 00 00 00 as a colour
BUTTONFACE  = HEXDEC("&HFAFAFF")

GLOBAL RED, BUTTONFACE, BLACK, StaticTextHandle

[DEFINE.STATIC.CONTROLS]
STATICTEXT #SHO.LBL1, "LBL 1", 5, 5, 125, 40
BUTTON #SHO.BTN, "PUSH", CHANGE.PROPERTIES, UL, 100, 135, 50, 25

OPEN "LABELS" FOR WINDOW AS #SHO

[SET.PROPERTIES]
'####################################################
'
' SET PROPERTIES FOR CONTROLS ON WINDOW "LABELS"
' "TXTCLR": 32-bit Color of text; The string "TXTCLOR" is
'           a property key.  It can be anything you want,
'           e. g. "FORCOLOR", "TXT".
'           It can also be mix-cased and be expressed as a
'           string, e. g. Prop1$ = "ForeColor".
'
' "BKGCLR": See above
'
'####################################################
OPEN "CTL_COLOR" FOR DLL AS #CTL
WinHndl = HWND(#SHO)
#SHO.LBL1, "!font tahoma 20"

StaticTextHandle = HWND(#SHO.LBL1) '<--- static control handle


'  INITIALIZE THE DLL
CALLDLL #CTL, "FN_InitProperties", WinHndl AS ULONG, "TXTCLR" AS PTR, "BKGCLR" AS PTR, BmpHndl AS ULONG, 1 AS LONG, RetVal AS LONG


PRINT #SHO, "TRAPCLOSE DMO.END"

WAIT

'----------------------------------------------------------
'----------------------------------------------------------

SUB CHANGE.PROPERTIES BtnHndl$

   RetVal = FN.SetProperties(StaticTextHandle, "TXTCLR", RED)' , "BKGCLR", BUTTONFACE)

   '<-------------- change static control text -------------------->
   #SHO.LBL1, "Changed!"

END SUB

'----------------------------------------------------
'----------------------------------------------------

SUB DMO.END WinHndl$
'###############################################################
'     clean up
'###############################################################

   CtlHndl = HWND(#SHO.LBL1)
   RetVal = FN.KillProperties(WinHndl, "TXTCLR", "BKGCLR")

   WinHndl = HWND(#SHO)
   CALLDLL #CTL, "FN_CLOSE", WinHndl AS ULONG, RetVal AS VOID

   CLOSE #SHO
   CLOSE #CTL

   STOP

END SUB

'-----------------------------------------------------------------------
'-----------------------------------------------------------------------

FUNCTION FN.SetProperties(WinHndl, TxtKey$, TxtColor)', BkgKey$, BkgColor)

   CALLDLL #user32, "SetPropA", WinHndl AS ULONG, TxtKey$ AS PTR, TxtColor AS ULONG, RetVal AS VOID
   'CALLDLL #user32, "SetPropA", WinHndl AS ULONG, BkgKey$ AS PTR, BkgColor AS ULONG, RetVal AS VOID

END FUNCTION

'-----------------------------------------------------------------------
'-----------------------------------------------------------------------

FUNCTION FN.KillProperties(WinHndl, TxtKey$, BkgKey$)

   CALLDLL #user32, "RemovePropA", WinHndl AS ULONG, TxtKey$ AS PTR, RetVal AS VOID
   CALLDLL #user32, "RemovePropA", WinHndl AS ULONG, BkgKey$ AS PTR, RetVal AS VOID

END FUNCTION


[Walt Decker]

Ok. I will make a small change in the dll so that if the background color is not there it will check the foreground color instead.

I will also look up the value of buttonface for you. Check back later today. The changed dll will be in the post where you obtained the original with a note indicating that it is updated.

[Walt Decker]

The dll is updated. See post #1

[Tasp]

Thanks for the update.

This is certainly a simple way to change the statictext colour 'on the fly'.

I think the stumbling block for me was the ButtonFace colour, if you know what that is by grabbing the info from GetSysColor , which I had found and had just been attempting to work out how to retrieve the info when you beat me too it!

For anyone looking to alter statictext colour in the future, here's the code I used;

'===========================================================================
'                        STATCLR_TST_001
'===========================================================================

GLOBAL RED, SysColor, StaticTextHandle

[DEFINE.STATIC.CONTROLS]
STATICTEXT #SHO.LBL1, "LBL 1", 5, 5, 125, 40
BUTTON #SHO.BTN, "PUSH", CHANGE.PROPERTIES, UL, 100, 135, 50, 25

'Open Window and DLL
OPEN "LABELS" FOR dialog AS #SHO
OPEN "CTL_COLOR" FOR DLL AS #CTL
WinHndl = HWND(#SHO)
#SHO.LBL1, "!font tahoma 20"
#SHO, "TRAPCLOSE DMO.END"

'Collect handle of statictext item
StaticTextHandle = HWND(#SHO.LBL1)

'INITIALIZE THE DLL & ASSOCIATED INFO
RED = HEXDEC("&H0000FF")
COLOR.BTNFACE = 15
CALLDLL #user32, "GetSysColor", COLOR.BTNFACE AS ULONG, SysColor AS ULONG
CALLDLL #CTL, "FN_InitProperties", WinHndl AS ULONG, "TXTCLR" AS PTR, "BKGCLR" AS PTR, BmpHndl AS ULONG, 0 AS LONG, RetVal AS LONG

WAIT

'----------------------------------------------------------
'----------------------------------------------------------

SUB CHANGE.PROPERTIES BtnHndl$

   RetVal = FN.SetProperties(StaticTextHandle, "TXTCLR", RED , "BKGCLR", SysColor)

   '<-------------- change static control text -------------------->
   #SHO.LBL1, "Changed!"

END SUB

'----------------------------------------------------
'----------------------------------------------------

SUB DMO.END WinHndl$
'###############################################################
'     clean up
'###############################################################

   CtlHndl = HWND(#SHO.LBL1)
   RetVal = FN.KillProperties(WinHndl, "TXTCLR", "BKGCLR")

   WinHndl = HWND(#SHO)
   CALLDLL #CTL, "FN_CLOSE", WinHndl AS ULONG, RetVal AS VOID

   CLOSE #SHO
   CLOSE #CTL

   STOP

END SUB

'-----------------------------------------------------------------------
'-----------------------------------------------------------------------

FUNCTION FN.SetProperties(WinHndl, TxtKey$, TxtColor, BkgKey$, BkgColor)

   CALLDLL #user32, "SetPropA", WinHndl AS ULONG, TxtKey$ AS PTR, TxtColor AS ULONG, RetVal AS VOID
   CALLDLL #user32, "SetPropA", WinHndl AS ULONG, BkgKey$ AS PTR, BkgColor AS ULONG, RetVal AS VOID

END FUNCTION

'-----------------------------------------------------------------------
'-----------------------------------------------------------------------

FUNCTION FN.KillProperties(WinHndl, TxtKey$, BkgKey$)

   CALLDLL #user32, "RemovePropA", WinHndl AS ULONG, TxtKey$ AS PTR, RetVal AS VOID
   CALLDLL #user32, "RemovePropA", WinHndl AS ULONG, BkgKey$ AS PTR, RetVal AS VOID

END FUNCTION


For other controls and window elements, Walt has included info within the DLL ZIP file.

Thanks Walt for your assistance and DLL

Do you have a license/restrictions/distribution requirements for using your DLL within software we create?

[Walt Decker]

There are no restrictions. Just let me know when it does not perform as expected.

You have an error in your code and you will get some unexpected results unless you have done something you are not showing:


CALLDLL #CTL, "FN_InitProperties", WinHndl AS ULONG, "TXTCLR" AS PTR, "BKGCLR" AS PTR, BmpHndl AS ULONG, 1 AS LONG, _ '<--- if BmpHndl has a value and you have
                                             'not loaded a bitmap this might turn
                                             'your form to black
RetVal AS LONGinsert code here

[Tasp]

I did miss that, I am not loading a BMP, so the handle would be zero.

I would imagine good practice would be to set this to 0, just incase BmpHndl ever gets set.

Post updated.

[Walt Decker]

Nov 14, 2021 12:17:10 GMT -5 Tasp said:

I did miss that, I am not loading a BMP, so the handle would be zero.

I would imagine good practice would be to set this to 0, just incase BmpHndl ever gets set.

Post updated.

Not true.  BmpHndl can be a color value.  Whether it is a color value for painting the client area depends on the value of BmpTrue.  If BmpTrue is false (zero), BmpHndl is interpreted as a color.  If BmpTrue is true (<> 0) BmpHndl is interpreted as a previously loaded DIBsection.

A bitmap can be loaded either with LoadImage() or LB's LOADBMP.  If LOADBMP is used the handle you would use for BmpHndl is that obtained from HBMP("BITMAPNAME").  If a bitmap is loaded it is tiled vertically and horizontally on the client area.

You are in charge.  You just have to let the dll know what you want. 

Incidentally, the control background color can now be zero.  If it is zero the engine defaults to the windoz default color.

EDIT:

You should set the control properties BEFORE initializing the dll.  That way they will go into effect immediately.  Otherwise they will not go into effect until there is a change in the controls.

[nr8s]

This is great, Walt! Being able to change the background color and text color of a Listbox enhances the look and sophistication of the GUI. Thank you for sharing!

[Walt Decker]

Nov 25, 2021 12:11:05 GMT -5 nr8s said:

This is great, Walt! Being able to change the background color and text color of a Listbox enhances the look and sophistication of the GUI. Thank you for sharing!

You are welcome.

Don't forget to try out the form window coloring and bitmap tiling options for a more professional look.