Timer in a loop

[tsh73]

Two lines marked ('!!!!!) fixes that program for me.
EDIT: actually three
Have a look.
'Timer Demo  Aug. 03, 2022
   
   nomainwin
   
   WindowWidth=1160:WindowHeight=480
   UpperLeftX=1:UpperLeftY=1
   
   button #main.start "SHUFFLE",[shuffle],     UL, 15, 200, 70, 30
   graphicbox #main.shuffleind,                    15, 230, 70,  5  
   
   graphicbox #main.g, 0, 30, 1150, 440
   open "Timer Demo" for window_nf as #main
   #main "trapclose [quit]"

   'graphicbox handle
   hBox=hwnd(#main.g)

   'open the cards dll
   open "qcard32.dll" for dll as #qc
 
   'background
   #main.g "down; fill 15 190 225"

   numcards = 52
   dim num(numcards)
   dim cards (100)
   gosub [shuffle]
   wait
 
[shuffleindclear]
   #main.shuffleind, "down; fill white"
   timer 0
goto [afterScan] '!!!!!
   'wait
 
[shuffle]
   #main.shuffleind, "down; fill red"   'turns on LED
   timer 100, [shuffleindclear]  'should turn off LED after 100 ms
   
   Call InitializeDeck hBox
   
   FOR j = 1 to 52
       num(j) = j
   NEXT j

[randomize]
   FOR j = 1 to numcards
       r = int(rnd(1)* numcards + 1)
       temp = num(j)
       num(j) = num(r)
       num(r) = temp
   NEXT

   'draw cards
   FOR j = 1 to numcards
scan '!!!!!
[afterScan] '!!!!!
       i = i + 1
       cards(i) = num(j)
       print "Cards = ";i; "      "; cards(i)
       nc = cards(i)  
       face = 1
       Call SetCardStatus nC,face
       Call DealCard hBox,nc,i * 20,50
       call Pause 10   'normally zero delay
   NEXT
   
   i = 0
   wait

[quit] close #qc:close #main:end

'subs and functions:

Sub Pause ms
   'pause ms number of milliseconds
   calldll #kernel32,"Sleep",_
   ms as long, re as void
   End Sub

Sub InitializeDeck hndle
   calldll #qc, "InitializeDeck",_
   hndle as long,r as long
   End Sub

Sub DealCard hndle,nC,x,y
   'places card on window whose handle is hndle at x,y
   'nC is number of card - 1-52 in first deck and
 
   calldll #qc, "DealCard",hndle as long,nC as long,_
   x as long,y as long,r as void
   End Sub

Sub SetCardStatus nC,face
   'nC is number of card:  1-52
   
   'face:  0=facedown,1=faceup
   calldll #qc, "SetCardStatus",nC as long,_
   face as long,r as void
   End Sub

[Walt Decker]

DELETE FROM [SHUFFLE]:

IF Milisecs THEN GOTO [SCAN.ONCE]

Milisecs = 100

ADD IN SUB DRAW.CARDS:

face = 1
SCAN '<---- ADD
Call SetCardStatus nc,face
Call DealCard hBox,nc,i * 20,50
call Pause 10 'normally zero dela
NEXT
IF Milisecs = 0 THEN Milisecs = 100 '<--- ADD

[tsh73]

Indeed there is a way without jumping back into the loop.
Use SUB timer.
(I remember having SUB timer tends to hang on window move/resize, not sure
But I did not managed to make it hang here
)
So
timer 300, shuffleindclear
and
sub   shuffleindclear
   #main.shuffleind, "down; fill white"
   timer 0
end sub


[turtleman]

WOW! It looks like it's finally doing what I need – and I was sooooo close. I tried using "return" instead of "goto [afterScan]", but of course, that didn't work. I'll try integrating the example code into the real program as soon as I get the chance. The LED is just a bell and whistle, but I like bells and whistles! Thanks a bunch!

[Rod]

Here is the simplest fix I can see. I just make your handler a Sub and I insert a single scan in the drawing loop. Now the led dims at 100ms.

'Timer Demo  Aug. 03, 2022

   nomainwin

   WindowWidth=1160:WindowHeight=480
   UpperLeftX=1:UpperLeftY=1

   button #main.start "SHUFFLE",[shuffle],     UL, 15, 200, 70, 30
   graphicbox #main.shuffleind,                    15, 230, 70,  5

   graphicbox #main.g, 0, 30, 1150, 440
   open "Timer Demo" for window_nf as #main
   #main "trapclose [quit]"

   'graphicbox handle
   hBox=hwnd(#main.g)

   'open the cards dll
   open "qcard32.dll" for dll as #qc

   'background
   #main.g "down; fill 15 190 225"

   numcards = 52
   dim num(numcards)
   dim cards (100)
   gosub [shuffle]
   wait


[shuffle]
   #main.shuffleind, "down; fill red"   'turns on LED
   timer 100, shuffleindclear  'should turn off LED after 100 ms

   Call InitializeDeck hBox

   FOR j = 1 to 52
       num(j) = j
   NEXT j

[randomize]
   FOR j = 1 to numcards
       r = int(rnd(1)* numcards + 1)
       temp = num(j)
       num(j) = num(r)
       num(r) = temp
   NEXT

   'draw cards
   FOR j = 1 to numcards
       i = i + 1
       cards(i) = num(j)
       print "Cards = ";i; "      "; cards(i)
       nc = cards(i)
       face = 1
       Call SetCardStatus nC,face
       Call DealCard hBox,nc,i * 20,50
       call Pause 10   'normally zero delay
       scan
   NEXT

   i = 0
   wait

[quit] close #qc:close #main:end

'subs and functions:

Sub shuffleindclear
   timer 0
   #main.shuffleind, "down; fill white"
   end sub

Sub Pause ms
   'pause ms number of milliseconds
   calldll #kernel32,"Sleep",_
   ms as long, re as void
   End Sub

Sub InitializeDeck hndle
   calldll #qc, "InitializeDeck",_
   hndle as long,r as long
   End Sub

Sub DealCard hndle,nC,x,y
   'places card on window whose handle is hndle at x,y
   'nC is number of card - 1-52 in first deck and

   calldll #qc, "DealCard",hndle as long,nC as long,_
   x as long,y as long,r as void
   End Sub

Sub SetCardStatus nC,face
   'nC is number of card:  1-52

   'face:  0=facedown,1=faceup
   calldll #qc, "SetCardStatus",nC as long,_
   face as long,r as void
   End Sub



[turtleman]

Rod: You latest code version is FANTASTIC! For some reason, I was having difficulties trying to integrate previous examples into my program, but this one worked perfectly from the get-go. (My example code is an extremely simplified snippet from what's in the actual program, which has a ridiculous 19K lines! I'm not bragging – it's far better to have the smallest number of lines, and I'm sure a semi competent programmer could reduce mine by half or more.) Thanks a bunch!!!

[Rod]

Liberty is an event driven BASIC. Events can be fired by buttons or keys or timers or the mouse. You code to handle those events. Code is in blocks. A block of code falls into another block or stops and waits. A code block may loop. If it loops you have to manage how events are handled. You can just leave the event unhandled till the loop stops at a wait or you can handle the event inside the loop with a scan. If you handle the event inside the loop you must arrange to return to the loop. Use gosub [branch] or use a Sub as we did in this example.

So you have all these code blocks. Some are handlers some are loops, some are functions. Always you must think about program flow.

Never jump out a loop, gosub [branch], call Sub or if you must Exit While, Exit For to stop the loop prematurely and move on.

But in your case we just needed to blip outside the loop for an instance and return to it from the sub. Thus the program flow is preserved.