default button (ENTER) moving to nexr control in tab order

[tsh73]

really, metro's code in thread
Default Button reply from Jan 5, 2020 at 4:24pm with

for the input of numeric data I do prefer to be able to press enter
you can have both options...

is shorter
But he codes control order by hand

This program uses Windows tab order

'Default buttom moves to next tabControl demo
'tsh73, Jum 2020

[setup.main.Window]

   '-----Begin code for #main

   nomainwin
   WindowWidth = 550
   WindowHeight = 660
   UpperLeftX=int((DisplayWidth-WindowWidth)/2)
   UpperLeftY=int((DisplayHeight-WindowHeight)/2)


   '-----Begin GUI objects code

   TexteditorColor$ = "white"
   texteditor #main.textedit12,   5, 212, 520, 395
   TextboxColor$ = "white"
   textbox #main.textbox1,   5,   5, 100,  25
   textbox #main.textbox2,   5,  42, 100,  25
   textbox #main.textbox3,   5,  72, 100,  25
   textbox #main.textbox4, 120,   7, 100,  25
   textbox #main.textbox5, 120,  42, 100,  25
   textbox #main.textbox6, 120,  72, 100,  25

   button #main.default,"default button",[button7Click], UL,   5, 107,  128,  25
   stylebits #main.default, _BS_DEFPUSHBUTTON, 0, 0, 0

   button #main.button8,"gather data",[button8Click], UL,  145, 107,  128,  25

open "Default buttom moves to next tabControl" for window as #main
   print #main, "font ms_sans_serif 10"
   print #main, "trapclose [quit.main]"
   #main.textbox1,  "!setfocus"

   hmain = hWnd(#main) 'main window handle, will need later

   validHandles4tab$=" "
   for i = 1 to 6
       handle$="#main.textbox";i
       validHandles4tab$=validHandles4tab$;hWnd(#handle$);" "
   next
   #main.textedit12, validHandles4tab$

[main.inputLoop]   'wait here for input event
timer 50, [time]

   wait

[time]
   CallDLL #user32, "GetFocus", handle As long
   lastHndl =  handle
wait

[button7Click]   'Perform action for the button named 'button7'
   'what is current control (before activating default button that is)
   'does it valid textbox we want to handle (tab to next control on Enter)
   if instr(validHandles4tab$, " ";lastHndl;" ")<>0 then
       'get next tab order control
       CallDLL #user32, "GetNextDlgTabItem", _
           hmain As long, _
           lastHndl As long, _
           0 As long, _
           retHndl As long
       'switch to it
       CallDLL #user32, "SetFocus", retHndl As long, ret as long

       'some reporting
       'from control
       #main.textedit12, time$();"."; right$("";time$("ms"),3);" from ";Str$(lastHndl); _
       'to control
       #main.textedit12, " to ";Str$(retHndl)

       'set it to last control
           lastHndl = retHndl
   end if

   wait


[button8Click]   'Perform action for the button named 'button8'
   #main.textedit12, "data entered:"
   for i = 1 to 6
       handle$="#main.textbox";i
       #handle$, "!contents? value$"
       #main.textedit12, handle$;" ";value$
   next
   #main.textedit12, "----------------"

   wait

[quit.main] 'End the program
   close #main
   end



[mknarr]

Rather than us a Default Button, I prefer to do it with a timer. I use this technique in a lot of Dialog windows.

       'Enter key demo
       nomainwin
       WindowWidth = 355
       WindowHeight = 220
       UpperLeftX=int((DisplayWidth-WindowWidth)/2)
       UpperLeftY=int((DisplayHeight-WindowHeight)/2)
       TextboxColor$ = "white"
       statictext #main.st1,"",100,120,150,25
       textbox #main.tb1, 100, 20, 100, 25
       textbox #main.tb2, 100, 50, 100, 25
       textbox #main.tb3, 100, 80, 100, 25
       open "Enter Key Demo" for dialog_modal as #main
       print #main, "font arial 10"
       print #main, "trapclose [quit]"
       hTextbox1=hwnd(#main.tb1)'get handles of textboxes
       hTextbox2=hwnd(#main.tb2)
       hTextbox3=hwnd(#main.tb3)
       print #main.tb1,"!setfocus"
       timer 50, [enterkey]'goto [editkey] every 50 milliseconds to check for Enter key press
       wait
       [enterkey]
       CallDLL #user32, "GetAsyncKeyState",_VK_RETURN as long,fKeyPress as long
       if fKeyPress <0 then 'if Enter or Return key is pressed
           'set focus to next text box based on what text box currently has focus
           calldll #user32,"GetFocus",textboxHandle as long
           select case textboxHandle
               case hTextbox1
                   print #main.tb2,"!setfocus" 'set focus to next text box
               case hTextbox2
                   print #main.tb3,"!setfocus"
               case hTextbox3
                   'replace this section with the action that completes
                   'the operation the window is meant to perform
                   print #main.st1,"Action complete"
                   print #main.tb1,"!setfocus"
           end select
       end if
       wait
       [quit]
       close #main
       end


[ernie]

nomainwin

WindowWidth = 1000
WindowHeight = 600
UpperLeftX = INT((DisplayWidth-WindowWidth)/2)
UpperLeftY = INT((DisplayHeight-WindowHeight)/2)-15
BackgroundColor$ = "white"
ForegroundColor$ = "black"

statictext #main.nam, "Name", 40, 33, 45, 15
textbox #main.tb01, 40, 50, 200, 22

statictext #main.nar "Name to use in narrative", 40, 88, 200, 15
textbox #main.tb02, 40, 105, 200, 22

statictext #main.date, "Date", 40, 143, 40, 15
textbox #main.tb03, 40, 160, 120, 22

statictext #main.pp, "Presenting Problem", 40, 332, 120, 18
textbox #main.tb04, 40, 350, 200, 75

statictext #main.white, "Difficulties Notes", 374, 400, 100, 18
textbox #main.tb05, 374, 418, 440, 75

button #main.fakeTab, "", [next_tb], ul, 0, 0, 1, 1
stylebits #main.fakeTab, _BS_DEFPUSHBUTTON, 0, 0, 0

open "test" for window as #main

#main "trapclose [quit]"
#main.fakeTab "hide" 'allow cycling between text windows

#main.tb01, "!setfocus"

hText = hWnd(#main.tb03)
flag = _EM_LIMITTEXT
Call SendMessageLong hText,flag,400,0

hText = hWnd(#main.tb04)
flag = _EM_LIMITTEXT
Call SendMessageLong hText,flag,500,0

#main.fakeTab "hide" 'allow cycling between text windows

wait

[quit]
close #main
end


'ALLOW CYCLING BETWEEN TABS
[next_tb]
calldll #user32, "GetFocus", _
gotFocus as long
for i = 1 to 5
checkHandle$ = "#main.tb0"; i
nextBoxIndex = i+1
if nextBoxIndex > 5 then nextBoxIndex = 1
nextHandle$ = "#main.tb0"; nextBoxIndex
if gotFocus = hwnd(#checkHandle$) then
#nextHandle$, "!setfocus"
exit for
end if
next
wait


' LIMIT TEXT THAT CAN BE ENTERED IN TEXT BOX
Sub SendMessageLong hWnd,msg,w,l
CallDLL #user32, "SendMessageA",_
hWnd As long,_ 'window handle
msg As long,_ 'message
w As long,_ 'wParam
l As long,_ 'lParam
re As long
End Sub