Serial message byte decoding

[msteffes]

Hello Gang,

Below is a segment of code that I loop through to detect bits in a serial message package and then set or reset corresponding radio buttons.

It works well enough but I think there might be a faster cleaner way to do this. The full routine inspects three consecutive bytes extracted from a message packet.

The routine is constantly checking new messages coming in the serial port. The program dictates the speed since it is sending out polling messages at about 100ms interval

and then waits on the response. One issue I have seen is if the hardware address is changed on the fly( to look at a different device) the bit sequencing can get jumbled or out

of sequence and the app has to be restarted to recover. I want to be able to seamlessly jump from one address to another. I am sure I can modify my existing code to

accommodate this but would like to clean up the process of decoding the bits first if possible.



'###########################################

'##### 'setup Rad btn status for byt 5 #####

'###########################################



'''''not visible chars---print "BufrCurntInputMsg$ _> " +  BufrCurntInputMsg$

byteInWork = asc(mid$(BufrCurntInputMsg$,5,1))'



'Dead Blt Ext

        if byteInWork >= 128 then

           byteInWork = byteInWork - 128

           print #main.radiobutton8,"set"

        else

           if byteInWork < 128 then

               #main.radiobutton8,"reset"

           end if

        end if



'*********************************************************

'Clutch

       if byteInWork >= 64 then 'Clutch



           #main.radiobutton7,"set"

           byteInWork = byteInWork - 64

       else

           if byteInWork < 64 then

               #main.radiobutton7,"reset"

           end if

       end if



'*********************************************************

'Motor Stld

      if byteInWork >= 32 then  'Motor Stld

           #main.radiobutton6,"set"

           byteInWork = byteInWork - 32

      else

           if byteInWork < 32 then

                #main.radiobutton6,"reset"

           end if

      end if

'*********************************************************

'Cache

      if byteInWork >= 16 then



          #main.radiobutton5,"set"

          byteInWork =  InWork - 16

      else

           if byteInWork < 16 then

               #main.radiobutton5,"reset"

           end if

      end if 'xzxzx



'**********************************

'RSD Tmp

       if byteInWork >= 8 then



           #main.radiobutton4,"set"

           byteInWork = byteInWork - 8

      else

          if byteInWork < 8 then

               #main.radiobutton4,"reset"

          end if

      end if



'*********************************************************

'RF Loss

      if byteInWork >= 4 then

"

           #main.radiobutton3,"set"

           byteInWork = byteInWork - 4

      else

          if byteInWork < 4 then

              #main.radiobutton3,"reset"

          end if

      end if



'*********************************************************

'Low Batt

      if byteInWork >= 2 then



           #main.radiobutton2,"set"

           byteInWork = byteInWork - 2

       else

           if byteInWork < 2 then

              #main.radiobutton2,"reset"

           end if

       end if

'*********************************************************

'RDR Tmp

       if byteInWork >= 1 then 'RDR Tmp

           #main.radiobutton1,"set"

           byteInWork = byteInWork - 1

       else

          if byteInWork < 1 then"

             #main.radiobutton1,"reset"

          end if

      end if





[tsh73]

Just to say, you cannot set several radiobuttons at once
By definition there is ONLY ONE radio button could be set
_{(unless you do something strange)}

Probably you mean checkboxes.

Have a look:
'   Form created with the help of Freeform-J v.261006
'   Generated on Jan 24, 2023 at 00:46:18

'    nomainwin

   WindowWidth = 550
   WindowHeight = 410

   UpperLeftX=int((DisplayWidth-WindowWidth)/2)
   UpperLeftY=int((DisplayHeight-WindowHeight)/2)

   textbox #main.textbox1, 26, 16, 100, 25
   button #main.button2, "Set checkboxs", [button2Click], UL, 174, 16, 122, 25
   button #main.button3, "Randomize", [button3Click], UL, 304, 16, 122, 25
   checkbox #main.checkbox1, "checkbox 1", rbSet, rbReSet, 22, 56, 168, 20
   checkbox #main.checkbox2, "checkbox 2", rbSet, rbReSet, 22, 76, 168, 20
   checkbox #main.checkbox3, "checkbox 3", rbSet, rbReSet, 22, 96, 168, 20
   checkbox #main.checkbox4, "checkbox 4", rbSet, rbReSet, 22, 116, 168, 20
   checkbox #main.checkbox5, "checkbox 5", rbSet, rbReSet, 22, 136, 168, 20
   checkbox #main.checkbox6, "checkbox 6", rbSet, rbReSet, 22, 156, 168, 20
   checkbox #main.checkbox7, "checkbox 7", rbSet, rbReSet, 22, 176, 168, 20
   checkbox #main.checkbox8, "checkbox 8", rbSet, rbReSet, 22, 196, 168, 20

   open "Set checkboxs by number" for window as #main
   print #main, "trapclose [quit.main]"

   print #main, "font ms_sans_serif 10"

   goto [button3Click]

   wait

[quit.main]
   Close #main
   END


[button2Click]    'Perform action for the button named 'button2'
   #main.textbox1 "!contents? n"
   'notice n
   for i = 1 to 8
       hndl$="#main.checkbox";i
       d = n mod 2
       'print i, n, d, hndl$
       if d then #hndl$ "set" else #hndl$ "reset"
       n=int(n/2)
   next

   wait

[button3Click]     '"Randomize"
   n=int(rnd(0)*256)
   #main.textbox1 n
wait


sub rbSet handle$    'Perform action for the checkbox named 'checkbox3'
   'Insert your own code here
end sub


sub rbReSet handle$    'Perform reset for the checkbox named 'checkbox3'
   'Insert your own code here
end sub


[msteffes]

Thanks, I really wanted the look of the radio buttons. It took a bit more code

The below snippet works nicely

'Group boxes make the radio buttons they contain (are within the x, y confines of
'the group box) mutually exclusive to each other, only one can be selected
'If you want a radio button to act independently put it in a group box alone.



   'Radio buttons to show various lock status
   Radiobutton #main.radiobutton1,"",[nil],[nil],30,30,20,10 'Rex
   Radiobutton #main.radiobutton2,"",[nil],[nil],30,80,20,10 'Ren
   Radiobutton #main.radiobutton3,"",[nil],[nil],30,130,20,10 'key OverRd
   Radiobutton #main.radiobutton4,"",[nil],[nil],120,30,20,10 'IPB
   Radiobutton #main.radiobutton5,"",[nil],[nil],120,80,20,10 'DPS
   Radiobutton #main.radiobutton6,"",[nil],[nil],120,130,20,10 'Rdr Tmpr
   Radiobutton #main.radiobutton7,"",[nil],[nil],210,30,20,10 'unlocked
   Radiobutton #main.radiobutton8,"",[nil],[nil],210,80,20,10 ' Cltch UNLkd
   Radiobutton #main.radiobutton9,"",[nil],[nil],210,130,20,10 'Mtr Stl


   Groupbox #main.groupbox1," REX",10,10,50,40
   Groupbox #main.groupbox2," REN",10,60,50,40
   Groupbox #main.groupbox3,"KEY OVR",10,110,50,40
   Groupbox #main.groupbox4,"IPB",100,10,50,40
   Groupbox #main.groupbox5,"DPS",100,60,50,40
   Groupbox #main.groupbox6," RDR TMP",100,110,50,40
   Groupbox #main.groupbox7,"UNLCK",190,10,50,40
   Groupbox #main.groupbox8,"CLT UNLK",190,60,50,40
   Groupbox #main.groupbox9,"MTR STL",190,110,50,40


[Brandon Parker]

Also, you can simply hide the GroupBoxes if you wish to have just the RadioButtons showing. The execution of the program will perform as expected where each and every RadioButton is selectable. This is achievable because of the way Windows treats controls that are located within the bounds of individual GroupBoxes...

   NoMainWin

   'Radio buttons to show various lock status
   Radiobutton #main.radiobutton1, "", doNothing, doNothing, 30, 30, 20, 10
   Radiobutton #main.radiobutton2, "", doNothing, doNothing, 30, 80, 20, 10
   Radiobutton #main.radiobutton3, "", doNothing, doNothing, 30, 130, 20, 10
   Radiobutton #main.radiobutton4, "", doNothing, doNothing, 120, 30, 20, 10
   Radiobutton #main.radiobutton5, "", doNothing, doNothing, 120, 80, 20, 10
   Radiobutton #main.radiobutton6, "", doNothing, doNothing, 120, 130, 20, 10
   Radiobutton #main.radiobutton7, "", doNothing, doNothing, 210, 30, 20, 10
   Radiobutton #main.radiobutton8, "", doNothing, doNothing, 210, 80, 20, 10
   Radiobutton #main.radiobutton9, "", doNothing, doNothing, 210, 130, 20, 10


   Groupbox #main.groupbox1, "", 10, 10, 50, 40
   Groupbox #main.groupbox2, "", 10, 60, 50, 40
   Groupbox #main.groupbox3, "", 10, 110, 50, 40
   Groupbox #main.groupbox4, "", 100, 10, 50, 40
   Groupbox #main.groupbox5, "", 100, 60, 50, 40
   Groupbox #main.groupbox6, "", 100, 110, 50, 40
   Groupbox #main.groupbox7, "", 190, 10, 50, 40
   Groupbox #main.groupbox8, "", 190, 60, 50, 40
   Groupbox #main.groupbox9, "", 190, 110, 50, 40

   Open "Test" For Window As #main
   #main "TrapClose quit"
   For i = 1 To 9
       handle$ = "#main.groupbox";i
       #handle$ "!Hide"
   Next i
   Wait

   Sub quit handle$
       Close #handle$
       End
   End Sub

   Sub doNothing handle$
       Notice "You selected - ";handle$
   End Sub


{:0)

Brandon Parker

[msteffes]

Going back to the original question.
Does anyone have a better approach to boiling down the byte massage bits as I have done to set/reset a group of radio buttons. I guess the radio buttons are a secondary action, it could be anything thing that is acted on when a given bit is detected set or not.

[Rod]

You would normally use AND to check a bit. So if byteInWork AND 8 then it’s set.

[tsh73]

Going back to the original question.
Does anyone have a better approach to boiling down the byte massage bits as I have done to set/reset a group of radio buttons.

How about this piece of code from my reply above?

[button2Click]    'Perform action for the button named 'button2'
   #main.textbox1 "!contents? n"
   'notice n
   for i = 1 to 8
       hndl$="#main.checkbox";i
       d = n mod 2
       'print i, n, d, hndl$
       if d then #hndl$ "set" else #hndl$ "reset"
       n=int(n/2)
   next

   wait

[Rod]

Back to basics, if it helps.


'bit0=1=set
'bit1=2=set
'bit2=4=set
'bit3=8=set
'bit4=16=set
'bit5=32=set
'bit6=64=set
'bit7=128=set
byte=0
byte=byte or 1 'set bit0
byte=byte or 32 'set bit5
print byte
print
n=1
for bit=0 to 7
   print "byte ";byte;" Bit ";bit;" ";
   if (byte and n) then print "on" else print "off"
   n=n*2
next


[msteffes]

Hi Rod,
Thanks , Your Basic approach was the most adaptable for my goal. Thanks to all commenters. Testing on my hardware Monday. I will let you know how it works out.

[msteffes]

Worked perfectly; cleaned and simplified the code.