Toast Notfications / Batch Code

[muXed]

Evening all!

On a recent project i've had to use toast notifications (A.K.A win10 notification messages)

Thought i'd share the code. Although actual true libertybasic code is minimal in this example... I'm sure there are better ways of utilising toaster notifications and using liberty herself instead of cmd

However my requirements were simple and i'm lacking in knowledg so here is my easy example:-

Please see below...

' Window   10+ Only....

nomainwin

REM Enter message below



toastmsg$ = "Test"

open "test.bat" for output as #f





print #f, "@if (@x)==(@y) @end /* JScript comment"

print #f, "@echo off"



print #f, "setlocal"

print #f, "del /q /f %~n0.exe >nul 2>&1"

print #f,"for /f ";chr$(34);"tokens=* delims=";chr$(34); " %%v in ('dir /b /s /a:-d /o:-n ";chr$(34); "%SystemRoot%\Microsoft.NET\Framework\*jsc.exe";chr$(34);"') do ("

print #f, "set ";chr$(34);"jsc=%%v";chr$(34)

print #f,")"



print #f, "if not exist ";chr$(34); "%~n0.exe";chr$(34);" ("

print #f, chr$(34); "%jsc%";chr$(34);" /nologo /out:";chr$(34);"%~n0.exe";chr$(34); " ";chr$(34);"%~dpsfnx0";chr$(34)

print #f, ")"



print #f, "if exist ";chr$(34);"%~n0.exe";chr$(34);" ( "

print #f, " ";chr$(34);"%~n0.exe";chr$(34);" %* "

print #f, ")"





print #f, "endlocal & exit /b %errorlevel%"



print #f, "end of jscript comment*/"



print #f, "import System;"

print #f, "import System.Windows;"

print #f, "import System.Windows.Forms;"

print #f, "import System.Drawing;"

print #f, "import System.Drawing.SystemIcons;"



print #f, "var notification;"

print #f, "try {"

print #f, " notification = new System.Windows.Forms.NotifyIcon();"





print #f, "} catch (Application){"



print #f, "}"



print #f,"notification.Icon = System.Drawing.SystemIcons.Information; // Could be Application,Asterisk,Error,Exclamation,Hand,Information,Question,Shield,Warning,WinLogo"

print #f, "notification.BalloonTipText = ";chr$(34);toastmsg$;chr$(34)

print #f, "notification.Visible = true;"

print #f, "// optional - BalloonTipIcon = System.Windows.Forms.ToolTipIcon.Info;"

print #f, "// optional - BalloonTipTitle = ";chr$(34);toastmsg$;chr$(34);









print #f, "// Display for 2 seconds."

print #f, "notification.ShowBalloonTip(5000);"

print #f, "System.Threading.Thread.Sleep(5100);"



print #f, "notification.Dispose();"





close #f







run "test.bat /c", HIDE



end

[Chris Iverson]

Here's some sample code to do a similar thing using the Windows API. It's not the cleanest interface, but it should demonstrate the possibility.

   gosub [NotifyIconConstants]

   'We need a window handle to work with the notify icon,
   'but we don't need it visible right now.
   stylebits #test, 0, _WS_VISIBLE, 0, 0
   open "test" for window as #test

   hWnd = hwnd(#test)

   'Assign our window handle
   NotifyIconData.hWnd.struct = hWnd

   'NIF.INFO means we intend to display a notification.
   NotifyIconData.uFlags.struct = NIF.INFO

   'NIIF.INFO gives us an Information icon in the notification.
   '
   'Others available include NIIF.WARNING(exclamation mark), NIIF.ERROR(red 'x'),
   'NIIF.USER(for a custom icon, not demonstrated), or NIIF.NONE for no icon in the
   'message.
   NotifyIconData.dwInfoFlags.struct = NIIF.INFO

   'Specify the message and the title of the notification.
   NotifyIconData.szInfo.struct = "This is a message"
   NotifyIconData.szInfoTitle.struct = "Title"

   'Our notify icon doesn't exist yet, so we create it.
   'Since we don't specify an icon, it'll be blank, but we still need one to send notifications from
   '
   'By not specifying a uID, we use the default uID of zero.
   'If you have multiple notify icons to show, or need to show separate notifications at the same time,
   'you can give them different uIDs when creating them.
   '
   'Just change the NotifyIconData.uID.struct member.
   '
   'By using the NIF.INFO flag, we can have it pop up a notification at the same time we add the icon.
   a = ShellNotifyIcon(NIM.ADD)

   print "Waiting seven seconds, then sending another notification"
   print

   timer 7000, [continue]
   wait

[continue]
   timer 0


   NotifyIconData.szInfo.struct = "Message 2"
   NotifyIconData.szInfoTitle.struct = "Title 2"
   NotifyIconData.dwInfoFlags.struct = NIIF.WARNING

   'Once we have an existing notification icon, we can pop up a new notification from it by using the
   'MODIFY message instead of the ADD message.  (The ADD message will do nothing if you try to ADD an
   'icon ID that already exists.)
   a = ShellNotifyIcon(NIM.MODIFY)


   input "Press enter to remove the notifications and end the program.";a

   'You must call NIM.DELETE to delete your notify icons once you're done with them.
   '
   'For each one you created, call this function again with the same uID specified in the
   'NotifyIconData struct.
   '
   'Note that, for Windows 10, if there are still notifications for this icon stored in the
   'action center, they will be automatically removed by removing the associated icon.
   a = ShellNotifyIcon(NIM.DELETE)

   close #test
   end

Function ShellNotifyIcon(message)
   CallDLL #shell32, "Shell_NotifyIconA",_
   message as long,_
   NotifyIconData as struct,_
   ShellNotifyIcon as long
End Function

[NotifyIconConstants]
   'Notify Icon Message(NIM)
   global NIM.ADD : NIM.ADD = 0
   global NIM.MODIFY : NIM.MODIFY = 1
   global NIM.DELETE : NIM.DELETE = 2
   global NIM.SETFOCUS : NIM.SETFOCUS = 3
   global NIM.SETVERSION : NIM.SETVERSION = 4

   'Notify Icon Flags(NIF)
   global NIF.MESSAGE : NIF.MESSAGE = 1
   global NIF.ICON : NIF.ICON = 2
   global NIF.TIP : NIF.TIP = 4
   global NIF.STATE : NIF.STATE = 8
   global NIF.INFO : NIF.INFO = hexdec("10")
   global NIF.GUID : NIF.GUID = hexdec("20")
   global NIF.REALTIME : NIF.REALTIME = hexdec("40")
   global NIF.SHOWTIP : NIF.SHOWTIP = hexdec("80")

   'Noitfy Icon State(NIS)
   global NIS.HIDDEN : NIS.HIDDEN = 1
   global NIS.SHAREDICON : NIS.SHAREDICON = 2

   'Notify Icon Info Flags(NIIF)
   global NIIF.NONE : NIIF.NONE = 0
   global NIIF.INFO : NIIF.INFO = 1
   global NIIF.WARNING : NIIF.WARNING = 2
   global NIIF.ERROR : NIIF.ERROR = 3
   global NIIF.USER : NIIF.USER = 4
   global NIIF.NOSOUND : NIIF.NOSOUND = hexdec("10")
   global NIIF.LARGE.ICON : NIIF.LARGE.ICON = hexdec("20")
   global NIIF.RESPECT.QUIET.TIME : NIIF.RESPECT.QUIET.TIME = hexdec("80")


   struct NotifyIconData,_
       cbSize as long,_
       hWnd as ulong,_
       uID as long,_
       uFlags as long,_
       uCallbackMessage as long,_
       hIcon as ulong,_
       szTip as char[128],_
       dwState as long,_
       dwStateMask as long,_
       szInfo as char[256],_
       uVersion as long,_
       szInfoTitle as char[64],_
       dwInfoFlags as long,_
       guidItem as char[16],_
       hBalloonIcon as ulong

   NotifyIconData.cbSize.struct = len(NotifyIconData.struct)
   return

[muXed]

Well Chris, you put me to shame there!

Works much better and no need to rely on pesky batch files!