BareBones HTML | Liberty BASIC Community Forum

metro
Guru

ignorance is bliss ....I don't know just how much I don' t know.....

Posts: 667

BareBones HTML Sept 3, 2023 18:07:04 GMT -5

Quote

Post by metro on Sept 3, 2023 18:07:04 GMT -5

This may be of interest

'** Bare Bones HTML Editor
'** Alyce Watson, 2004
global s$
s$ = ""
global filename$

    nomainwin

    q$=chr$(34)'double quotation mark
        lf$ = chr$(13) + chr$(10)
    nowPath$=DefaultDir$    'current directory for file operations

    WindowWidth = 550:WindowHeight = 410

    menu #main, "&File","&New",[new],"&Open",[open],"&Save",[save],"Convert to &CGI", [cgi], _
       "Save cgi file", [cgi_save], | ,"&View",[view],"&Print",[print],|,"E&xit",[quit]
    menu #main, "Edit"
    menu #main, "&Help","&Instructions",[help],"&About",[about]

    button #main.new, "new", [new], UL, 0, 0, 24, 24
    button #main.font, "<fnt>", [font], UL, 24, 0, 30, 24
    button #main.para, "<p>", [para], UL, 54, 0, 24, 24
    button #main.br, "<br>", br, UL, 78, 0, 24, 24
    button #main.hr, "<hr>", [hr], UL, 102, 0, 24, 24
    button #main.table, "<tble>", [table], UL, 126, 0, 34, 24
    button #main.center, "<ctr>", [center],UL,160,0,30,24
    button #main.div, "<div>",[div],UL,190,0,30,24
    button #main.ul, "<ul>",[ul],UL,220,0,24,24
    button #main.ol, "<ol>",[ol],UL,244,0,24,24
    button #main.pre, "<pre>",[pre],UL,268,0,30,24
    button #main.img, "<img>",[img],UL,298,0,30,24
    button #main.href, "<a href>",[href],UL,328,0,44,24

    texteditor #main.te, 2, 25, 537, 338
    'hidden texteditor allows copy to clipboard so that
    'text can be pasted into visible texteditor at current location
    texteditor #main.h, -1000,0,600,300

    open "Bare Bones HTML Editor" for window as #main

    'trap the event of user closing window with X button
    #main "trapclose [quit]"
    'set font for all controls on window
    #main "font ms_sans_serif 8"
    'cause texteditor to resize when window size changes
    #main.te "!autoresize"
    'issue separate font command for texteditor
    'courier_new is a monospaced font
    #main.te "!font courier_new 10"

[new]
    #main.te "!modified? ans$"
    if ans$="true" then
        confirm "Would you like to save the current file?";answer$
        if answer$="yes" then
            filedialog "Save As",nowPath$+"*.html",file$
            if file$="" then wait
            #main.te "!contents? t$"
            open file$ for output as #f
                    print #f, t$
            close #f
            'separate the path from the newly opened filename
            'so it can be used elsewhere
            nowPath$=SeparatePath$(file$)
        end if
    end if

    #main.te "!cls"
    #main.te "<html>"
    #main.te "<head>"
    #main.te "<title>Title of Page</title>"
    #main.te "</head>"
    #main.te "<body>"
    #main.te "<center><h2>Headline Goes Here</h2></center>"
    #main.te ""
    #main.te ""
    #main.te ""
    #main.te "</body></html>"
    #main.te "!setfocus"
    wait

[quit] close #main:end

[open]
    'add a path to the extension to cause the filedialog
    'to begin in the designated path
    filedialog "Open",nowPath$+"*.htm;*.html",file$
    if file$="" then wait
    open file$ for input as #f
    #main.te "!contents #f"
    close #f
    'separate the path from the newly opened filename
    'so it can be used elsewhere
    nowPath$=SeparatePath$(file$)
    #main.te "!setfocus"
    wait
[cgi]
#main.te "!contents? s$"
open "temp.txt" for output as #temp
print #temp, s$
close #temp
s$ = " html$ = " + q$ + "Content-type:text/html" + q$  + _
" + chr$(13)+chr$(10)+chr$(13)+chr$(10) " + chr$(13)+chr$(10)
open "temp.txt" for input as #temp
[loop]
  if eof(#temp) <> 0 then [finish_read]
  line input #temp, item$
t$ = ""
for x = 1 to len(item$)
    if mid$(item$,x,1) = chr$(34) then
      t$ = t$ + chr$(34) + " + chr$(34) + " + chr$(34)
        else
        t$ = t$ + mid$(item$,x,1)
  end if
  next x
s$ = s$ + " html$ = html$ + " + q$ + t$ + q$ + lf$
  goto [loop]
[finish_read]
  close #temp
  WindowWidth=400
  WindowHeight = 400
texteditor #cgibox.texted, 10, 10, 370, 350
open "cgi text" for dialog_modal as #cgibox
print #cgibox, "trapclose [cgiclose]"
print #cgibox.texted, "!contents s$"
wait
[cgiclose]
close #cgibox
    #main.te "!setfocus"
    wait

[cgi_save]

filedialog "Save As",nowPath$+"\*.cgilb",file$
    if file$="" then wait

open file$ for output as #f
print #f, s$
close #f
    'separate the path from the newly opened filename
    'so it can be used elsewhere
    'nowPath$=SeparatePath$(file$)
notice "File saved as ";file$

wait


[save]
    'add a path to the extension to cause the filedialog
    'to begin in the designated path
    filedialog "Save As",nowPath$+"*.html",file$
    if file$="" then wait
    #main.te "!contents? t$"
    open file$ for output as #f
        print #f, t$
    close #f
    'separate the path from the newly opened filename
    'so it can be used elsewhere
    nowPath$=SeparatePath$(file$)
    notice "File saved as ";file$
    #main.te "!setfocus"
    wait

[view]
    #main.te "!contents? t$"    'get contents of texteditor into string variable
    open nowPath$+"temp.html" for output as #f
        print #f, t$    'write to disk in temp file for viewing
    close #f
    'open user's default browser
    run "explorer "+q$+nowPath$+"temp.html"+q$,RESTORE
    wait

[print]
    #main.te "!contents? t$"    'get contents of texteditor into string variable
    lprint t$                   'send to printer
    dump                        'cause printing to start now
    wait

[help]
    m$="You may open an existing HTML file, or begin a new one. "
    m$=m$+"Click the corresponding button to insert an HTML tag at the current caret location in the text. "
    m$=m$+"You can save or print the file by selecting those options from the File Menu. "
    m$=m$+"You can even preview a file in your default browser by selecting View from the File Menu. "
    m$=m$+"There are many online references for HTML scripting. "
    m$=m$+"This program does not attempt to document HTML tags. "
    notice m$
    #main.te "!setfocus"
    wait

[about]
    notice "Bare Bones HTML Editor "+chr$(169)+"2004, Alyce Watson"
    #main.te "!setfocus"
    wait

[font]
    #main.h "<font size=3 face=verdana color=black>"
    #main.h "</font>"
    call PasteIt
    wait

[para]
    #main.h "<p>"
     #main.h "</p>"
    call PasteIt
    wait

[hr]
    #main.h "<hr>"
    call PasteIt
    wait

[table]
    #main.h "<center>"
    #main.h "<table border=2 cellspacing=2 cellpadding=2 bgcolor=#00ffff width=80%>"
    #main.h "<th colspan=2>Table Header</th>"
    #main.h "<tr>"
    #main.h "<td align=center>First Row, First Column</td>"
    #main.h "<td align=center>First Row, Second Column</td>"
    #main.h "</tr>"
    #main.h "<tr>"
    #main.h "<td align=center>Second Row, First Column</td>"
    #main.h "<td align=center>Second Row, Second Column</td>"
    #main.h "</tr>"
    #main.h "</table>"
    #main.h "</center>"
    call PasteIt
    wait

[center]
    #main.h "<center>"
    #main.h "</center>"
    call PasteIt
    wait

[div]
    #main.h "<div>"
    #main.h "</div>"
    call PasteIt
    wait

[ul]
    #main.h "<ul>Unordered List Title"
    #main.h "<li>List Item"
    #main.h "<li>List Item"
    #main.h "<li>List Item"
    #main.h "</ul>"
    call PasteIt
    wait

[ol]
    #main.h "<ol>Ordered List Title"
    #main.h "<li>List Item"
    #main.h "<li>List Item"
    #main.h "<li>List Item"
    #main.h "</ol>"
    call PasteIt
    wait

[pre]
    #main.h "<pre>"
    #main.h "Preformatted text goes here."
    #main.h "</pre>"
    call PasteIt
    wait

[img]
    #main.h "<img src="+q$+"imagename.jpg"+q$+">"
    call PasteIt
    wait

[href]
    #main.h "<a href="+q$+"url.html"+q$+">URL Name Here</a>"
    call PasteIt
    wait

'This sub copies text from hidden texteditor and puts it on clipboard,
'then pastes it to visible texteditor at current cursor position
Sub PasteIt
    #main.h "!selectall"
    #main.h "!copy"
    #main.te "!paste"
    #main.h "!cls"
    #main.te "!setfocus"
    end sub

Function SeparatePath$(f$)
    fileindex=Len(f$)
    filelength=Len(f$)
      While Mid$(f$, fileindex,1)<>"\"
        fileindex=fileindex-1
      Wend
    SeparatePath$=Left$(f$,fileindex)
    End Function

Don't assume that because I have an answer that I have an understanding. I do not possess the skills to recognize my own incompetence. www.verywellmind.com/an-overview-of-the-dunning-kruger-effect-4160740

metro
Guru

ignorance is bliss ....I don't know just how much I don' t know.....

Posts: 667

BareBones HTML Sept 3, 2023 18:10:11 GMT -5

Quote

Post by metro on Sept 3, 2023 18:10:11 GMT -5

Or this: Perhaps Mark could supply the dll, I cant find it.

    'LB Save as HTML
    'Date: 6.22.2022
    'Coded By: Mark A. Dunham

    nomainwin
    BackgroundColor$ = "darkgray"
    ForegroundColor$ = "black"
    print DefaultDir$

    'VARIABLES
    header$ = "LB HTML"
    column1$ = "Column 1"
    column2$ = "Column 2"
    column3$ = "Column 3"
    row1$ = "Row 1"
    row2$ = "Row 2"
    row3$ = "Row 3"
    fullName$ = "Peter Pan"
    age$ = "27"
    size$ = "Average"
    height$ = "6'-1" + chr$(34)
    weight$ = "260 lbs."
    hairColor$ = "Brown"
    language$ = "English"

[Main.Menu]
    WindowWidth = 640
    WindowHeight = 360
    UpperLeftX = int((DisplayWidth - WindowWidth)/2)
    UpperLeftY = int((DisplayHeight - WindowHeight)/2)

    Stylebits #Main, _WS_CAPTION, 0, 0, 0

    button #Main.btnSaveHTML, "Save HTML",[SaveHTML],UL,20,250,120,50

    graphicbox #Main.gbx1, -1,-1, 640, 360

    open "LB Save HTML" for graphics_nsb_nf as #Main
    #Main, "trapclose [Main.Quit]"
    #Main, "font Viner_Hand_ITC 0 0 bold"

    #Main.gbx1, "font Algerian 40 bold"
    #Main.gbx1, "down; color 0 0 0"
    #Main.gbx1, "Place 15 50"
    #Main.gbx1, "\LB Save HTML"

    #Main.gbx1, "font Algerian 14 bold"
    #Main.gbx1, "Place 15 100"
    #Main.gbx1, "\Name: "; fullName$
    #Main.gbx1, "Place 15 120"
    #Main.gbx1, "\Age: "; age$
    #Main.gbx1, "Place 15 140"
    #Main.gbx1, "\Size: "; size$
    #Main.gbx1, "Place 15 160"
    #Main.gbx1, "\Height: "; height$
    #Main.gbx1, "Place 15 180"
    #Main.gbx1, "\Weight: "; weight$
    #Main.gbx1, "Place 15 200"
    #Main.gbx1, "\Hair Color: "; hairColor$
    #Main.gbx1, "Place 15 220"
    #Main.gbx1, "\Language: "; language$

    wait

[Main.Quit]
    close #Main
    wait
    end

[SaveHTML]
    DefaultDir$ = DefaultDir$ + "\Saves\"

    filedialog "Save Character Sheet", "*.html", fileName$

    'IF THE FILE EXTENSION IS MISSING ADD IT TO THE FILENAME
    if right$(fileName$,5) <> ".html" then
        fileName$ = fileName$ + ".html"
    end if

    open fileName$ for output as #Save

    #Save, "<!DOCTYPE html>"
    #Save, "<html lang="; chr$(34);"en-US";chr$(34); ">"
    #Save, chr$(9);"<head>"
    #Save, chr$(9);chr$(9); "<meta charset="; chr$(34);"utf-8"; chr$(34); ">"
    #Save, chr$(9);chr$(9); "<link type="; chr$(34); "text/css"; chr$(34); "rel="; chr$(34); "stylesheet"; chr$(34); chr$(34); "media="; chr$(34); "all"; chr$(34); "href="; chr$(34); "Save_Style.css"; chr$(34); "/>"
    #Save, chr$(9);chr$(9); "<title>LB Save as HTML</title>"
    #Save, chr$(9); "</head>"
    #Save, ""

    #Save, "<body style="; chr$(34); "background-image: url('Parchment_LARGE.jpg')"; chr$(59);chr$(34); ">"
    #Save, "<div class="; chr$(34); "main"; chr$(34); ">"
    #Save, "<h1 align="; chr$(34);"center"; chr$(34); ">LB Save as HTML</h1>"

    #Save, "<table style="; chr$(34); "width:100%"; chr$(34);  "id="; chr$(34); "t01"; chr$(34); ">"
    #Save, "<tr>"
    #Save, "<td colspan="; chr$(34); "3"; chr$(34); "id="; chr$(34); "t02"; chr$(34);"><b>Column Span</b></td>"
    #Save, "</tr>"

    #Save, "<tr>"
    #Save, "<td id="; chr$(34); "t02"; chr$(34);"><u><b>"; column1$; "</b></u></td>"
    #Save, "<td id="; chr$(34); "t02"; chr$(34); "><u><b>"; column2$; "</b></u></td>"
    #Save, "<td colspan="; chr$(34); "1"; chr$(34); "id="; chr$(34); "t02"; chr$(34); "><u><b>"; column3$; "</b></u></td>"
    #Save, "</tr>"

    #Save, "<tr>"
    #Save, "<td><u><b>Name:</b></b></u> "; fullName$; "</td>"
    #Save, "<td><u><b>Age:</b></u> "; age$; "</td>"
    #Save, "<td><u><b>Size:</b></u> "; size$; "</td>"
    #Save, "</tr>"

    #Save, "<tr>"
    #Save, "<td><u><b>Height:</b></u> "; height$; "</td>"
    #Save, "<td><u><b>Weight:</b></u> "; weight$; "</td>"
    #Save, "<td><u><b>Hair Color:</b></u> "; hairColor$; "</td>"
    #Save, "</tr>"

    #Save, "<tr>"
    #Save, "<td><u><b>Language:</b></u> "; language$;"</td>"
    #Save, "<td></td>"
    #Save, "<td></td>"
    #Save, "</tr>"

    #Save, "<tr>"
    #Save, "<td colspan="; chr$(34); "3"; chr$(34);"><u><b>"; row1$; "</b></u></td>"
    #Save, "</tr>"

    #Save, "<tr>"
    #Save, "<td colspan="; chr$(34); "3"; chr$(34);"><u><b>"; row2$; "</b></u></td>"
    #Save, "</tr>"

    #Save, "<tr>"
    #Save, "<td colspan="; chr$(34); "3"; chr$(34);"><u><b>"; row3$; "</b></u></td>"
    #Save, "</tr>"

    #Save, "</table>"

    #Save, chr$(9);chr$(9); "</div>"

    #Save, chr$(9); "</body>"
    #Save, "</html>"

    close #Save

    run "rundll32.exe url.dll,FileProtocolHandler ";fileName$

    wait

Last Edit: Sept 3, 2023 18:13:45 GMT -5 by metro

Don't assume that because I have an answer that I have an understanding. I do not possess the skills to recognize my own incompetence. www.verywellmind.com/an-overview-of-the-dunning-kruger-effect-4160740

metro
Guru

ignorance is bliss ....I don't know just how much I don' t know.....

Posts: 667

BareBones HTML Sept 3, 2023 19:03:42 GMT -5

Quote

Post by metro on Sept 3, 2023 19:03:42 GMT -5

'PageFoundry uses the power of the <DIV> tag in HTML 4.0
'cascading style sheets to allow the user to visually
'create a web page, no HTML knowledge required!

Just had a quick look at this, I have an issue with dll's (could be linux<wine>)

pagefoundry3.zip (543.72 KB)

dll's are in resource folder

Last Edit: Sept 3, 2023 19:09:43 GMT -5 by metro

Don't assume that because I have an answer that I have an understanding. I do not possess the skills to recognize my own incompetence. www.verywellmind.com/an-overview-of-the-dunning-kruger-effect-4160740

xxgeek
Senior Member

Posts: 325

BareBones HTML Sept 4, 2023 15:12:12 GMT -5

Quote

Post by xxgeek on Sept 4, 2023 15:12:12 GMT -5

Thanks for posting these metro.

btw- url.dll is an MS dll in c:\windows\system32 so no problems there.

In Linux\WINE it may not be there by default, but possibly using winetricks: Add a component or dll

I have copied some files to the system32 folder in WINE a few times to get things working as well. IEXPRESS.exe cab.exe, and webstract.exe were needed in one of my apps.

Code-Share - for updates.

metro
Guru

ignorance is bliss ....I don't know just how much I don' t know.....

Posts: 667

BareBones HTML Sept 19, 2023 6:50:01 GMT -5 Tasp likes this

Quote

Post by metro on Sept 19, 2023 6:50:01 GMT -5

I know LB does not have direct access to HTML.
However one way is to create a html file and place images in a <table> and create a html output file.
In this example you can place images in a <table> and tell it to fill each cell by 100%. It will always fill the table even if you streatch and shrink it.
They can be any format.

This maybe useful to display simple HTML

No real functionality but useful to display reports or html tables etc

drop an image into your DefaultDir and rename the file chart.png to your file name in the STORE.HTML SUB

An added bonus, if your right click on the displayed HTML page the Context menu should give you the option to print the page for an easy PDF



DefaultDir$ = DefaultDir$;"\"
FileName$ = "a.html"

OPEN "atl" FOR DLL AS #atl
CallDLL #atl, "AtlAxWinInit", Ret AS long

CALL STORE.HTML DefaultDir$, FileName$

nomainwin
[setupGUIWdo]
    WindowWidth  = 955
    WindowHeight = 500
    UpperLeftX   = (DisplayWidth - WindowWidth)/2
    UpperLeftY   = 100

button  #s.content "DISPLAY HTML", [displaypics], UL, 35, 1, 154, 30
graphicbox #s.resource 35, 35, 900, 370    'container for browser control

     open WdoTitle$ for dialog_nf as #s
hMain = hwnd(#s)
   #s "trapclose [quit]"
  WAIT

[quit]
    close #s
    close #atl
end
[displaypics]
CALL createBrowseControl DefaultDir$, FileName$, hFlag
WAIT


SUB createBrowseControl D$, F$, byref hATL

    if hATL then
        CallDLL #user32, "DestroyWindow", _
            hATL   As ulong, _
            result As long
            hATL   = 0
    end if

    hWndContainer = hWnd(#s.resource)   'graphicbox handle

    callDLL #user32, "GetWindowLongA", _
        hWndContainer  as ulong, _
        _GWL_HINSTANCE as long, _
                 hInst as ulong

 ResName$ = D$ + F$                  'file to display

    style = _WS_CHILD or _WS_VISIBLE or _WS_VSCROLL

    CallDLL #user32, "CreateWindowExA", _
    _WS_EX_STATICEDGE As long, _        'extended type
           "AtlAxWin" As ptr, _         'class name
             ResName$ As ptr, _         'resource file name & path
                style As long, _        'window style
                    1 As long, _        'left x pos
                    1 As long, _        'top y pos
                  925 As long, _        'width
                  400 As long, _        'height
        hWndContainer As ulong, _       'handle of container
                  100 As long, _        'handle to menu or child window ID
                hInst As ulong, _       'parent instance handle
                    0 As long, _        'window creation data
                 hATL As ulong          'handle of active template library control

END SUB

SUB STORE.HTML Path$, File$
' name & store the inage in DefaultDir$
open Path$;File$ for output as #f
print #f, "<!DOCTYPE html>"
print #f, "<HTML><HEAD>"
print #f, "<TITLE>image float</TITLE>"
print #f, "</HEAD>"
print #f, "<BODY>"
print #f, "<TABLE BORDER=1 CELLPADDING=0 CELLSPACING=0 WIDTH=100%><TR>"
print #f, "<TD WIDTH=33%></TD><TD WIDTH=33%></TD><TD WIDTH=33%></TD></TR>"
print #f, "<TR align=bottom>"
print #f, "<TD><IMG SRC=chart.png WIDTH=100% ></TD>"
print #f, "<TD><IMG SRC=chart.png WIDTH=100% ></TD>"
print #f, "<TD><IMG SRC=chart.png WIDTH=100% ></TD>"
print #f, "</TR>"
print #f, "</TABLE>"
print #f, "</BODY>"
print #f, "</HTML>"
print #f, "<style>"
print #f, "table { "
print #f, "  font-family: arial, sans-serif;"
print #f, "  border-collapse: collapse;"
print #f, "  width: 100%;"
print #f, "}"
print #f, "td, th {"
print #f, "  border: 1px solid #dddddd;"
print #f, "  text-align: left;"
print #f, "  padding: 8px;"
print #f, "}"
print #f, "tr:nth-child(even) {"
print #f, "  background-color: #dddddd;"
print #f, "}"
print #f, "</style>"
print #f, "<h2>HTML Table</h2>"
print #f, "<table>"
print #f, "  <tr>"
print #f, "    <th>Company</th>"
print #f, "    <th>Contact</th>"
print #f, "    <th>Country</th>"
print #f, "  </tr>"
print #f, "  <tr>"
print #f, "    <td>Alfreds Futterkiste</td>"
print #f, "    <td>Maria Anders</td>"
print #f, "    <td>Germany</td>"
print #f, "  </tr>"
print #f, "  <tr>"
print #f, "    <td>Centro comercial Moctezuma</td>"
print #f, "    <td>Francisco Chang</td>"
print #f, "    <td>Mexico</td>"
print #f, "  </tr>"
print #f, "  <tr>"
print #f, "    <td>Ernst Handel</td>"
print #f, "    <td>Roland Mendel</td>"
print #f, "    <td>Austria</td>"
print #f, "  </tr>"
print #f, "  <tr>"
print #f, "    <td>Island Trading</td>"
print #f, "    <td>Helen Bennett</td>"
print #f, "    <td>UK</td>"
print #f, "  </tr>"
print #f, "  <tr>"
print #f, "    <td>Laughing Bacchus Winecellars</td>"
print #f, "    <td>Yoshi Tannamuri</td>"
print #f, "    <td>Canada</td>"
print #f, "  </tr>"
print #f, "  <tr>"
print #f, "    <td>Magazzini Alimentari Riuniti</td>"
print #f, "    <td>Giovanni Rovelli</td>"
print #f, "    <td>Italy</td>"
print #f, "  </tr>"
print #f, "</table>"
close #f
END SUB

Last Edit: Sept 19, 2023 19:02:48 GMT -5 by metro

Don't assume that because I have an answer that I have an understanding. I do not possess the skills to recognize my own incompetence. www.verywellmind.com/an-overview-of-the-dunning-kruger-effect-4160740