Leaving a control

[hal9k]

Between my aging mind and my lack of LB experience I don't remember how to do something that's probably easy.  I'm writing a program to manage the data in a file.  I have a window with a bunch of textboxes on it - one for each field of a record in the file.  When I have a record loaded into the textboxes I want to be able to change some of the values.  When I change a value and then move to another textbox I want to be able to validate the new data and set a flag that I will need to update the data file.  My problem is I can't find an event that I can trap when my user moves off of a textbox.  I'm thinking that there must be some event for this.

Thanks again for your help.

[Walt Decker]

There is not. However, if you want to use a timer event and a little API that can be managed fairly easily.

For example, assume you have three edit controls named #FORM.TXB1, #FORM.TXB2, and #FORM.TXB3:

'
'this assumes the bottom of your window declaration
[START.TIMER]
TIMER 100, [WAIT.TIMER]
WAIT

[WAIT.TIMER]
TIMER 0
CALLDLL #User32, "GetFocus", CurFocus AS ULONG
WinHndl = HWND(#FORM.TXB1)

IF WinHndl = Curfocus THEN
 DO SOMETHING
END IF

WinHndl = HWND(#FORM.TXB1)

IF WinHndl = Curfocus THEN
 DO SOMETHING
 GOTO [START.TIMER]
END IF

WinHndl = HWND(#FORM.TXB2)

IF WinHndl = Curfocus THEN
 DO SOMETHING
 GOTO [START.TIMER]
END IF

WinHndl = HWND(#FORM.TXB3)

IF WinHndl = Curfocus THEN
 DO SOMETHING
 GOTO [START.TIMER]
END IF

GOTO [START.TIMER]
'

[hal9k]

Wow! Thanks so much for the example. I will give it a try.
That said, it surprises me that there is no trapable event that fires when a user moves to or from a control. Maybe in a future release...

Thanks again!

[Walt Decker]

Most programming languages do not have an exit event for edit controls. If the programmer wants to trap an event for an edit control he will normally either add a "NEXT" button to h\er form or subclass the control or form to trap the "ENTER" key or the "TAB" key.

Here is a complete working example:
'
GLOBAL CurTxb

TEXTBOX #FRM.TXB1, 5, 5, 75, 20
TEXTBOX #FRM.TXB2, 85, 5, 75, 20
TEXTBOX #FRM.TXB3, 165, 5, 75, 20

OPEN "TEST" FOR WINDOW AS #FRM
#FRM, "TRAPCLOSE CLOSE.FRM"
CurTxb = HWND(#FRM.TXB1)
#FRM.TXB1, "!SETFOCUS"
[START.TIMER]
TIMER 100, [WAIT.TIMER]
WAIT

[WAIT.TIMER]
TIMER 0

LastFocus = 0
TxbHndl   = 0

CALLDLL #user32, "GetFocus", LastFocus AS ULONG

IF LastFocus = CurTxb THEN
 GOTO [START.TIMER]
END IF

IF LastFocus <> CurTxb THEN
 TxbHndl = HWND(#FRM.TXB1)
 IF LastFocus = TxbHndl THEN CurTxb = LastFocus

 TxbHndl = HWND(#FRM.TXB2)
 IF LastFocus = TxbHndl THEN CurTxb = LastFocus

 TxbHndl = HWND(#FRM.TXB3)
 IF LastFocus = TxbHndl THEN CurTxb = LastFocus

 PRINT "DO SOMETHING"
END IF

GOTO [START.TIMER]
[WAIT.TIMER.END]

SUB CLOSE.FRM Hndl$
CLOSE #Hndl$
END
END SUB
'

Just press the tab key to move from one edit control to the other.

[hal9k]

Thank you very much for your efforts and wisdom. This will be a big help!

[utaner]

The event you are looking for is the 'LostFocus' event. The LostFocus event is triggered when a user moves off of a textbox, and this is the perfect event to hook your validation process onto. You can find more information on the LostFocus event on the official Microsoft website here.

[Rod]

We don’t have a lost focus event in Liberty. We can get the current focus with an API and see that it has changed. But, the usual solution for the problem stated is to record the contents of all of the text boxes when they are originally filled, on exit or close the solution is to check those contents against the original contents and act accordingly if they have changed. No API required, simple solution,, you could tie yourself in knots following blow by blow textbox changes but here there is no need, chest check them all on exit.

[Walt Decker]

Here is an example that grabs the contents of the last edit control entry:
'
CurTxb$ = ""

TEXTBOX #FRM.TXB1, 5, 5, 70, 20
TEXTBOX #FRM.TXB2, 85, 5, 70, 20
TEXTBOX #FRM.TXB3, 160, 5, 70, 20

OPEN "TEST" FOR WINDOW AS #FRM
#FRM, "TRAPCLOSE CLOSE.FRM"

#FRM.TXB1, "!SETFOCUS"
CurTxb$ = "#FRM.TXB1"

[BEGIN.WAIT]
TIMER 500, [TXB.EVENT]
WAIT

'----------------------------
'----------------------------

[TXB.EVENT]
TIMER 0

TxbHndl   = 0
CurFocus  = 0

TxbStr$ = ""

TxbHndl = HWND(#CurTxb$)
CALLDLL #user32, "GetFocus", CurFocus as ULONG

IF CurFocus = TxbHndl THEN GOTO [BEGIN.WAIT]

SELECT CASE CurFocus
 CASE HWND(#FRM.TXB1)
   TxbStr$ = FN.GetTxbString$(CurTxb$)
   PRINT TxbStr$
   CurTxb$ = "#FRM.TXB1"

 CASE HWND(#FRM.TXB2)
   TxbStr$ = FN.GetTxbString$(CurTxb$)
   PRINT TxbStr$
   CurTxb$ = "#FRM.TXB2"

 CASE HWND(#FRM.TXB3)
   TxbStr$ = FN.GetTxbString$(CurTxb$)
   PRINT TxbStr$
   CurTxb$ = "#FRM.TXB3"
END SELECT
GOTO [BEGIN.WAIT]

[END.TXB.EVENT]

'----------------------------
'----------------------------

SUB CLOSE.FRM FrmHndl$

CLOSE #FrmHndl$
END

END SUB

'----------------------------
'----------------------------

FUNCTION FN.GetTxbString$(TxbTag$)

ReturnStr$ = ""

#TxbTag$, "!CONTENTS? ReturnStr$"

FN.GetTxbString$ = ReturnStr$
END FUNCTION
'

[Rod]

Is that not just getting the text of the currently selected textbox? The focus could have changed with tab enter or click within the 500ms.

[Walt Decker]

No. It takes longer than 500 ms to type something into an edit control and hit "TAB" or click on another control. Try it.

[Rod]

This is the knot tying bit, you might have it almost completely typed. So yes, you can move focus in less than 500ms, so leaving the edit unnoticed. On entry and on exit checks are far more encompassing. IMHO.