Project - Music and Sound

[Rod]

I also found this in my archives, its a vu meter using mcisendstring.

'**************************************************************
'   Hank Doyle  October, 2010
'   VU meter for reading audio inputs from the sound card   ***
'   This reads the mciSendString 'level' status and         ***
'   display's it in a graphic box.                          ***
'   Feel free to use this code or modify in any way for     ***
'   your application.                                       ***
'**************************************************************
'modified by Rod using code by Richard and Chris to set the audio
'format and read the high and low level response

  ' nomainwin
   WindowWidth = 450
   WindowHeight = 130
   UpperLeftX=int((DisplayWidth-WindowWidth)/2)
   UpperLeftY=int((DisplayHeight-WindowHeight)/2)

   graphicbox #1.left,  23,  50, 400,  20
   graphicbox #1.right,  23,  75, 400,  20

   button #1.button1,"Start recording",[startRecording], UL,  25,  5, 120,  25
   button #1.button2,"Stop recording",[stopRecording], UL, 160, 5, 120, 25

   open "Vu meter" for window_nf as #1
   #1.left "down; fill white; flush"
   #1.left "backcolor green"
   #1.right "down; fill white; flush"
   #1.right "backcolor green"
   #1 "font ms_sans_serif 10"
   #1 "trapclose [quit]"
   wait


   [startRecording]
   'set the .wav recording format
   bitspersample = 16
   channels = 2
   samplespersec = 44100
   alignment = bitspersample * channels / 8
   bytespersec = alignment * samplespersec

   params$ = " bitspersample " + STR$(bitspersample)+_
           " channels " + STR$(channels) +_
           " alignment " + STR$(alignment) + _
           " samplespersec " + STR$(samplespersec) + _
           " bytespersec " + STR$(bytespersec)

   'we open two devices, one to listen and one to record
   'open wav audio to listen to the wavaudio
   r$=mciSendString$("open new type waveaudio alias wav")
   r$=mciSendString$("set wav "+params$)

   'open myRecording to record sound from mic
   r$=mciSendString$("open new type waveaudio alias myRecording")
   r$=mciSendString$("set myRecording "+params$)
   r$=mciSendString$("record myRecording") 'start the recording

   timer 50, [readVolume]
   wait

   [readVolume]
   #1.left "discard ; backcolor white"
   #1.left "boxfilled 400 25 ; backcolor green"
   #1.right "discard ; backcolor white"
   #1.right "boxfilled 400 25; backcolor green"
   r$=mciSendString$("status wav level")
   level = val(r$)
   left = hiWord(level)
   right = loWord(level)
   'log scale
   nl = 116 * log(left + 1) - 800
   nr = 116 * log(right + 1) - 800
   'record high for persistence
   'and lower it slowly
   nlh=nlh-10
   if nl>nlh then nlh=nl
   nrh=nrh-10
   if nr>nrh then nrh=nr
   'display green for exact reading
   'display yellow for historic high
   #1.left "backcolor yellow ; boxfilled ";nlh;" 20"
   #1.right "backcolor yellow ; boxfilled ";nrh;" 20"
   #1.left "backcolor green ; boxfilled ";nl;" 20"
   #1.right "backcolor green ; boxfilled ";nr;" 20"
   wait

   [stopRecording]
   timer 0
   #1.left "fill white"
   #1.right "fill white"
   r$=mciSendString$("close wav")
   r$=mciSendString$("close myRecording")
   wait

   [quit] 'End the program
   timer 0
   r$=mciSendString$("close wav")
   r$=mciSendString$("close myRecording")
   close #1
   end

Function mciSendString$(s$)
   'Buffer will contain a return string from
   'the function, if there is one.
   buffer$=space$(1024)+chr$(0)
   calldll #winmm,"mciSendStringA",s$ as ptr,buffer$ as ptr,_
   1028 as long, 0 as long, r as long
   'truncate returned string at null character
   buffer$=left$(buffer$, instr(buffer$, chr$(0)) - 1)
   if r>0 then
       mciSendString$="error"
   else
   mciSendString$=buffer$
   end if
End Function




Function hiWord(num)
   hiWord = int( num / (256^2))
End Function

Function loWord(num)
   loWord = num AND hexdec("FFFF")
End Function





[Rod]

Within this demo you will find more messages that manage recording and saving sounds.

       'this records saves and loads 1.5 second long
       'audio as 8bit .wav files it runs at
       '11025 samples per second for 1.5 seconds = 16537 samples
       'in each file. samples range from 0 to 255
       true=1
       false=0
       recording=false   ' are we recording right now or not?
       mid=127
       sampos=45

       WindowWidth = 800
       WindowHeight = 600
       UpperLeftX=int((DisplayWidth-WindowWidth)/2)
       UpperLeftY=int((DisplayHeight-WindowHeight)/2)



       nomainwin
       graphicbox #main.current, 130,   5, 630, 256
       graphicbox #main.library, 130, 266, 630, 256
       button #main.record,"Record",[record], UL,   5,   7,  90,  25
       button #main.save,"Save",[save], UL,   5,  37,  90,  25
       button #main.load,"Load",[load], UL,   5,  67,  90,  25
       button #main.play,"Play",[play], UL,   5,  97,  90,  25
       button #main.left,"<",[left], UL, 5,127,40,25
       button #main.right,">",[right], UL 55,127,40,25



       open "Sound Recording" for window as #main
       print #main.current, "down; fill darkgray; flush"
       print #main.library, "down; fill darkgray; flush"
       print #main, "font ms_sans_serif 10"


[mainloop]
       wait
       goto [mainloop]

[record]
       if recording=true then wait
       r$=mciSendString$("close all")
       r$=mciSendString$("open new type waveaudio alias capture")
       gosub [setRate]
       r$=mciSendString$("record capture")
       if r$="error" then [error]
       recording=true
       t=time$("milliseconds")
       while time$("milliseconds")<t+1500
       wend
       r$=mciSendString$("stop capture")
       r$=mciSendString$("save capture capture.wav")
       r$=mciSendString$("close capture")
       recording=false
       gosub [chart]
       wait

[play]
       if recording=true then wait
       r$=mciSendString$("open capture.wav type waveaudio alias capture")
       if r$="error" then [error]
       r$=mciSendString$("play capture wait")
       r$=mciSendString$("close capture")
       wait

[save]
       if recording=true then wait
       filedialog "Save As","*.wav",wave$
       if wave$="" then wait
       if lower$(right$(wave$,4))<>".wav" then wave$=wave$+".wav"
       r$=mciSendString$("open capture.wav type waveaudio alias capture")
       if r$="error" then [error]
       r$=mciSendString$("save capture " + wave$)
       r$=mciSendString$("close capture")
       wait

[load]
       if recording=true then wait
       filedialog "Open As","*.wav",wave$
       if wave$="" then wait
       wave$=chr$(34)+wave$+chr$(34)
       r$=mciSendString$("open " +wave$+ " type waveaudio alias capture")
       if r$="error" then [error]
       r$=mciSendString$("save capture capture.wav")
       r$=mciSendString$("close capture")
       gosub [chart]
       wait




[chart]
       xpos=0
       print #main.current, "discard ;redraw ;down"
       print #main.library, "discard ;redraw ;down"
       open "capture.wav" for binary as #live
       length=lof(#live)
       seek #live, sampos
       for n=1 to 630
       samnum=asc(input$(#live, 1))
       if samnum>mid then
       print #main.current, "color red ;size 1; line ";xpos;" ";mid;" ";xpos;" ";samnum
       else
       print #main.current, "color red ;size 1; line ";xpos;" ";samnum;" ";xpos;" ";mid
       end if
       xpos=xpos+1
       next n
       close #live
       return

[right]
       sampos=sampos+630
       if sampos>length-630 then sampos=length-630
       gosub [chart]
       wait

[left]  sampos=sampos-630
       if sampos<45 then sampos=45
       gosub [chart]
       wait


[quit]
       close #main
       end


[setRate]
       r$=mciSendString$("set capture time format ms bitspersample 8")
       r$=mciSendString$("set capture channels 1 samplespersec 11025")
       r$=mciSendString$("set capture alignment 1 bytespersec 8000")
       return


Function GetShortPathName$(lPath$)
       lPath$=lPath$+chr$(0)
       sPath$=space$(256)
       lenPath=len(sPath$)
       calldll #kernel32, "GetShortPathNameA",lPath$ as ptr,_
       sPath$ as ptr,lenPath as long,r as long
       GetShortPathName$=left$(sPath$,r)
       end function



Function mciSendString$(s$)
       buffer$=space$(1024)+chr$(0)
       calldll #winmm,"mciSendStringA",s$ as ptr,buffer$ as ptr, 1028 as long, 0 as long, r as long
       buffer$=left$(buffer$, instr(buffer$, chr$(0)) - 1)
       if r>0 then
           mciSendString$="error"
       else
           mciSendString$=buffer$
       end if
       End Function






[Carl Gundel]

Thanks Rod so much for all this!

I need to sit down and soak it in.

-Carl

[Rod]

Having thought about it a little more I recon all we need in Liberty are three functions. setVol(device,left,right) , getVol(device,left right) and playmedia$(device,message$) Device will nearly always be 0 but sods law says the first user will want to control two media devices. Left and right are values between 0 and 65535. The message$ format will be a new tutorial on multimedia messaging. Whether left and right become system variables could be debated, the volume functions would simplify to setVol(device) , getVol(device)

The volume discussed is the volume of the stream the audio device opens specifically for Liberty BASIC. On my pc there is a Device volume, and an Application volume which Liberty appears to inherit. Once established Liberty can manage its own volume but has no impact on the Device or Application volumes.

So three simple functions giving us access to such stunning sound management appears to be a no brainer.