Pandemic simulator

[David Drake]

Just as an interesting exercise, I created the code below to simulate the effects of different factors on the spread of an infectious disease.  This isn't scientific and it wasn't designed by an epidemiologist, but it is interesting to observe what happens as you vary population density, how contagious it is, fraction of the population that stays put, the length of time someone can spread the disease, and so forth.  I think it helps emphasize the value of not moving around. 

It isn't pretty or efficient, but it works.  Enjoy!



population=100 'population
seeds=5 'number of starting sick
wellCount=population-seeds
transferRate=0.50'probability of contracting on contact
recoCount=0'number of sims that were sick but recovered
fractionStationary=0.75
daysInfectious=21

prompt "Population: ";population
prompt "Seeds: ";seeds
prompt "Stationary fraction: ";fractionStationary
prompt "Transfer on contact fraction: ";transferRate
prompt "Days infectious: ";daysInfectious

sickCount=seeds

'nomainwin
UpperLeftX=1
UpperLeftY=1
WindowWidth=800
WindowHeight=600
graphicbox #1.g, 1, 1, 500, 500
graphicbox #1.t1, 1, 501, 800, 100
graphicbox #1.t2, 501, 1, 300, 500
open "Sim" for graphics_nf_nsb as #1
#1.g "fill white;flush"
#1.t1 "fill darkblue;flush"
#1.t2 "fill black;flush"
#1 "trapclose [q]"

dim sim(500,10)'500 sims, 10 parameters each
'1=x location
'2=y location
'3=x velocity
'4=y velocity
'5=wellness parameter (0=well, 1=sick, 2=recovered)
'6=time since initial infection

'set initial paramaters
'random location
for a =1 to population
   sim(a,1)=int(rnd(1)*450)+20
   sim(a,2)=int(rnd(1)*450)+20
   sim(a,3)=(0.5-rnd(rnd(1)))*5
   if sim(a,3)<1 and sim(a,3)>-1 then
       if sim(a,3)<1 then sim(a,3)=sim(a,3)-2
       if sim(a,3)>1 then sim(a,3)=sim(a,3)+2
   end if
   sim(a,4)=(0.5-rnd(rnd(1)))*5
   if sim(a,4)<1 and sim(a,4)>-1 then
       if sim(a,4)<1 then sim(a,4)=sim(a,4)-2
       if sim(a,4)>1 then sim(a,4)=sim(a,4)+2
   end if
   if a/population<fractionStationary then sim(a,3)=0:sim(a,4)=0
next a

'make sprites
#1.t2 "down;place 1 1;color white;backcolor white;boxfilled 10 10;place 5 5;backcolor black;color black;circlefilled 5;place 5 15;color green;backcolor green;circlefilled 5"
#1.t2 "getbmp well 1 1 8 20"
#1.t2 "color red;backcolor red;circlefilled 4"
#1.t2 "getbmp sick 1 1 8 20"
#1.t2 "color blue;backcolor blue;circlefilled 4"
#1.t2 "getbmp reco 1 1 8 20"
#1.g "getbmp bg 1 1 500 500"
#1.g "background bg"
#1.g "drawbmp well 10 10;drawbmp sick 40 40;drawbmp reco 80 80"

for a = 1 to population
   #1.g "addsprite sim";a;" well sick reco"
   #1.g "spritexy sim";a;" ";sim(a,1);" ";sim(a,2)
   #1.g "spritemovexy sim";a;" ";sim(a,3);" ";sim(a,4)
next a

for a = 1 to seeds ' seed sick people with random times since infaction
   sim(a,5)=1
   sim(a,6)=rnd(1)*14*24
    #1.g "spriteimage sim";a;" sick"
next a

#1.g "drawsprites"

timer 25, [animate]
wait

[animate]
   scan
   if sickCount<=0 then
       waitCount=waitCount+1
       if waitCount>50 then
           timer 0
           goto [endSim]
       end if
   end if
   hours=hours+1
   #1.g "drawsprites"
   for a = 1 to population
       if sim(a,6)>0 then 'decrement time sick
           sim(a,6)=sim(a,6)-1
           if sim(a,6)<=0 then
               sim(a,5)=2 'move to reco
               #1.g "spriteimage sim";a;" reco"
               recoCount=recoCount+1
               sickCount=sickCount-1
           end if
       end if

       #1.g "spritecollides sim";a;" col$"
       #1.g "spritexy? sim";a;" x y"
       if col$<>"" then
           if rnd(1)<0.5 then sim(a,3)=sim(a,3)*(-1) 'change direction
           if rnd(1)<0.5 then sim(a,4)=sim(a,4)*(-1) 'change direction
           col=val(left$(after$(col$,"sim"),2)) 'get the colliding sim
           if sim(a,5)=1 and sim(col,5)=0 and rnd(1)<transferRate then  'move from well to sick
               sim(col,5)=1:sim(col,6)=daysInfectious*24
               #1.g "spriteimage sim";col;" sick"
               wellCount=wellCount-1
               sickCount=sickCount+1
           else
               if sim(a,5)=0 and sim(col,5)=1  and rnd(1)<transferRate then
                   sim(a,5)=1:sim(a,6)=daysInfectious*24 'move from well to sick
                   #1.g "spriteimage sim";a;" sick"
                   wellCount=wellCount-1
                   sickCount=sickCount+1
               end if
           end if
       end if

       if x>=480 or x<=10 then sim(a,3)=sim(a,3)*(-1) 'change direction at perimeter
       if y>=480 or y<=10 then sim(a,4)=sim(a,4)*(-1) 'change direction at perimeter

       #1.g "spritemovexy sim";a;" ";sim(a,3);" ";sim(a,4)
   next a

   if sickCount>maxSickCount then maxSickCount=sickCount
   #1.t1, "place 10 40;\Time: ";hours;"  Well: ";wellCount;"  Sick: ";sickCount;"  Reco: ";recoCount;"        "
   #1.t2 "discard;cls"
   #1.t2, "place 10 100;backcolor white;color black;boxfilled 40 0"
   #1.t2, "place 40 100;backcolor white;color black;boxfilled 70 0"
   #1.t2, "place 70 100;backcolor white;color black;boxfilled 100 0"
   #1.t2, "place 40 100;backcolor pink;color black;boxfilled 70 ";100-(100*maxSickCount/population)
   #1.t2, "place 10 100;backcolor green;color black;boxfilled 40 ";100-(100*wellCount/population)
   #1.t2, "place 40 100;backcolor red;color black;boxfilled 70 ";100-(100*sickCount/population)
   #1.t2, "place 70 100;backcolor blue;color black;boxfilled 100 ";100-(100*recoCount/population)
   wait

[endSim]
   timer 0
   print "Simulation complete"
   print "Population: ";population
   print "Seed sick:  ";seeds
   print "Stationary: ";fractionStationary
   print "Tran rate:  ";transferRate
   print "Days infec: ";daysInfectious
   print
   print "Hrs of end: ";hours
   print "% infected: ";int(recoCount/population*100);"%"
   print "Max % sick: ";int(maxSickCount/population*100);"%"
   print "------------------------"
   wait

[q]
timer 0
unloadbmp "well"
unloadbmp "sick"
unloadbmp "reco"
#1.g "cls;discard"
#1.t1 "cls;discard"
#1.t2 "cls;discard"
close #1
end


[tsh73]

I've got negative number of well persons.
Not the thing you usually encounter

[sarossell]

Nice, clever design.

[sarossell]

Mar 17, 2020 14:26:55 GMT -5 tsh73 said:

I've got negative number of well persons.
Not the thing you usually encounter

"Negative well"...Ordinarily, that would indicate "dead"(?)

[tsh73]

Rather counting error I think
I set patients to 300 and now I see -197 well while 3 green and 4 blue

[tsh73]

Rather counting error I think

Indeed. Problem is that first,
population=100 'population
seeds=5 'number of starting sick

Then wellCount is calculated as
wellCount=population-seeds
Then there is a prompt
prompt "Population: ";population
prompt "Seeds: ";seeds

and I enter 200
BUT wellCount is already set and does not change!
So it goes negative after 100 infected.

So fix is to move
wellCount=population-seeds
after PROMPT block.

[David Drake]

Yeah, guess it was a little half-baked. Thanks for finding my errors. Still interesting, though.

[bluatigro]

see for my version the justB site
look for "virus outbreak sim try"

[tsh73]

Just run it another time. Called in kids, explained what's going on.
They get impressed
(older one asked "where dead ones?")

[Brandon Parker]

Corrected the wellCount issue and added a "Natural Immunity" factor to it since that sort of thing actually exists.

I also added a check to ensure the recovery section is not "actioned" for non-sick individuals.  That is in this section here ...
for a = 1 to population
       If sim(a,5)=1 Then
           if sim(a,6)>0 then 'decrement time sick

I might find some time to play with this some more ... hopefully anyway ...

population=100 'population
seeds=5 'number of starting sick
transferRate=0.50'probability of contracting on contact
recoCount=0'number of sims that were sick but recovered
fractionStationary=0.75
daysInfectious=21
immunePercentage = 2

prompt "Population: ";population
prompt "Seeds: ";seeds
prompt "Percentage with Natural Immunity: ";immunePercentage
prompt "Stationary fraction: ";fractionStationary
prompt "Transfer on contact fraction: ";transferRate
prompt "Days infectious: ";daysInfectious

sickCount=seeds
wellCount=population-seeds

'nomainwin
UpperLeftX=1
UpperLeftY=1
WindowWidth=800
WindowHeight=600
graphicbox #1.g, 1, 1, 500, 500
graphicbox #1.t1, 1, 501, 800, 100
graphicbox #1.t2, 501, 1, 300, 500
open "Sim" for graphics_nf_nsb as #1
#1.g "fill white;flush"
#1.t1 "fill darkblue;flush"
#1.t2 "fill black;flush"
#1 "trapclose [q]"

dim sim(500,10)'500 sims, 10 parameters each
'1=x location
'2=y location
'3=x velocity
'4=y velocity
'5=wellness parameter (0=well, 1=sick, 2=recovered)
'6=time since initial infection
'7 = Natural Immunity

'set initial paramaters
'random location
for a =1 to population
   sim(a,1)=int(rnd(1)*450)+20
   sim(a,2)=int(rnd(1)*450)+20
   sim(a,3)=(0.5-rnd(rnd(1)))*5
   if sim(a,3)<1 and sim(a,3)>-1 then
       if sim(a,3)<1 then sim(a,3)=sim(a,3)-2
       if sim(a,3)>1 then sim(a,3)=sim(a,3)+2
   end if
   sim(a,4)=(0.5-rnd(rnd(1)))*5
   if sim(a,4)<1 and sim(a,4)>-1 then
       if sim(a,4)<1 then sim(a,4)=sim(a,4)-2
       if sim(a,4)>1 then sim(a,4)=sim(a,4)+2
   end if
   if (a/population)<fractionStationary then sim(a,3)=0:sim(a,4)=0
next a

'make sprites
#1.t2 "down;place 1 1;color white;backcolor white;boxfilled 10 10;place 5 5;backcolor black;color black;circlefilled 5;place 5 15;color green;backcolor green;circlefilled 5"
#1.t2 "getbmp well 1 1 8 20"
#1.t2 "color red;backcolor red;circlefilled 4"
#1.t2 "getbmp sick 1 1 8 20"
#1.t2 "color blue;backcolor blue;circlefilled 4"
#1.t2 "getbmp reco 1 1 8 20"

#1.t2 "color Yellow;backcolor Yellow;circlefilled 4"
#1.t2 "getbmp immune 1 1 8 20"

#1.g "getbmp bg 1 1 500 500"
#1.g "background bg"
#1.g "drawbmp well 10 10;drawbmp sick 40 40;drawbmp reco 80 80;drawbmp immune 120 120"

for a = 1 to population
   #1.g "addsprite sim";a;" well sick reco immune"
   #1.g "spritexy sim";a;" ";sim(a,1);" ";sim(a,2)
   #1.g "spritemovexy sim";a;" ";sim(a,3);" ";sim(a,4)
next a

for a = 1 to seeds ' seed sick people with random times since infection
   sim(a,5)=1
   sim(a,6)=Int((rnd(1)*24*daysInfectious) + 0.5)   'rnd(1)*14*24
   #1.g "spriteimage sim";a;" sick"
next a

For i = 0 To ((population*immunePercentage/100) - 1)
   element = Int((rnd(1)*population) + 0.4)
   If (sim(element, 7) < 1) And (sim(element, 5) = 0) Then
       sim(element, 7) = 1
       #1.g "spriteimage sim";element;" immune"
       immunePersons = (immunePersons + 1)
   Else
       i = (i - 1)
   End If
Next i

#1.g "drawsprites"

timer 1, [animate]
wait

[animate]
   scan
   if sickCount<=0 then
       waitCount=waitCount+1
       if waitCount>50 then
           timer 0
           goto [endSim]
       end if
   end if
   hours=hours+1
   #1.g "drawsprites"
   for a = 1 to population
       If sim(a,5)=1 Then
           if sim(a,6)>0 then 'decrement time sick
               sim(a,6)=sim(a,6)-1
               if sim(a,6)<=0 then
                   sim(a,5)=2 'move to reco
                   #1.g "spriteimage sim";a;" reco"
                   recoCount=recoCount+1
                   sickCount=sickCount-1
               end if
           end if
       End If

       #1.g "spritecollides sim";a;" col$"
       #1.g "spritexy? sim";a;" x y"
       if col$<>"" then
           if rnd(1)<0.5 then sim(a,3)=sim(a,3)*(-1) 'change direction
           if rnd(1)<0.5 then sim(a,4)=sim(a,4)*(-1) 'change direction
           col=val(left$(after$(col$,"sim"),2)) 'get the colliding sim
           if sim(a,5)=1 and sim(col,5)=0 and rnd(1)<transferRate And Not(sim(col,7)) then  'move from well to sick
               sim(col,5)=1:sim(col,6)=daysInfectious*24
               #1.g "spriteimage sim";col;" sick"
               wellCount=wellCount-1
               sickCount=sickCount+1
           else
               if sim(a,5)=0 and sim(col,5)=1 and rnd(1)<transferRate And Not(sim(a,7)) then
                   sim(a,5)=1:sim(a,6)=daysInfectious*24 'move from well to sick
                   #1.g "spriteimage sim";a;" sick"
                   wellCount=wellCount-1
                   sickCount=sickCount+1
               end if
           end if
       end if

       if x>=480 or x<=10 then sim(a,3)=sim(a,3)*(-1) 'change direction at perimeter
       if y>=480 or y<=10 then sim(a,4)=sim(a,4)*(-1) 'change direction at perimeter

       #1.g "spritemovexy sim";a;" ";sim(a,3);" ";sim(a,4)
   next a

   if sickCount>maxSickCount then maxSickCount=sickCount
   #1.t1, "place 10 40;\Time: ";hours;"  Well: ";wellCount;"  Sick: ";sickCount;"  Reco: ";recoCount;"  Immune: ";immunePersons;"        "
   #1.t2 "discard;cls"
   #1.t2, "place 10 100;backcolor white;color black;boxfilled 40 0"
   #1.t2, "place 40 100;backcolor white;color black;boxfilled 70 0"
   #1.t2, "place 70 100;backcolor white;color black;boxfilled 100 0"
   #1.t2, "place 40 100;backcolor pink;color black;boxfilled 70 ";100-(100*maxSickCount/population)
   #1.t2, "place 10 100;backcolor green;color black;boxfilled 40 ";100-(100*wellCount/population)
   #1.t2, "place 40 100;backcolor red;color black;boxfilled 70 ";100-(100*sickCount/population)
   #1.t2, "place 70 100;backcolor blue;color black;boxfilled 100 ";100-(100*recoCount/population)
   wait

[endSim]
   timer 0
   print "Simulation complete"
   print "Population: ";population
   print "Seed sick:  ";seeds
   Print "Immune Persons:  ";immunePersons
   print "Stationary: ";fractionStationary
   print "Tran rate:  ";transferRate
   print "Days infec: ";daysInfectious
   print
   print "Hrs of end: ";hours
   print "% infected: ";int(recoCount/population*100);"%"
   print "Max % sick: ";int(maxSickCount/population*100);"%"
   print "------------------------"
   wait

[q]
timer 0
unloadbmp "well"
unloadbmp "sick"
unloadbmp "reco"
#1.g "cls;discard"
#1.t1 "cls;discard"
#1.t2 "cls;discard"
close #1
end


{:0)

Brandon Parker

[tsh73]

Get time to play with it
added graphs and moved final report to textbox from a main window


Am I the only one seeing occasionally simulated men juggling along outer edge (xmax, ymax)?
Can it be helped?

population=100 'population
seeds=5 'number of starting sick
transferRate=0.50'probability of contracting on contact
recoCount=0'number of sims that were sick but recovered
fractionStationary=0.75
daysInfectious=21
immunePercentage = 2

prompt "Population: ";population
prompt "Seeds: ";seeds
prompt "Percentage with Natural Immunity: ";immunePercentage
prompt "Stationary fraction: ";fractionStationary
prompt "Transfer on contact fraction: ";transferRate
prompt "Days infectious: ";daysInfectious

sickCount=seeds
wellCount=population-seeds

nomainwin
UpperLeftX=1
UpperLeftY=1
WindowWidth=800
WindowHeight=600
graphicbox #1.g, 1, 1, 500, 500
graphicbox #1.t1, 1, 501, 800, 100
graphicbox #1.t2, 501, 1, 300, 220
texteditor #1.txt, 501, 220, 300, 280
open "Sim" for graphics_nf_nsb as #1
#1.g "fill white;flush"
#1.t1 "fill darkblue;flush"
#1.t2 "fill black;flush"
#1 "trapclose [q]"

dim sim(500,10)'500 sims, 10 parameters each
'1=x location
'2=y location
'3=x velocity
'4=y velocity
'5=wellness parameter (0=well, 1=sick, 2=recovered)
'6=time since initial infection
'7 = Natural Immunity

'set initial paramaters
'random location
for a =1 to population
   sim(a,1)=int(rnd(1)*450)+20
   sim(a,2)=int(rnd(1)*450)+20
   sim(a,3)=(0.5-rnd(rnd(1)))*5
   if sim(a,3)<1 and sim(a,3)>-1 then
       if sim(a,3)<1 then sim(a,3)=sim(a,3)-2
       if sim(a,3)>1 then sim(a,3)=sim(a,3)+2
   end if
   sim(a,4)=(0.5-rnd(rnd(1)))*5
   if sim(a,4)<1 and sim(a,4)>-1 then
       if sim(a,4)<1 then sim(a,4)=sim(a,4)-2
       if sim(a,4)>1 then sim(a,4)=sim(a,4)+2
   end if
   if (a/population)<fractionStationary then sim(a,3)=0:sim(a,4)=0
next a

'make sprites
#1.t2 "down;place 1 1;color white;backcolor white;boxfilled 10 10;place 5 5;backcolor black;color black;circlefilled 5;place 5 15;color green;backcolor green;circlefilled 5"
#1.t2 "getbmp well 1 1 8 20"
#1.t2 "color red;backcolor red;circlefilled 4"
#1.t2 "getbmp sick 1 1 8 20"
#1.t2 "color blue;backcolor blue;circlefilled 4"
#1.t2 "getbmp reco 1 1 8 20"

#1.t2 "color Yellow;backcolor Yellow;circlefilled 4"
#1.t2 "getbmp immune 1 1 8 20"

#1.g "getbmp bg 1 1 500 500"
#1.g "background bg"
#1.g "drawbmp well 10 10;drawbmp sick 40 40;drawbmp reco 80 80;drawbmp immune 120 120"

for a = 1 to population
   #1.g "addsprite sim";a;" well sick reco immune"
   #1.g "spritexy sim";a;" ";sim(a,1);" ";sim(a,2)
   #1.g "spritemovexy sim";a;" ";sim(a,3);" ";sim(a,4)
next a

for a = 1 to seeds ' seed sick people with random times since infection
   sim(a,5)=1
   sim(a,6)=Int((rnd(1)*24*daysInfectious) + 0.5)   'rnd(1)*14*24
   #1.g "spriteimage sim";a;" sick"
next a

For i = 0 To ((population*immunePercentage/100) - 1)
   element = Int((rnd(1)*population) + 0.4)
   If (sim(element, 7) < 1) And (sim(element, 5) = 0) Then
       sim(element, 7) = 1
       #1.g "spriteimage sim";element;" immune"
       immunePersons = (immunePersons + 1)
   Else
       i = (i - 1)
   End If
Next i

#1.g "drawsprites"
#1.t2 "cls; fill white;flush"

timer 1, [animate]
wait

[animate]
   scan
   if sickCount<=0 then
       waitCount=waitCount+1
       if waitCount>50 then
           timer 0
           goto [endSim]
       end if
   end if
   hours=hours+1
   #1.g "drawsprites"
   for a = 1 to population
       If sim(a,5)=1 Then
           if sim(a,6)>0 then 'decrement time sick
               sim(a,6)=sim(a,6)-1
               if sim(a,6)<=0 then
                   sim(a,5)=2 'move to reco
                   #1.g "spriteimage sim";a;" reco"
                   recoCount=recoCount+1
                   sickCount=sickCount-1
               end if
           end if
       End If

       #1.g "spritecollides sim";a;" col$"
       #1.g "spritexy? sim";a;" x y"
       if col$<>"" then
           if rnd(1)<0.5 then sim(a,3)=sim(a,3)*(-1) 'change direction
           if rnd(1)<0.5 then sim(a,4)=sim(a,4)*(-1) 'change direction
           col=val(left$(after$(col$,"sim"),2)) 'get the colliding sim
           if sim(a,5)=1 and sim(col,5)=0 and rnd(1)<transferRate And Not(sim(col,7)) then  'move from well to sick
               sim(col,5)=1:sim(col,6)=daysInfectious*24
               #1.g "spriteimage sim";col;" sick"
               wellCount=wellCount-1
               sickCount=sickCount+1
           else
               if sim(a,5)=0 and sim(col,5)=1 and rnd(1)<transferRate And Not(sim(a,7)) then
                   sim(a,5)=1:sim(a,6)=daysInfectious*24 'move from well to sick
                   #1.g "spriteimage sim";a;" sick"
                   wellCount=wellCount-1
                   sickCount=sickCount+1
               end if
           end if
       end if

       if x>=480 or x<=10 then sim(a,3)=sim(a,3)*(-1) 'change direction at perimeter
       if y>=480 or y<=10 then sim(a,4)=sim(a,4)*(-1) 'change direction at perimeter

       #1.g "spritemovexy sim";a;" ";sim(a,3);" ";sim(a,4)
   next a

   if sickCount>maxSickCount then maxSickCount=sickCount
   #1.t1, "place 10 40;\Time: ";hours;"  Well: ";wellCount;"  Sick: ";sickCount;"  Reco: ";recoCount;"  Immune: ";immunePersons;"        "
   '#1.t2 "discard;cls"
   #1.t2, "place 10 100;backcolor white;color black;boxfilled 40 0"
   #1.t2, "place 40 100;backcolor white;color black;boxfilled 70 0"
   #1.t2, "place 70 100;backcolor white;color black;boxfilled 100 0"
   #1.t2, "place 40 100;backcolor pink;color black;boxfilled 70 ";100-(100*maxSickCount/population)
   #1.t2, "color pink; set ";10+hours/24;" ";200-(100*maxSickCount/population)

   #1.t2, "place 10 100;backcolor green;color black;boxfilled 40 ";100-(100*wellCount/population)
   #1.t2, "color green; set ";10+hours/24;" ";200-(100*wellCount/population)

   #1.t2, "place 40 100;backcolor red;color black;boxfilled 70 ";100-(100*sickCount/population)
   #1.t2, "color red; set ";10+hours/24;" ";200-(100*sickCount/population)

   #1.t2, "place 70 100;backcolor blue;color black;boxfilled 100 ";100-(100*recoCount/population)
   #1.t2, "color blue; set ";10+hours/24;" ";200-(100*recoCount/population)
   wait

[endSim]
   #1.t2, "flush"
   timer 0
   print #1.txt, "Simulation complete"
   print #1.txt, "Population: ";population
   print #1.txt, "Seed sick:  ";seeds
   Print #1.txt, "Immune Persons:  ";immunePersons
   print #1.txt, "Stationary: ";fractionStationary
   print #1.txt, "Tran rate:  ";transferRate
   print #1.txt, "Days infec: ";daysInfectious
   print #1.txt,""
   print #1.txt, "Hrs of end: ";hours
   print #1.txt, "% infected: ";int(recoCount/population*100);"%"
   print #1.txt, "Max % sick: ";int(maxSickCount/population*100);"%"
   'print "------------------------"
   wait

[q]
timer 0
unloadbmp "well"
unloadbmp "sick"
unloadbmp "reco"
#1.g "cls;discard"
#1.t1 "cls;discard"
#1.t2 "cls;discard"
close #1
end


[tenochtitlanuk]

Like!

I wonder if it would look more realistic with toroidal geometry, ie going of one edge you reappear on the opposite one? But then I feel bouncing off the walls is metaphorically how the world feels to me at the moment...

[David Drake]

Nice improvements! I see you even rated a post by Carl on the LB Facebook page.

[bluatigro]

my version :
justbasiccom.proboards.com/thread/454/virus-outbreak-sim?page=1&scrollTo=2864

[judir]

I am getting a type mismatch error when I try to run this file. The compiler stops at this line:
col=val(left$(after$(col$,"sim"),2)) 'get the colliding sim

array$() requires numeric parameters.

Judi

Running LB V4.04