LB Build 353 leftButtonMove

[Rod]

This relates to the Scrabble code but is an extract of drawx.bas to show the issue. It appears some mouse tracking is not happy when a sub is used.

This works:
nomainwin

   graphicbox #1.graph, 5, 37, 300, 200

   WindowWidth = 312
   WindowHeight = 282

   open "Liberty Draw" for window as #1
   print #1, "trapclose [quit]"
   print #1.graph, "when rightButtonUp [cls]"
   print #1.graph, "down"
   print #1.graph, "color black"
 
[setForLine]
   print #1.graph, "when leftButtonDown [startDraw]"
   print #1.graph, "when leftButtonMove [firstLine]"
   print #1.graph, "when leftButtonUp [finishLine]"
   wait

[startDraw]
   startX = MouseX
   startY = MouseY
   print #1.graph, "place "; startX; " "; startY
   wait

[firstLine]
   print #1.graph, "when leftButtonMove [trackLine]"
   print #1.graph, "line "; startX; " "; startY; " "; MouseX; " "; MouseY
   oMouseY = MouseY
   oMouseX = MouseX
   wait

[trackLine]
   print #1.graph, "color white"
   print #1.graph, "line "; startX; " "; startY; " "; oMouseX; " "; oMouseY
   print #1.graph, "color black"
   print #1.graph, "place "; startX; " "; startY
   print #1.graph, "line "; startX; " "; startY; " "; MouseX; " "; MouseY
   oMouseY = MouseY
   oMouseX = MouseX
   wait

[finishLine]
   print #1.graph, "when leftButtonMove [firstLine]"
   print #1.graph, "discard"
   print #1.graph, "line "; startX; " "; startY; " "; MouseX; " "; MouseY
   print #1.graph, "flush ; redraw"
   wait

[cls]
   print #1.graph, "cls"
   wait

[quit]
   close #1
   end

This sub version does not, unless I have a stupid coding mistake. But it mirrors what happens in Scrabble Assist.bas

   'nomainwin
   global startX,startY,oMouseX,oMouseY
   graphicbox #1.graph, 5, 37, 300, 200

   WindowWidth = 312
   WindowHeight = 282

   open "Liberty Draw" for window as #1
   print #1, "trapclose quit"
   print #1.graph, "when rightButtonUp clearscreen"
   print #1.graph, "down"
   print #1.graph, "color black"
   print #1.graph, "when leftButtonDown startDraw"
   print #1.graph, "when leftButtonMove firstLine"
   print #1.graph, "when leftButtonUp finishLine"
   wait

sub startDraw
   print "got start"
   startX = MouseX
   startY = MouseY
   print #1.graph, "place "; startX; " "; startY
end sub

sub firstLine
   print "Got firstline"
   print #1.graph, "when leftButtonMove trackLine"
   print #1.graph, "line "; startX; " "; startY; " "; MouseX; " "; MouseY
   oMouseY = MouseY
   oMouseX = MouseX
end sub

sub trackLine
   print #1.graph, "color white"
   print #1.graph, "line "; startX; " "; startY; " "; oMouseX; " "; oMouseY
   print #1.graph, "color black"
   print #1.graph, "place "; startX; " "; startY
   print #1.graph, "line "; startX; " "; startY; " "; MouseX; " "; MouseY
   oMouseY = MouseY
   oMouseX = MouseX
end sub

sub finishLine
   print #1.graph, "when leftButtonMove firstLine"
   print #1.graph, "discard"
   print #1.graph, "line "; startX; " "; startY; " "; MouseX; " "; MouseY
   print #1.graph, "flush ; redraw"
end sub

sub clearscreen
   print "got clearscreen"
   print #1.graph, "cls"
end sub

sub quit h$
   close #1
end sub

[Carl Gundel]

Apr 6, 2022 9:24:49 GMT -5 Rod said:

This relates to the Scrabble code but is an extract of drawx.bas to show the issue. It appears some mouse tracking is not happy when a sub is used.

Thanks.  I appreciate it when you take the time to craft a simplest example.

[tsh73]

Run this as it is in LB4.
It goes like this:
each click triggers sub handler,
it increments zzz,
draws circle at point clicked,
draws at same point zzz,
prints "got start sub1 " and coords clicked
prints "got out"
draws word "out".
I guess it really gets out, next click repeats sequence.

Now LB5 (LB5.353 32 bit on win10 32 bit)
FIRST click triggers sub handler,
it increments zzz,
draws circle at point clicked,
draws at same point zzz,
somehow draws the word "OUT" - should it be out of sub already after that?
BUT
there is 2 prints to mainwin in between?
It goes weirder still
it happened to print "got start sub1 "
but coords and next print happens only AFTER I move mouse OUT of graphicbox.

And sub did not fire on click after.

(Oh, flush and redraw was adden in attempt to make it work in both LB4 and LB5
Problem in LB5 I do not see stuff drawn at all unless I add
print #1.graph, "redraw"

Now, on LB4 it redraws only things after last flush
draw stuff1-redraw-draw stuff2 - flush - redraw end swith "stuff2"

On LB5 I need redraw just to see a thing. Don't depends on flush.
)

   global zzz
   graphicbox #1.graph, 5, 37, 300, 200

   WindowWidth = 312
   WindowHeight = 282

   open "Liberty Draw" for window as #1
   print #1, "trapclose quit"
   print #1.graph, "down"
   print #1.graph, "when leftButtonDown subDraw"
   'print #1.graph, "when leftButtonDown [lblDraw]"
   wait

sub subDraw handle$,x,y
   'print #1.graph, "fill cyan"
   print #1.graph, "place "; x; " "; y
   print #1.graph, "circlefilled 5"
   zzz=zzz+1
   print #1.graph, "\";zzz
   'print #1.graph, "redraw"

   print "got start sub1 "; x; " "; y
   print "got out "

   print #1.graph, "place "; 150; " "; 150
   print #1.graph, "\out"

   print #1.graph, "flush"
   print #1.graph, "redraw"
end sub

[lblDraw] 'handle$,x,y
   x = MouseX
   y = MouseY
   print "got start2 "; x; " "; y
   print #1.graph, "place "; x; " "; y
   print #1.graph, "color blue"
   print #1.graph, "circlefilled 5"
wait

sub quit h$
   close #1
end sub